fork/nix-minecraft

git clone https://git.julia.blue/fork/nix-minecraft

Gabriel Fontesfeat: add paper server packages (#21)07c2cbb

module/fix-14
1.4 KiB40 linesraw
1{ callPackage
2, lib
3, javaPackages
4}:
5let
6  inherit (lib.our) escapeVersion;
7  inherit (lib) nameValuePair flatten last versionOlder mapAttrsToList;
8  versions = lib.importJSON ./lock.json;
9
10  # Remove -build... suffix
11  stripBuild = v: builtins.head (builtins.match "(.*)-build.*" v);
12  # Sort by attribute 'attr' using 'f' function
13  sortBy = attr: f: builtins.sort (a: b: f a.${attr} b.${attr});
14
15  getJavaVersion = v: (builtins.getAttr "openjdk${toString v}" javaPackages.compiler);
16  # https://docs.papermc.io/paper/getting-started#requirements
17  getRecommendedJavaVersion = v:
18    if versionOlder v "1.11.2" then getJavaVersion 8
19    else if versionOlder v "1.16.5" then getJavaVersion 11
20    else if versionOlder v "1.17.1" then getJavaVersion 16
21    else getJavaVersion 17;
22
23  packages = mapAttrsToList
24    (mcVersion: builds: sortBy "version" versionOlder (mapAttrsToList
25      (buildNumber: value: callPackage ./derivation.nix {
26        inherit (value) url sha256;
27        version = "${mcVersion}-build.${buildNumber}";
28        jre = getRecommendedJavaVersion mcVersion;
29      })
30      builds))
31    versions;
32
33  # Latest build for each MC version
34  latestBuilds = sortBy "version" versionOlder (map last packages);
35in
36lib.recurseIntoAttrs (builtins.listToAttrs (
37  (map (x: nameValuePair (escapeVersion x.name) x) (flatten packages)) ++
38  (map (x: nameValuePair (escapeVersion (stripBuild x.name)) x) latestBuilds) ++
39  [ (nameValuePair "paper" (last latestBuilds)) ]
40))