fork/rules_rust

git clone https://git.julia.blue/fork/rules_rust

Keith SmileyAdd test coverage support (#1324)7465c1aa

0.7.0
13.8 KiB385 linesraw
1"""Unittests for rust rules."""
2
3load("@bazel_skylib//lib:unittest.bzl", "analysistest", "asserts")
4load("@rules_cc//cc:defs.bzl", "cc_library")
5load("//rust:defs.bzl", "rust_binary", "rust_library", "rust_proc_macro", "rust_shared_library", "rust_static_library")
6load(
7    "//test/unit:common.bzl",
8    "assert_argv_contains",
9    "assert_argv_contains_not",
10    "assert_argv_contains_prefix",
11    "assert_argv_contains_prefix_not",
12    "assert_argv_contains_prefix_suffix",
13    "assert_list_contains_adjacent_elements",
14)
15
16def _rlib_has_no_native_libs_test_impl(ctx):
17    env = analysistest.begin(ctx)
18    tut = analysistest.target_under_test(env)
19    action = tut.actions[0]
20    assert_argv_contains(env, action, "--crate-type=rlib")
21    assert_argv_contains_not(env, action, "-lstatic=native_dep")
22    assert_argv_contains_not(env, action, "-ldylib=native_dep")
23    assert_argv_contains_prefix_not(env, action, "--codegen=linker=")
24    return analysistest.end(env)
25
26def _cdylib_has_native_libs_test_impl(ctx):
27    env = analysistest.begin(ctx)
28    tut = analysistest.target_under_test(env)
29    action = tut.actions[0]
30    assert_argv_contains_prefix_suffix(env, action, "-Lnative=", "/native_deps")
31    assert_argv_contains(env, action, "--crate-type=cdylib")
32    assert_argv_contains(env, action, "-lstatic=native_dep")
33    assert_argv_contains(env, action, "-Clink-arg=-lnative_dep")
34    assert_argv_contains_prefix(env, action, "--codegen=linker=")
35    return analysistest.end(env)
36
37def _staticlib_has_native_libs_test_impl(ctx):
38    env = analysistest.begin(ctx)
39    tut = analysistest.target_under_test(env)
40    action = tut.actions[0]
41    assert_argv_contains_prefix_suffix(env, action, "-Lnative=", "/native_deps")
42    assert_argv_contains(env, action, "--crate-type=staticlib")
43    assert_argv_contains(env, action, "-lstatic=native_dep")
44    assert_argv_contains(env, action, "-Clink-arg=-lnative_dep")
45    assert_argv_contains_prefix(env, action, "--codegen=linker=")
46    return analysistest.end(env)
47
48def _proc_macro_has_native_libs_test_impl(ctx):
49    env = analysistest.begin(ctx)
50    tut = analysistest.target_under_test(env)
51    if ctx.configuration.coverage_enabled:
52        asserts.equals(env, 2, len(tut.actions))
53    else:
54        asserts.equals(env, 1, len(tut.actions))
55    action = tut.actions[0]
56    assert_argv_contains_prefix_suffix(env, action, "-Lnative=", "/native_deps")
57    assert_argv_contains(env, action, "--crate-type=proc-macro")
58    assert_argv_contains(env, action, "-lstatic=native_dep")
59    assert_argv_contains(env, action, "-Clink-arg=-lnative_dep")
60    assert_argv_contains_prefix(env, action, "--codegen=linker=")
61    return analysistest.end(env)
62
63def _bin_has_native_libs_test_impl(ctx):
64    env = analysistest.begin(ctx)
65    tut = analysistest.target_under_test(env)
66    action = tut.actions[0]
67    assert_argv_contains_prefix_suffix(env, action, "-Lnative=", "/native_deps")
68    assert_argv_contains(env, action, "-lstatic=native_dep")
69    assert_argv_contains(env, action, "-Clink-arg=-lnative_dep")
70    assert_argv_contains_prefix(env, action, "--codegen=linker=")
71    return analysistest.end(env)
72
73def _extract_linker_args(argv):
74    return [a for a in argv if (
75        a.startswith("link-arg=") or
76        a.startswith("link-args=") or
77        a.startswith("-l") or
78        a.endswith(".lo") or
79        a.endswith(".o")
80    )]
81
82def _bin_has_native_dep_and_alwayslink_test_impl(ctx):
83    env = analysistest.begin(ctx)
84    tut = analysistest.target_under_test(env)
85    action = tut.actions[0]
86
87    compilation_mode = ctx.var["COMPILATION_MODE"]
88    workspace_prefix = "" if ctx.workspace_name == "rules_rust" else "external/rules_rust/"
89    if ctx.target_platform_has_constraint(ctx.attr._macos_constraint[platform_common.ConstraintValueInfo]):
90        want = [
91            "-lstatic=native_dep",
92            "link-arg=-Wl,-force_load,bazel-out/darwin-{}/bin/{}test/unit/native_deps/libalwayslink.lo".format(compilation_mode, workspace_prefix),
93        ]
94    elif ctx.target_platform_has_constraint(ctx.attr._windows_constraint[platform_common.ConstraintValueInfo]):
95        want = [
96            "-lstatic=native_dep",
97            "link-arg=/WHOLEARCHIVE:bazel-out/x64_windows-{}/bin/{}test/unit/native_deps/alwayslink.lo.lib".format(compilation_mode, workspace_prefix),
98        ]
99    else:
100        want = [
101            "-lstatic=native_dep",
102            "link-arg=-Wl,--whole-archive",
103            "link-arg=bazel-out/k8-{}/bin/{}test/unit/native_deps/libalwayslink.lo".format(compilation_mode, workspace_prefix),
104            "link-arg=-Wl,--no-whole-archive",
105        ]
106    individual_link_args = [
107        arg
108        for arg in _extract_linker_args(action.argv)
109        if arg.startswith("link-arg=") or arg.startswith("-lstatic=")
110    ]
111    asserts.equals(env, want, individual_link_args)
112    return analysistest.end(env)
113
114def _cdylib_has_native_dep_and_alwayslink_test_impl(ctx):
115    env = analysistest.begin(ctx)
116    tut = analysistest.target_under_test(env)
117    action = tut.actions[0]
118
119    # skipping first link-arg since it contains unrelated linker flags
120    linker_args = _extract_linker_args(action.argv)[1:]
121
122    compilation_mode = ctx.var["COMPILATION_MODE"]
123    workspace_prefix = "" if ctx.workspace_name == "rules_rust" else "external/rules_rust/"
124    pic_suffix = ".pic" if compilation_mode == "opt" else ""
125    if ctx.target_platform_has_constraint(ctx.attr._macos_constraint[platform_common.ConstraintValueInfo]):
126        want = [
127            "-lstatic=native_dep",
128            "link-arg=-Wl,-force_load,bazel-out/darwin-{}/bin/{}test/unit/native_deps/libalwayslink{}.lo".format(compilation_mode, workspace_prefix, pic_suffix),
129        ]
130    elif ctx.target_platform_has_constraint(ctx.attr._windows_constraint[platform_common.ConstraintValueInfo]):
131        want = [
132            "-lstatic=native_dep",
133            "link-arg=/WHOLEARCHIVE:bazel-out/x64_windows-{}/bin/{}test/unit/native_deps/alwayslink.lo.lib".format(compilation_mode, workspace_prefix),
134        ]
135    else:
136        want = [
137            "-lstatic=native_dep",
138            "link-arg=-Wl,--whole-archive",
139            "link-arg=bazel-out/k8-{}/bin/{}test/unit/native_deps/libalwayslink{}.lo".format(compilation_mode, workspace_prefix, pic_suffix),
140            "link-arg=-Wl,--no-whole-archive",
141        ]
142    asserts.equals(env, want, linker_args)
143    return analysistest.end(env)
144
145rlib_has_no_native_libs_test = analysistest.make(_rlib_has_no_native_libs_test_impl)
146staticlib_has_native_libs_test = analysistest.make(_staticlib_has_native_libs_test_impl)
147cdylib_has_native_libs_test = analysistest.make(_cdylib_has_native_libs_test_impl)
148proc_macro_has_native_libs_test = analysistest.make(_proc_macro_has_native_libs_test_impl)
149bin_has_native_libs_test = analysistest.make(_bin_has_native_libs_test_impl)
150bin_has_native_dep_and_alwayslink_test = analysistest.make(_bin_has_native_dep_and_alwayslink_test_impl, attrs = {
151    "_macos_constraint": attr.label(default = Label("@platforms//os:macos")),
152    "_windows_constraint": attr.label(default = Label("@platforms//os:windows")),
153})
154cdylib_has_native_dep_and_alwayslink_test = analysistest.make(_cdylib_has_native_dep_and_alwayslink_test_impl, attrs = {
155    "_macos_constraint": attr.label(default = Label("@platforms//os:macos")),
156    "_windows_constraint": attr.label(default = Label("@platforms//os:windows")),
157})
158
159def _native_dep_test():
160    rust_library(
161        name = "rlib_has_no_native_dep",
162        srcs = ["lib_using_native_dep.rs"],
163        edition = "2018",
164        deps = [":native_dep"],
165    )
166
167    rust_static_library(
168        name = "staticlib_has_native_dep",
169        srcs = ["lib_using_native_dep.rs"],
170        edition = "2018",
171        deps = [":native_dep"],
172    )
173
174    rust_shared_library(
175        name = "cdylib_has_native_dep",
176        srcs = ["lib_using_native_dep.rs"],
177        edition = "2018",
178        deps = [":native_dep"],
179    )
180
181    rust_proc_macro(
182        name = "proc_macro_has_native_dep",
183        srcs = ["proc_macro_using_native_dep.rs"],
184        edition = "2018",
185        deps = [":native_dep"],
186    )
187
188    rust_binary(
189        name = "bin_has_native_dep",
190        srcs = ["bin_using_native_dep.rs"],
191        edition = "2018",
192        deps = [":native_dep"],
193    )
194
195    rust_binary(
196        name = "bin_has_native_dep_and_alwayslink",
197        srcs = ["bin_using_native_dep.rs"],
198        edition = "2018",
199        deps = [":native_dep", ":alwayslink"],
200    )
201
202    cc_library(
203        name = "native_dep",
204        srcs = ["native_dep.cc"],
205        visibility = ["//test/unit:__subpackages__"],
206    )
207
208    cc_library(
209        name = "alwayslink",
210        srcs = ["alwayslink.cc"],
211        alwayslink = 1,
212    )
213
214    rust_shared_library(
215        name = "cdylib_has_native_dep_and_alwayslink",
216        srcs = ["lib_using_native_dep.rs"],
217        edition = "2018",
218        deps = [":native_dep", ":alwayslink"],
219    )
220
221    rlib_has_no_native_libs_test(
222        name = "rlib_has_no_native_libs_test",
223        target_under_test = ":rlib_has_no_native_dep",
224    )
225    staticlib_has_native_libs_test(
226        name = "staticlib_has_native_libs_test",
227        target_under_test = ":staticlib_has_native_dep",
228    )
229    cdylib_has_native_libs_test(
230        name = "cdylib_has_native_libs_test",
231        target_under_test = ":cdylib_has_native_dep",
232    )
233    proc_macro_has_native_libs_test(
234        name = "proc_macro_has_native_libs_test",
235        target_under_test = ":proc_macro_has_native_dep",
236    )
237    bin_has_native_libs_test(
238        name = "bin_has_native_libs_test",
239        target_under_test = ":bin_has_native_dep",
240    )
241    bin_has_native_dep_and_alwayslink_test(
242        name = "bin_has_native_dep_and_alwayslink_test",
243        target_under_test = ":bin_has_native_dep_and_alwayslink",
244    )
245    cdylib_has_native_dep_and_alwayslink_test(
246        name = "cdylib_has_native_dep_and_alwayslink_test",
247        target_under_test = ":cdylib_has_native_dep_and_alwayslink",
248    )
249
250def _linkopts_propagate_test_impl(ctx):
251    env = analysistest.begin(ctx)
252    tut = analysistest.target_under_test(env)
253    action = tut.actions[0]
254
255    # Ensure linkopts from direct (-Llinkoptdep1) and transitive
256    # (-Llinkoptdep2) dependencies are propagated.
257    # Consistently with cc rules, dependency linkopts take precedence over
258    # dependent linkopts (i.e. dependency linkopts appear later in the command
259    # line).
260    linkopt_args = [
261        arg
262        for arg in _extract_linker_args(action.argv)
263        if arg.startswith("link-args")
264    ][0].split(" ")
265    assert_list_contains_adjacent_elements(
266        env,
267        linkopt_args,
268        ["-Llinkoptdep1", "-Llinkoptdep2"],
269    )
270    return analysistest.end(env)
271
272linkopts_propagate_test = analysistest.make(_linkopts_propagate_test_impl)
273
274def _linkopts_test():
275    rust_binary(
276        name = "linkopts_rust_bin",
277        srcs = ["bin_using_native_dep.rs"],
278        edition = "2018",
279        deps = [":linkopts_native_dep_a"],
280    )
281
282    cc_library(
283        name = "linkopts_native_dep_a",
284        srcs = ["native_dep.cc"],
285        linkopts = ["-Llinkoptdep1"],
286        deps = [":linkopts_native_dep_b"],
287    )
288
289    cc_library(
290        name = "linkopts_native_dep_b",
291        linkopts = ["-Llinkoptdep2"],
292    )
293
294    linkopts_propagate_test(
295        name = "native_linkopts_propagate_test",
296        target_under_test = ":linkopts_rust_bin",
297    )
298
299def _check_additional_deps_test_impl(ctx, expect_additional_deps):
300    env = analysistest.begin(ctx)
301    tut = analysistest.target_under_test(env)
302    action = tut.actions[0]
303    additional_inputs = [inp.basename for inp in action.inputs.to_list()]
304    asserts.equals(env, "dynamic.lds" in additional_inputs, expect_additional_deps)
305    return analysistest.end(env)
306
307def _has_additional_deps_test_impl(ctx):
308    return _check_additional_deps_test_impl(ctx, expect_additional_deps = True)
309
310def _has_no_additional_deps_test_impl(ctx):
311    return _check_additional_deps_test_impl(ctx, expect_additional_deps = False)
312
313has_additional_deps_test = analysistest.make(_has_additional_deps_test_impl)
314has_no_additional_deps_test = analysistest.make(_has_no_additional_deps_test_impl)
315
316def _additional_deps_test():
317    rust_binary(
318        name = "bin_additional_deps",
319        srcs = ["bin_using_native_dep.rs"],
320        edition = "2018",
321        deps = [":additional_deps_cc"],
322    )
323
324    rust_shared_library(
325        name = "cdylib_additional_deps",
326        srcs = ["lib_using_native_dep.rs"],
327        edition = "2018",
328        deps = [":additional_deps_cc"],
329    )
330
331    rust_library(
332        name = "lib_additional_deps",
333        srcs = ["lib_using_native_dep.rs"],
334        edition = "2018",
335        deps = ["additional_deps_cc"],
336    )
337
338    cc_library(
339        name = "additional_deps_cc",
340        srcs = ["native_dep.cc"],
341        linkopts = ["-L$(execpath :dynamic.lds)"],
342        deps = [":dynamic.lds"],
343    )
344
345    has_additional_deps_test(
346        name = "bin_has_additional_deps_test",
347        target_under_test = ":bin_additional_deps",
348    )
349
350    has_additional_deps_test(
351        name = "cdylib_has_additional_deps_test",
352        target_under_test = ":cdylib_additional_deps",
353    )
354
355    has_no_additional_deps_test(
356        name = "lib_has_no_additional_deps_test",
357        target_under_test = ":lib_additional_deps",
358    )
359
360def native_deps_test_suite(name):
361    """Entry-point macro called from the BUILD file.
362
363    Args:
364        name: Name of the macro.
365    """
366    _native_dep_test()
367    _linkopts_test()
368    _additional_deps_test()
369
370    native.test_suite(
371        name = name,
372        tests = [
373            ":bin_has_additional_deps_test",
374            ":bin_has_native_dep_and_alwayslink_test",
375            ":bin_has_native_libs_test",
376            ":cdylib_has_additional_deps_test",
377            ":cdylib_has_native_dep_and_alwayslink_test",
378            ":cdylib_has_native_libs_test",
379            ":lib_has_no_additional_deps_test",
380            ":native_linkopts_propagate_test",
381            ":proc_macro_has_native_libs_test",
382            ":rlib_has_no_native_libs_test",
383            ":staticlib_has_native_libs_test",
384        ],
385    )