fork/rules_rust

git clone https://git.julia.blue/fork/rules_rust

UebelAndreFixed Clippy bug with `--@rules_rust//:clippy_flags`. (#1392)81590f4b

0.10.0
4.4 KiB131 linesraw
1"""Unittest to verify properties of clippy rules"""
2
3load("@bazel_skylib//lib:unittest.bzl", "analysistest")
4load("//rust:defs.bzl", "rust_clippy_aspect")
5load("//test/unit:common.bzl", "assert_argv_contains", "assert_list_contains_adjacent_elements")
6
7def _find_clippy_action(actions):
8    for action in actions:
9        if action.mnemonic == "Clippy":
10            return action
11    fail("Failed to find Clippy action")
12
13def _clippy_aspect_action_has_flag_impl(ctx, flags):
14    env = analysistest.begin(ctx)
15    target = analysistest.target_under_test(env)
16
17    clippy_action = _find_clippy_action(target.actions)
18
19    # Ensure each flag is present in the clippy action
20    for flag in flags:
21        assert_argv_contains(
22            env,
23            clippy_action,
24            flag,
25        )
26
27    clippy_checks = target[OutputGroupInfo].clippy_checks.to_list()
28    if len(clippy_checks) != 1:
29        fail("clippy_checks is only expected to contain 1 file")
30
31    # Ensure the arguments to generate the marker file are present in
32    # the clippy action
33    assert_list_contains_adjacent_elements(
34        env,
35        clippy_action.argv,
36        [
37            "--touch-file",
38            clippy_checks[0].path,
39        ],
40    )
41
42    return analysistest.end(env)
43
44def _binary_clippy_aspect_action_has_warnings_flag_test_impl(ctx):
45    return _clippy_aspect_action_has_flag_impl(
46        ctx,
47        ["-Dwarnings"],
48    )
49
50def _library_clippy_aspect_action_has_warnings_flag_test_impl(ctx):
51    return _clippy_aspect_action_has_flag_impl(
52        ctx,
53        ["-Dwarnings"],
54    )
55
56def _test_clippy_aspect_action_has_warnings_flag_test_impl(ctx):
57    return _clippy_aspect_action_has_flag_impl(
58        ctx,
59        [
60            "-Dwarnings",
61            "--test",
62        ],
63    )
64
65_CLIPPY_EXPLICIT_FLAGS = [
66    "-Dwarnings",
67    "-A",
68    "clippy::needless_return",
69]
70
71def _clippy_aspect_with_explicit_flags_test_impl(ctx):
72    return _clippy_aspect_action_has_flag_impl(
73        ctx,
74        _CLIPPY_EXPLICIT_FLAGS,
75    )
76
77def make_clippy_aspect_unittest(impl, **kwargs):
78    return analysistest.make(
79        impl,
80        extra_target_under_test_aspects = [rust_clippy_aspect],
81        **kwargs
82    )
83
84binary_clippy_aspect_action_has_warnings_flag_test = make_clippy_aspect_unittest(_binary_clippy_aspect_action_has_warnings_flag_test_impl)
85library_clippy_aspect_action_has_warnings_flag_test = make_clippy_aspect_unittest(_library_clippy_aspect_action_has_warnings_flag_test_impl)
86test_clippy_aspect_action_has_warnings_flag_test = make_clippy_aspect_unittest(_test_clippy_aspect_action_has_warnings_flag_test_impl)
87clippy_aspect_with_explicit_flags_test = make_clippy_aspect_unittest(_clippy_aspect_with_explicit_flags_test_impl, config_settings = {"@//:clippy_flags": _CLIPPY_EXPLICIT_FLAGS})
88
89def clippy_test_suite(name):
90    """Entry-point macro called from the BUILD file.
91
92    Args:
93        name (str): Name of the macro.
94    """
95
96    binary_clippy_aspect_action_has_warnings_flag_test(
97        name = "binary_clippy_aspect_action_has_warnings_flag_test",
98        target_under_test = Label("//test/clippy:ok_binary"),
99    )
100    library_clippy_aspect_action_has_warnings_flag_test(
101        name = "library_clippy_aspect_action_has_warnings_flag_test",
102        target_under_test = Label("//test/clippy:ok_library"),
103    )
104    test_clippy_aspect_action_has_warnings_flag_test(
105        name = "test_clippy_aspect_action_has_warnings_flag_test",
106        target_under_test = Label("//test/clippy:ok_test"),
107    )
108    clippy_aspect_with_explicit_flags_test(
109        name = "binary_clippy_aspect_with_explicit_flags_test",
110        target_under_test = Label("//test/clippy:ok_binary"),
111    )
112    clippy_aspect_with_explicit_flags_test(
113        name = "library_clippy_aspect_with_explicit_flags_test",
114        target_under_test = Label("//test/clippy:ok_library"),
115    )
116    clippy_aspect_with_explicit_flags_test(
117        name = "test_clippy_aspect_with_explicit_flags_test",
118        target_under_test = Label("//test/clippy:ok_test"),
119    )
120
121    native.test_suite(
122        name = name,
123        tests = [
124            ":binary_clippy_aspect_action_has_warnings_flag_test",
125            ":library_clippy_aspect_action_has_warnings_flag_test",
126            ":test_clippy_aspect_action_has_warnings_flag_test",
127            ":binary_clippy_aspect_with_explicit_flags_test",
128            ":library_clippy_aspect_with_explicit_flags_test",
129            ":test_clippy_aspect_with_explicit_flags_test",
130        ],
131    )