fork/rules_rust

git clone https://git.julia.blue/fork/rules_rust

Krasimir Georgiev"sandwich" rlibs between native deps in linker order (#1333)51f8e302

0.6.0
13.7 KiB382 linesraw
1"""Unittests for rust rules."""
2
3load("@bazel_skylib//lib:unittest.bzl", "analysistest", "asserts")
4load("@rules_cc//cc:defs.bzl", "cc_library")
5load("//rust:defs.bzl", "rust_binary", "rust_library", "rust_proc_macro", "rust_shared_library", "rust_static_library")
6load(
7    "//test/unit:common.bzl",
8    "assert_argv_contains",
9    "assert_argv_contains_not",
10    "assert_argv_contains_prefix",
11    "assert_argv_contains_prefix_not",
12    "assert_argv_contains_prefix_suffix",
13    "assert_list_contains_adjacent_elements",
14)
15
16def _rlib_has_no_native_libs_test_impl(ctx):
17    env = analysistest.begin(ctx)
18    tut = analysistest.target_under_test(env)
19    action = tut.actions[0]
20    assert_argv_contains(env, action, "--crate-type=rlib")
21    assert_argv_contains_not(env, action, "-lstatic=native_dep")
22    assert_argv_contains_not(env, action, "-ldylib=native_dep")
23    assert_argv_contains_prefix_not(env, action, "--codegen=linker=")
24    return analysistest.end(env)
25
26def _cdylib_has_native_libs_test_impl(ctx):
27    env = analysistest.begin(ctx)
28    tut = analysistest.target_under_test(env)
29    action = tut.actions[0]
30    assert_argv_contains_prefix_suffix(env, action, "-Lnative=", "/native_deps")
31    assert_argv_contains(env, action, "--crate-type=cdylib")
32    assert_argv_contains(env, action, "-lstatic=native_dep")
33    assert_argv_contains(env, action, "-Clink-arg=-lnative_dep")
34    assert_argv_contains_prefix(env, action, "--codegen=linker=")
35    return analysistest.end(env)
36
37def _staticlib_has_native_libs_test_impl(ctx):
38    env = analysistest.begin(ctx)
39    tut = analysistest.target_under_test(env)
40    action = tut.actions[0]
41    assert_argv_contains_prefix_suffix(env, action, "-Lnative=", "/native_deps")
42    assert_argv_contains(env, action, "--crate-type=staticlib")
43    assert_argv_contains(env, action, "-lstatic=native_dep")
44    assert_argv_contains(env, action, "-Clink-arg=-lnative_dep")
45    assert_argv_contains_prefix(env, action, "--codegen=linker=")
46    return analysistest.end(env)
47
48def _proc_macro_has_native_libs_test_impl(ctx):
49    env = analysistest.begin(ctx)
50    tut = analysistest.target_under_test(env)
51    asserts.equals(env, 1, len(tut.actions))
52    action = tut.actions[0]
53    assert_argv_contains_prefix_suffix(env, action, "-Lnative=", "/native_deps")
54    assert_argv_contains(env, action, "--crate-type=proc-macro")
55    assert_argv_contains(env, action, "-lstatic=native_dep")
56    assert_argv_contains(env, action, "-Clink-arg=-lnative_dep")
57    assert_argv_contains_prefix(env, action, "--codegen=linker=")
58    return analysistest.end(env)
59
60def _bin_has_native_libs_test_impl(ctx):
61    env = analysistest.begin(ctx)
62    tut = analysistest.target_under_test(env)
63    action = tut.actions[0]
64    assert_argv_contains_prefix_suffix(env, action, "-Lnative=", "/native_deps")
65    assert_argv_contains(env, action, "-lstatic=native_dep")
66    assert_argv_contains(env, action, "-Clink-arg=-lnative_dep")
67    assert_argv_contains_prefix(env, action, "--codegen=linker=")
68    return analysistest.end(env)
69
70def _extract_linker_args(argv):
71    return [a for a in argv if (
72        a.startswith("link-arg=") or
73        a.startswith("link-args=") or
74        a.startswith("-l") or
75        a.endswith(".lo") or
76        a.endswith(".o")
77    )]
78
79def _bin_has_native_dep_and_alwayslink_test_impl(ctx):
80    env = analysistest.begin(ctx)
81    tut = analysistest.target_under_test(env)
82    action = tut.actions[0]
83
84    compilation_mode = ctx.var["COMPILATION_MODE"]
85    workspace_prefix = "" if ctx.workspace_name == "rules_rust" else "external/rules_rust/"
86    if ctx.target_platform_has_constraint(ctx.attr._macos_constraint[platform_common.ConstraintValueInfo]):
87        want = [
88            "-lstatic=native_dep",
89            "link-arg=-Wl,-force_load,bazel-out/darwin-{}/bin/{}test/unit/native_deps/libalwayslink.lo".format(compilation_mode, workspace_prefix),
90        ]
91    elif ctx.target_platform_has_constraint(ctx.attr._windows_constraint[platform_common.ConstraintValueInfo]):
92        want = [
93            "-lstatic=native_dep",
94            "link-arg=/WHOLEARCHIVE:bazel-out/x64_windows-{}/bin/{}test/unit/native_deps/alwayslink.lo.lib".format(compilation_mode, workspace_prefix),
95        ]
96    else:
97        want = [
98            "-lstatic=native_dep",
99            "link-arg=-Wl,--whole-archive",
100            "link-arg=bazel-out/k8-{}/bin/{}test/unit/native_deps/libalwayslink.lo".format(compilation_mode, workspace_prefix),
101            "link-arg=-Wl,--no-whole-archive",
102        ]
103    individual_link_args = [
104        arg
105        for arg in _extract_linker_args(action.argv)
106        if arg.startswith("link-arg=") or arg.startswith("-lstatic=")
107    ]
108    asserts.equals(env, want, individual_link_args)
109    return analysistest.end(env)
110
111def _cdylib_has_native_dep_and_alwayslink_test_impl(ctx):
112    env = analysistest.begin(ctx)
113    tut = analysistest.target_under_test(env)
114    action = tut.actions[0]
115
116    # skipping first link-arg since it contains unrelated linker flags
117    linker_args = _extract_linker_args(action.argv)[1:]
118
119    compilation_mode = ctx.var["COMPILATION_MODE"]
120    workspace_prefix = "" if ctx.workspace_name == "rules_rust" else "external/rules_rust/"
121    pic_suffix = ".pic" if compilation_mode == "opt" else ""
122    if ctx.target_platform_has_constraint(ctx.attr._macos_constraint[platform_common.ConstraintValueInfo]):
123        want = [
124            "-lstatic=native_dep",
125            "link-arg=-Wl,-force_load,bazel-out/darwin-{}/bin/{}test/unit/native_deps/libalwayslink{}.lo".format(compilation_mode, workspace_prefix, pic_suffix),
126        ]
127    elif ctx.target_platform_has_constraint(ctx.attr._windows_constraint[platform_common.ConstraintValueInfo]):
128        want = [
129            "-lstatic=native_dep",
130            "link-arg=/WHOLEARCHIVE:bazel-out/x64_windows-{}/bin/{}test/unit/native_deps/alwayslink.lo.lib".format(compilation_mode, workspace_prefix),
131        ]
132    else:
133        want = [
134            "-lstatic=native_dep",
135            "link-arg=-Wl,--whole-archive",
136            "link-arg=bazel-out/k8-{}/bin/{}test/unit/native_deps/libalwayslink{}.lo".format(compilation_mode, workspace_prefix, pic_suffix),
137            "link-arg=-Wl,--no-whole-archive",
138        ]
139    asserts.equals(env, want, linker_args)
140    return analysistest.end(env)
141
142rlib_has_no_native_libs_test = analysistest.make(_rlib_has_no_native_libs_test_impl)
143staticlib_has_native_libs_test = analysistest.make(_staticlib_has_native_libs_test_impl)
144cdylib_has_native_libs_test = analysistest.make(_cdylib_has_native_libs_test_impl)
145proc_macro_has_native_libs_test = analysistest.make(_proc_macro_has_native_libs_test_impl)
146bin_has_native_libs_test = analysistest.make(_bin_has_native_libs_test_impl)
147bin_has_native_dep_and_alwayslink_test = analysistest.make(_bin_has_native_dep_and_alwayslink_test_impl, attrs = {
148    "_macos_constraint": attr.label(default = Label("@platforms//os:macos")),
149    "_windows_constraint": attr.label(default = Label("@platforms//os:windows")),
150})
151cdylib_has_native_dep_and_alwayslink_test = analysistest.make(_cdylib_has_native_dep_and_alwayslink_test_impl, attrs = {
152    "_macos_constraint": attr.label(default = Label("@platforms//os:macos")),
153    "_windows_constraint": attr.label(default = Label("@platforms//os:windows")),
154})
155
156def _native_dep_test():
157    rust_library(
158        name = "rlib_has_no_native_dep",
159        srcs = ["lib_using_native_dep.rs"],
160        edition = "2018",
161        deps = [":native_dep"],
162    )
163
164    rust_static_library(
165        name = "staticlib_has_native_dep",
166        srcs = ["lib_using_native_dep.rs"],
167        edition = "2018",
168        deps = [":native_dep"],
169    )
170
171    rust_shared_library(
172        name = "cdylib_has_native_dep",
173        srcs = ["lib_using_native_dep.rs"],
174        edition = "2018",
175        deps = [":native_dep"],
176    )
177
178    rust_proc_macro(
179        name = "proc_macro_has_native_dep",
180        srcs = ["proc_macro_using_native_dep.rs"],
181        edition = "2018",
182        deps = [":native_dep"],
183    )
184
185    rust_binary(
186        name = "bin_has_native_dep",
187        srcs = ["bin_using_native_dep.rs"],
188        edition = "2018",
189        deps = [":native_dep"],
190    )
191
192    rust_binary(
193        name = "bin_has_native_dep_and_alwayslink",
194        srcs = ["bin_using_native_dep.rs"],
195        edition = "2018",
196        deps = [":native_dep", ":alwayslink"],
197    )
198
199    cc_library(
200        name = "native_dep",
201        srcs = ["native_dep.cc"],
202        visibility = ["//test/unit:__subpackages__"],
203    )
204
205    cc_library(
206        name = "alwayslink",
207        srcs = ["alwayslink.cc"],
208        alwayslink = 1,
209    )
210
211    rust_shared_library(
212        name = "cdylib_has_native_dep_and_alwayslink",
213        srcs = ["lib_using_native_dep.rs"],
214        edition = "2018",
215        deps = [":native_dep", ":alwayslink"],
216    )
217
218    rlib_has_no_native_libs_test(
219        name = "rlib_has_no_native_libs_test",
220        target_under_test = ":rlib_has_no_native_dep",
221    )
222    staticlib_has_native_libs_test(
223        name = "staticlib_has_native_libs_test",
224        target_under_test = ":staticlib_has_native_dep",
225    )
226    cdylib_has_native_libs_test(
227        name = "cdylib_has_native_libs_test",
228        target_under_test = ":cdylib_has_native_dep",
229    )
230    proc_macro_has_native_libs_test(
231        name = "proc_macro_has_native_libs_test",
232        target_under_test = ":proc_macro_has_native_dep",
233    )
234    bin_has_native_libs_test(
235        name = "bin_has_native_libs_test",
236        target_under_test = ":bin_has_native_dep",
237    )
238    bin_has_native_dep_and_alwayslink_test(
239        name = "bin_has_native_dep_and_alwayslink_test",
240        target_under_test = ":bin_has_native_dep_and_alwayslink",
241    )
242    cdylib_has_native_dep_and_alwayslink_test(
243        name = "cdylib_has_native_dep_and_alwayslink_test",
244        target_under_test = ":cdylib_has_native_dep_and_alwayslink",
245    )
246
247def _linkopts_propagate_test_impl(ctx):
248    env = analysistest.begin(ctx)
249    tut = analysistest.target_under_test(env)
250    action = tut.actions[0]
251
252    # Ensure linkopts from direct (-Llinkoptdep1) and transitive
253    # (-Llinkoptdep2) dependencies are propagated.
254    # Consistently with cc rules, dependency linkopts take precedence over
255    # dependent linkopts (i.e. dependency linkopts appear later in the command
256    # line).
257    linkopt_args = [
258        arg
259        for arg in _extract_linker_args(action.argv)
260        if arg.startswith("link-args")
261    ][0].split(" ")
262    assert_list_contains_adjacent_elements(
263        env,
264        linkopt_args,
265        ["-Llinkoptdep1", "-Llinkoptdep2"],
266    )
267    return analysistest.end(env)
268
269linkopts_propagate_test = analysistest.make(_linkopts_propagate_test_impl)
270
271def _linkopts_test():
272    rust_binary(
273        name = "linkopts_rust_bin",
274        srcs = ["bin_using_native_dep.rs"],
275        edition = "2018",
276        deps = [":linkopts_native_dep_a"],
277    )
278
279    cc_library(
280        name = "linkopts_native_dep_a",
281        srcs = ["native_dep.cc"],
282        linkopts = ["-Llinkoptdep1"],
283        deps = [":linkopts_native_dep_b"],
284    )
285
286    cc_library(
287        name = "linkopts_native_dep_b",
288        linkopts = ["-Llinkoptdep2"],
289    )
290
291    linkopts_propagate_test(
292        name = "native_linkopts_propagate_test",
293        target_under_test = ":linkopts_rust_bin",
294    )
295
296def _check_additional_deps_test_impl(ctx, expect_additional_deps):
297    env = analysistest.begin(ctx)
298    tut = analysistest.target_under_test(env)
299    action = tut.actions[0]
300    additional_inputs = [inp.basename for inp in action.inputs.to_list()]
301    asserts.equals(env, "dynamic.lds" in additional_inputs, expect_additional_deps)
302    return analysistest.end(env)
303
304def _has_additional_deps_test_impl(ctx):
305    return _check_additional_deps_test_impl(ctx, expect_additional_deps = True)
306
307def _has_no_additional_deps_test_impl(ctx):
308    return _check_additional_deps_test_impl(ctx, expect_additional_deps = False)
309
310has_additional_deps_test = analysistest.make(_has_additional_deps_test_impl)
311has_no_additional_deps_test = analysistest.make(_has_no_additional_deps_test_impl)
312
313def _additional_deps_test():
314    rust_binary(
315        name = "bin_additional_deps",
316        srcs = ["bin_using_native_dep.rs"],
317        edition = "2018",
318        deps = [":additional_deps_cc"],
319    )
320
321    rust_shared_library(
322        name = "cdylib_additional_deps",
323        srcs = ["lib_using_native_dep.rs"],
324        edition = "2018",
325        deps = [":additional_deps_cc"],
326    )
327
328    rust_library(
329        name = "lib_additional_deps",
330        srcs = ["lib_using_native_dep.rs"],
331        edition = "2018",
332        deps = ["additional_deps_cc"],
333    )
334
335    cc_library(
336        name = "additional_deps_cc",
337        srcs = ["native_dep.cc"],
338        linkopts = ["-L$(execpath :dynamic.lds)"],
339        deps = [":dynamic.lds"],
340    )
341
342    has_additional_deps_test(
343        name = "bin_has_additional_deps_test",
344        target_under_test = ":bin_additional_deps",
345    )
346
347    has_additional_deps_test(
348        name = "cdylib_has_additional_deps_test",
349        target_under_test = ":cdylib_additional_deps",
350    )
351
352    has_no_additional_deps_test(
353        name = "lib_has_no_additional_deps_test",
354        target_under_test = ":lib_additional_deps",
355    )
356
357def native_deps_test_suite(name):
358    """Entry-point macro called from the BUILD file.
359
360    Args:
361        name: Name of the macro.
362    """
363    _native_dep_test()
364    _linkopts_test()
365    _additional_deps_test()
366
367    native.test_suite(
368        name = name,
369        tests = [
370            ":bin_has_additional_deps_test",
371            ":bin_has_native_dep_and_alwayslink_test",
372            ":bin_has_native_libs_test",
373            ":cdylib_has_additional_deps_test",
374            ":cdylib_has_native_dep_and_alwayslink_test",
375            ":cdylib_has_native_libs_test",
376            ":lib_has_no_additional_deps_test",
377            ":native_linkopts_propagate_test",
378            ":proc_macro_has_native_libs_test",
379            ":rlib_has_no_native_libs_test",
380            ":staticlib_has_native_libs_test",
381        ],
382    )