fork/nix-minecraft

git clone https://git.julia.blue/fork/nix-minecraft

Ryan Horiguchipaper-servers: add more granualar jdk version selection (#202)cb646a9

lazymc
1.6 KiB65 linesraw
1{
2  callPackage,
3  lib,
4  jdk8,
5  jdk11,
6  jdk17,
7  jdk21,
8  jdk25,
9  vanillaServers,
10}:
11let
12  inherit (lib.our) escapeVersion;
13  inherit (lib)
14    nameValuePair
15    flatten
16    last
17    versionOlder
18    mapAttrsToList
19    ;
20  versions = lib.importJSON ./lock.json;
21
22  # Remove -build... suffix
23  stripBuild = v: builtins.head (builtins.match "(.*)-build.*" v);
24  # Sort by attribute 'attr' using 'f' function
25  sortBy = attr: f: builtins.sort (a: b: f a.${attr} b.${attr});
26
27  # https://docs.papermc.io/paper/getting-started#requirements
28  getRecommendedJavaVersion =
29    v:
30    if versionOlder v "1.11.2" then
31      jdk8
32    else if versionOlder v "1.16.5" then
33      jdk11
34    else if versionOlder v "1.20" then
35      jdk17
36    else if versionOlder v "26.1" then
37      jdk21
38    else
39      jdk25;
40
41  packages = mapAttrsToList (
42    mcVersion: builds:
43    sortBy "version" versionOlder (
44      mapAttrsToList (
45        buildNumber: value:
46        callPackage ./derivation.nix {
47          inherit (value) url sha256;
48          version = "${mcVersion}-build.${buildNumber}";
49          jre = getRecommendedJavaVersion mcVersion;
50          minecraft-server = vanillaServers."vanilla-${escapeVersion mcVersion}";
51        }
52      ) builds
53    )
54  ) versions;
55
56  # Latest build for each MC version
57  latestBuilds = sortBy "version" versionOlder (map last packages);
58in
59lib.recurseIntoAttrs (
60  builtins.listToAttrs (
61    (map (x: nameValuePair (escapeVersion x.name) x) (flatten packages))
62    ++ (map (x: nameValuePair (escapeVersion (stripBuild x.name)) x) latestBuilds)
63    ++ [ (nameValuePair "paper" (last latestBuilds)) ]
64  )
65)