fork/nix-minecraft

git clone https://git.julia.blue/fork/nix-minecraft

Infinidogemeta: format all nix filese6e6044

master
1.5 KiB59 linesraw
1{
2  callPackage,
3  lib,
4  jdk8,
5  jdk11,
6  jdk,
7  vanillaServers,
8}:
9let
10  inherit (lib.our) escapeVersion;
11  inherit (lib)
12    nameValuePair
13    flatten
14    last
15    versionOlder
16    mapAttrsToList
17    ;
18  versions = lib.importJSON ./lock.json;
19
20  # Remove -build... suffix
21  stripBuild = v: builtins.head (builtins.match "(.*)-build.*" v);
22  # Sort by attribute 'attr' using 'f' function
23  sortBy = attr: f: builtins.sort (a: b: f a.${attr} b.${attr});
24
25  # https://docs.papermc.io/paper/getting-started#requirements
26  getRecommendedJavaVersion =
27    v:
28    if versionOlder v "1.11.2" then
29      jdk8
30    else if versionOlder v "1.16.5" then
31      jdk11
32    else
33      jdk;
34
35  packages = mapAttrsToList (
36    mcVersion: builds:
37    sortBy "version" versionOlder (
38      mapAttrsToList (
39        buildNumber: value:
40        callPackage ./derivation.nix {
41          inherit (value) url sha256;
42          version = "${mcVersion}-build.${buildNumber}";
43          jre = getRecommendedJavaVersion mcVersion;
44          minecraft-server = vanillaServers."vanilla-${escapeVersion mcVersion}";
45        }
46      ) builds
47    )
48  ) versions;
49
50  # Latest build for each MC version
51  latestBuilds = sortBy "version" versionOlder (map last packages);
52in
53lib.recurseIntoAttrs (
54  builtins.listToAttrs (
55    (map (x: nameValuePair (escapeVersion x.name) x) (flatten packages))
56    ++ (map (x: nameValuePair (escapeVersion (stripBuild x.name)) x) latestBuilds)
57    ++ [ (nameValuePair "paper" (last latestBuilds)) ]
58  )
59)