fork/nix-minecraft

git clone https://git.julia.blue/fork/nix-minecraft

Infinidogetextile-servers: replace unpacked libraries with classpathe857551

master
1.5 KiB75 linesraw
1{
2  lib,
3  fetchurl,
4  stdenvNoCC,
5  writeText,
6  jre_headless,
7  loaderName,
8  loaderVersion,
9  launchPrefix ? loaderName,
10  gameVersion,
11  serverLaunch,
12  mainClass ? "",
13  libraries,
14  extraBuildPhase ? "",
15}:
16
17let
18  lib_lock = lib.importJSON ./libraries.json;
19  fetchedLibraries = lib.forEach libraries (l: "${fetchurl lib_lock.${l}}");
20
21  classPath = lib.concatStringsSep " " fetchedLibraries;
22  manifest = writeText "manifest.mf" (
23    lib.our.wrapJarManifest ''
24      Manifest-Version: 1.0
25      Main-Class: ${serverLaunch}
26      Class-Path: ${classPath}
27    ''
28  );
29in
30stdenvNoCC.mkDerivation {
31  pname = "${loaderName}-server-launch";
32  version = "${loaderVersion}-${gameVersion}";
33
34  nativeBuildInputs = [ jre_headless ];
35
36  buildPhase = ''
37    ${lib.optionalString (mainClass != "") ''
38      echo launch.mainClass=${mainClass} > ${launchPrefix}-server-launch.properties
39    ''}
40
41    ${extraBuildPhase}
42  '';
43
44  installPhase = ''
45    rm env-vars
46
47    jar cmvf ${manifest} $out/lib/minecraft/launch.jar .
48
49    # Ensure Nix knows we depend on files listed in our class path.
50    mkdir $out/nix-support
51    echo ${classPath} > $out/nix-support/class-path
52  '';
53
54  phases = [
55    "buildPhase"
56    "installPhase"
57  ];
58
59  passthru = {
60    inherit
61      loaderName
62      loaderVersion
63      gameVersion
64      launchPrefix
65      ;
66
67    propertyPrefix =
68      {
69        "fabric" = "fabric";
70        "legacy-fabric" = "fabric";
71        "quilt" = "loader";
72      }
73      .${loaderName};
74  };
75}