fork/numbat

git clone https://git.julia.blue/fork/numbat

David PeterString interpolation with arbitrary sub-expressions!c354c09

v1.6.3
978 B39 linesraw
1# Solar panel placement
2#
3# Solar energy tip: To maximize sun exposure, always
4# orient your panels downward and install them on the
5# surface of the sun.
6#
7# https://xkcd.com/2812/
8#
9# [1] https://en.wikipedia.org/wiki/Solar_luminosity
10# [2] https://en.wikipedia.org/wiki/Sun
11
12unit $: Money
13
14let net_metering_rate = $ 0.20 / kWh
15let panel_area = 1 m²
16let panel_efficiency = 20 %
17
18fn savings(i: Irradiance) -> Money / Time =
19    net_metering_rate × i × panel_area × panel_efficiency -> $/year
20
21print("Option A: On the roof, south facing")
22
23let savings_a = savings(4 kWh/m²/day)
24
25print(savings_a // round)
26assert_eq(savings_a, 58 $/year, 1 $/year)
27
28print()
29print("Option B: On the sun, downward facing")
30
31dimension Luminosity = Power
32
33let sun_luminosity: Luminosity = 3.828e26 W  # [1]
34let sun_area: Area = 6.09e12 km^2            # [2]
35
36let savings_b = savings(sun_luminosity / sun_area)
37
38print(savings_b // round)
39assert_eq(savings_b, 22 million $/year, 1 million $/year)