fork/rules_rust

git clone https://git.julia.blue/fork/rules_rust

UebelAndreMade components of `rustc` bundles mandatory for `rust_toolchain`. (#1104)f1b8fd3b

0.11.0
4.3 KiB137 linesraw
1"""Unit tests for rust toolchains."""
2
3load("@bazel_skylib//lib:unittest.bzl", "analysistest", "asserts")
4load("@bazel_skylib//rules:write_file.bzl", "write_file")
5load("//rust:toolchain.bzl", "rust_stdlib_filegroup", "rust_toolchain")
6
7def _toolchain_specifies_target_triple_test_impl(ctx):
8    env = analysistest.begin(ctx)
9    toolchain_info = analysistest.target_under_test(env)[platform_common.ToolchainInfo]
10
11    asserts.equals(env, None, toolchain_info.target_json)
12    asserts.equals(env, "toolchain-test-triple", toolchain_info.target_flag_value)
13    asserts.equals(env, "toolchain-test-triple", toolchain_info.target_triple)
14
15    return analysistest.end(env)
16
17def _toolchain_specifies_target_json_test_impl(ctx):
18    env = analysistest.begin(ctx)
19    toolchain_info = analysistest.target_under_test(env)[platform_common.ToolchainInfo]
20
21    asserts.equals(env, "toolchain-test-triple.json", toolchain_info.target_json.basename)
22    asserts.equals(env, "test/unit/toolchain/toolchain-test-triple.json", toolchain_info.target_flag_value)
23    asserts.equals(env, "", toolchain_info.target_triple)
24
25    return analysistest.end(env)
26
27def _toolchain_location_expands_linkflags_impl(ctx):
28    env = analysistest.begin(ctx)
29    toolchain_info = analysistest.target_under_test(env)[platform_common.ToolchainInfo]
30
31    asserts.equals(
32        env,
33        "test:test/unit/toolchain/config.txt",
34        toolchain_info.stdlib_linkflags.linking_context.linker_inputs.to_list()[0].user_link_flags[0],
35    )
36
37    return analysistest.end(env)
38
39toolchain_specifies_target_triple_test = analysistest.make(_toolchain_specifies_target_triple_test_impl)
40toolchain_specifies_target_json_test = analysistest.make(_toolchain_specifies_target_json_test_impl)
41toolchain_location_expands_linkflags_test = analysistest.make(_toolchain_location_expands_linkflags_impl)
42
43def _toolchain_test():
44    native.filegroup(
45        name = "stdlib_srcs",
46        srcs = ["config.txt"],
47    )
48    rust_stdlib_filegroup(
49        name = "std_libs",
50        srcs = [":stdlib_srcs"],
51    )
52
53    native.filegroup(
54        name = "target_json",
55        srcs = ["toolchain-test-triple.json"],
56    )
57
58    write_file(
59        name = "mock_rustc",
60        out = "mock_rustc.exe",
61        content = [],
62        is_executable = True,
63    )
64
65    write_file(
66        name = "mock_rustdoc",
67        out = "mock_rustdoc.exe",
68        content = [],
69        is_executable = True,
70    )
71
72    rust_toolchain(
73        name = "rust_triple_toolchain",
74        binary_ext = "",
75        dylib_ext = ".so",
76        exec_triple = "x86_64-unknown-none",
77        os = "linux",
78        rust_doc = ":mock_rustdoc",
79        rust_std = ":std_libs",
80        rustc = ":mock_rustc",
81        staticlib_ext = ".a",
82        stdlib_linkflags = [],
83        target_triple = "toolchain-test-triple",
84    )
85
86    rust_toolchain(
87        name = "rust_json_toolchain",
88        binary_ext = "",
89        dylib_ext = ".so",
90        exec_triple = "x86_64-unknown-none",
91        os = "linux",
92        rust_doc = ":mock_rustdoc",
93        rust_std = ":std_libs",
94        rustc = ":mock_rustc",
95        staticlib_ext = ".a",
96        stdlib_linkflags = [],
97        target_json = ":target_json",
98    )
99
100    rust_toolchain(
101        name = "rust_location_expand_toolchain",
102        binary_ext = "",
103        dylib_ext = ".so",
104        exec_triple = "x86_64-unknown-none",
105        os = "linux",
106        rust_doc = ":mock_rustdoc",
107        rust_std = ":std_libs",
108        rustc = ":mock_rustc",
109        staticlib_ext = ".a",
110        stdlib_linkflags = ["test:$(location :stdlib_srcs)"],
111        target_json = ":target_json",
112    )
113
114    toolchain_specifies_target_triple_test(
115        name = "toolchain_specifies_target_triple_test",
116        target_under_test = ":rust_triple_toolchain",
117    )
118    toolchain_specifies_target_json_test(
119        name = "toolchain_specifies_target_json_test",
120        target_under_test = ":rust_json_toolchain",
121    )
122    toolchain_location_expands_linkflags_test(
123        name = "toolchain_location_expands_linkflags_test",
124        target_under_test = ":rust_location_expand_toolchain",
125    )
126
127def toolchain_test_suite(name):
128    _toolchain_test()
129
130    native.test_suite(
131        name = name,
132        tests = [
133            ":toolchain_specifies_target_triple_test",
134            ":toolchain_specifies_target_json_test",
135            ":toolchain_location_expands_linkflags_test",
136        ],
137    )