fork/nix-minecraft

git clone https://git.julia.blue/fork/nix-minecraft

Infinidogepurpur-servers: remove unnecessary stripBuilddd2f97c

master
2.0 KiB72 linesraw
1{
2  callPackage,
3  lib,
4  jdk11,
5  jdk17,
6  jdk,
7  vanillaServers,
8}:
9let
10  inherit (lib.our) escapeVersion;
11  inherit (lib)
12    nameValuePair
13    flatten
14    last
15    versionOlder
16    mapAttrsToList
17    ;
18  versions = lib.importJSON ./lock.json;
19
20  # Remove -build... suffix
21  stripBuild = v: builtins.head (builtins.match "(.*)-build.*" v);
22  # Sort by attribute 'attr' using 'f' function
23  sortBy = attr: f: builtins.sort (a: b: f a.${attr} b.${attr});
24
25  # https://docs.papermc.io/paper/getting-started#requirements
26  getRecommendedJavaVersion =
27    v:
28    # oldest version is 1.14.1
29    # Version older than 1.1 1.1 = false
30    if versionOlder v "1.17" then
31      jdk11
32    else if versionOlder v "1.18.2" then # paper says 1.18.1+ but 1.18.1 max is 17
33      jdk17
34    else
35      jdk;
36
37  getLog4j =
38    v:
39    if lib.versionOlder v "1.17" then
40      "-Dlog4j.configurationFile=" + ./purpur_log4j2_1141-1165.xml
41    else if lib.versionOlder v "1.18.2" then
42      "-Dlog4j.configurationFile=" + ./purpur_log4j2_117.xml
43    else
44      ""; # newer than 1.18.1 are patched.
45
46  packages = mapAttrsToList (
47    mcVersion: builds:
48    sortBy "version" versionOlder (
49      mapAttrsToList (
50        buildNumber: value:
51        callPackage ./derivation.nix rec {
52          inherit (value) sha256;
53          version = "${mcVersion}";
54          url = "https://api.purpurmc.org/v2/purpur/${mcVersion}/${buildNumber}/download";
55          jre = getRecommendedJavaVersion mcVersion;
56          log4j = getLog4j mcVersion;
57          minecraft-server = vanillaServers."vanilla-${escapeVersion mcVersion}";
58        }
59      ) builds
60    )
61  ) versions;
62
63  # Latest build for each MC version
64  latestBuilds = sortBy "version" versionOlder (map last packages);
65in
66lib.recurseIntoAttrs (
67  builtins.listToAttrs (
68    (map (x: nameValuePair (escapeVersion x.name) x) (flatten packages))
69    ++ (map (x: nameValuePair (escapeVersion x.name) x) latestBuilds)
70    ++ [ (nameValuePair "purpur" (last latestBuilds)) ]
71  )
72)