fork/nix-minecraft

git clone https://git.julia.blue/fork/nix-minecraft

Gabriel Fontesfeat: add paper server packages (#21)07c2cbb

module/fix-14
1.8 KiB53 linesraw
1{
2  description = "An attempt to better support Minecraft-related content for the Nix ecosystem";
3
4  inputs = {
5    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
6    flake-utils.url = "github:numtide/flake-utils";
7  };
8
9  outputs =
10    { self
11    , nixpkgs
12    , flake-utils
13    , ...
14    }@inputs:
15    let
16      packages = pkgs:
17        let
18          callPackage = pkgs.newScope {
19            inherit inputs;
20            lib = pkgs.lib.extend (_: _: { our = self.lib; });
21          };
22        in
23        rec {
24          vanillaServers = callPackage ./pkgs/minecraft-servers { };
25          fabricServers = callPackage ./pkgs/fabric-servers { inherit vanillaServers; };
26          quiltServers = callPackage ./pkgs/quilt-servers { inherit vanillaServers; };
27          legacyFabricServers = callPackage ./pkgs/legacy-fabric-servers { inherit vanillaServers; };
28          paperServers = callPackage ./pkgs/paper-servers { };
29          minecraftServers = vanillaServers // fabricServers // quiltServers // legacyFabricServers // paperServers;
30
31          vanilla-server = vanillaServers.vanilla;
32          fabric-server = fabricServers.fabric;
33          quilt-server = quiltServers.quilt;
34          paper-server = paperServers.paper;
35          minecraft-server = vanilla-server;
36        } // (
37          builtins.mapAttrs (n: v: callPackage v) (self.lib.rakeLeaves ./pkgs/helpers)
38        ) // (
39          builtins.mapAttrs (n: v: callPackage v { }) (self.lib.rakeLeaves ./pkgs/tools)
40        );
41    in
42    {
43      lib = import ./lib { lib = flake-utils.lib // nixpkgs.lib; };
44
45      overlay = final: prev: packages prev;
46      nixosModules = self.lib.rakeLeaves ./modules;
47    } // flake-utils.lib.eachDefaultSystem (system: {
48      packages = packages (import nixpkgs {
49        inherit system;
50        config = { allowUnfree = true; };
51      });
52    });
53}