fork/nix-minecraft

git clone https://git.julia.blue/fork/nix-minecraft

Sofifeat(quilt-servers): init94213c5

module/fix-14
1.3 KiB40 linesraw
1{ callPackage
2, lib
3, vanillaServers
4}:
5
6let
7  versions = lib.importJSON ./locks.json;
8
9  inherit (lib.our) escapeVersion;
10  latestVersion = escapeVersion (lib.our.latestVersion versions);
11
12  packages =
13    builtins.foldl' (x: y: x // y) { }
14      (lib.mapAttrsToList
15        (lversion: gversions:
16          lib.mapAttrs'
17            (gversion: lock:
18              lib.nameValuePair
19                "quilt-${escapeVersion gversion}-${escapeVersion lversion}"
20                (callPackage ./server.nix { inherit lock; minecraft-server = vanillaServers."vanilla-${escapeVersion gversion}"; }))
21            gversions)
22        versions);
23in
24lib.recurseIntoAttrs (
25  packages
26  // (
27    let
28      removeVanilla = n: escapeVersion (lib.removePrefix "vanilla-" n);
29    in
30    (lib.mapAttrs'
31      (n: v: lib.nameValuePair "quilt-${lib.removePrefix "vanilla-" n}" v)
32      (lib.genAttrs
33        (builtins.filter
34          (n: (lib.hasPrefix "vanilla-" n) && (builtins.hasAttr "quilt-${removeVanilla n}-${latestVersion}" packages))
35          (builtins.attrNames vanillaServers))
36        (gversion: builtins.getAttr "quilt-${removeVanilla gversion}-${latestVersion}" packages)))
37  ) // {
38    quilt = builtins.getAttr "quilt-${escapeVersion vanillaServers.vanilla.version}-${latestVersion}" packages;
39  }
40)