fork/rules_rust

git clone https://git.julia.blue/fork/rules_rust

scentiniDo not pass `--Clink-arg=-l` for libstd and libtest (#1500)4e5fac59

0.9.0
14.8 KiB393 linesraw
1"""Unittests for rust rules."""
2
3load("@bazel_skylib//lib:unittest.bzl", "analysistest", "asserts")
4load("@rules_cc//cc:defs.bzl", "cc_library")
5load("//rust:defs.bzl", "rust_binary", "rust_library", "rust_proc_macro", "rust_shared_library", "rust_static_library")
6load(
7    "//test/unit:common.bzl",
8    "assert_argv_contains",
9    "assert_argv_contains_not",
10    "assert_argv_contains_prefix",
11    "assert_argv_contains_prefix_not",
12    "assert_argv_contains_prefix_suffix",
13    "assert_list_contains_adjacent_elements",
14)
15
16def _rlib_has_no_native_libs_test_impl(ctx):
17    env = analysistest.begin(ctx)
18    tut = analysistest.target_under_test(env)
19    action = tut.actions[0]
20    assert_argv_contains(env, action, "--crate-type=rlib")
21    assert_argv_contains_not(env, action, "-lstatic=native_dep")
22    assert_argv_contains_not(env, action, "-ldylib=native_dep")
23    assert_argv_contains_prefix_not(env, action, "--codegen=linker=")
24    return analysistest.end(env)
25
26def _cdylib_has_native_libs_test_impl(ctx):
27    env = analysistest.begin(ctx)
28    tut = analysistest.target_under_test(env)
29    action = tut.actions[0]
30    assert_argv_contains_prefix_suffix(env, action, "-Lnative=", "/native_deps")
31    assert_argv_contains(env, action, "--crate-type=cdylib")
32    assert_argv_contains(env, action, "-lstatic=native_dep")
33    native_link_arg = "-Clink-arg=-lnative_dep.lib" if ctx.target_platform_has_constraint(ctx.attr._windows_constraint[platform_common.ConstraintValueInfo]) else "-Clink-arg=-lnative_dep"
34    assert_argv_contains(env, action, native_link_arg)
35    assert_argv_contains_prefix(env, action, "--codegen=linker=")
36    return analysistest.end(env)
37
38def _staticlib_has_native_libs_test_impl(ctx):
39    env = analysistest.begin(ctx)
40    tut = analysistest.target_under_test(env)
41    action = tut.actions[0]
42    assert_argv_contains_prefix_suffix(env, action, "-Lnative=", "/native_deps")
43    assert_argv_contains(env, action, "--crate-type=staticlib")
44    assert_argv_contains(env, action, "-lstatic=native_dep")
45    native_link_arg = "-Clink-arg=-lnative_dep.lib" if ctx.target_platform_has_constraint(ctx.attr._windows_constraint[platform_common.ConstraintValueInfo]) else "-Clink-arg=-lnative_dep"
46    assert_argv_contains(env, action, native_link_arg)
47    assert_argv_contains_prefix(env, action, "--codegen=linker=")
48    return analysistest.end(env)
49
50def _proc_macro_has_native_libs_test_impl(ctx):
51    env = analysistest.begin(ctx)
52    tut = analysistest.target_under_test(env)
53    action = tut.actions[0]
54    assert_argv_contains_prefix_suffix(env, action, "-Lnative=", "/native_deps")
55    assert_argv_contains(env, action, "--crate-type=proc-macro")
56    assert_argv_contains(env, action, "-lstatic=native_dep")
57    native_link_arg = "-Clink-arg=-lnative_dep.lib" if ctx.target_platform_has_constraint(ctx.attr._windows_constraint[platform_common.ConstraintValueInfo]) else "-Clink-arg=-lnative_dep"
58    assert_argv_contains(env, action, native_link_arg)
59    assert_argv_contains_prefix(env, action, "--codegen=linker=")
60    return analysistest.end(env)
61
62def _bin_has_native_libs_test_impl(ctx):
63    env = analysistest.begin(ctx)
64    tut = analysistest.target_under_test(env)
65    action = tut.actions[0]
66    assert_argv_contains_prefix_suffix(env, action, "-Lnative=", "/native_deps")
67    assert_argv_contains(env, action, "-lstatic=native_dep")
68    native_link_arg = "-Clink-arg=-lnative_dep.lib" if ctx.target_platform_has_constraint(ctx.attr._windows_constraint[platform_common.ConstraintValueInfo]) else "-Clink-arg=-lnative_dep"
69    assert_argv_contains(env, action, native_link_arg)
70    assert_argv_contains_prefix(env, action, "--codegen=linker=")
71    return analysistest.end(env)
72
73def _extract_linker_args(argv):
74    return [a for a in argv if (
75        a.startswith("link-arg=") or
76        a.startswith("link-args=") or
77        a.startswith("-l") or
78        a.endswith(".lo") or
79        a.endswith(".o")
80    )]
81
82def _bin_has_native_dep_and_alwayslink_test_impl(ctx):
83    env = analysistest.begin(ctx)
84    tut = analysistest.target_under_test(env)
85    action = tut.actions[0]
86
87    compilation_mode = ctx.var["COMPILATION_MODE"]
88    workspace_prefix = "" if ctx.workspace_name == "rules_rust" else "external/rules_rust/"
89    if ctx.target_platform_has_constraint(ctx.attr._macos_constraint[platform_common.ConstraintValueInfo]):
90        want = [
91            "-lstatic=native_dep",
92            "link-arg=-Wl,-force_load,bazel-out/darwin-{}/bin/{}test/unit/native_deps/libalwayslink.lo".format(compilation_mode, workspace_prefix),
93        ]
94    elif ctx.target_platform_has_constraint(ctx.attr._windows_constraint[platform_common.ConstraintValueInfo]):
95        want = [
96            "-lstatic=native_dep",
97            "link-arg=/WHOLEARCHIVE:bazel-out/x64_windows-{}/bin/{}test/unit/native_deps/alwayslink.lo.lib".format(compilation_mode, workspace_prefix),
98        ]
99    else:
100        want = [
101            "-lstatic=native_dep",
102            "link-arg=-Wl,--whole-archive",
103            "link-arg=bazel-out/k8-{}/bin/{}test/unit/native_deps/libalwayslink.lo".format(compilation_mode, workspace_prefix),
104            "link-arg=-Wl,--no-whole-archive",
105        ]
106    individual_link_args = [
107        arg
108        for arg in _extract_linker_args(action.argv)
109        if arg.startswith("link-arg=") or arg.startswith("-lstatic=")
110    ]
111    asserts.equals(env, want, individual_link_args)
112    return analysistest.end(env)
113
114def _cdylib_has_native_dep_and_alwayslink_test_impl(ctx):
115    env = analysistest.begin(ctx)
116    tut = analysistest.target_under_test(env)
117    action = tut.actions[0]
118
119    # skipping first link-arg since it contains unrelated linker flags
120    linker_args = _extract_linker_args(action.argv)[1:]
121
122    compilation_mode = ctx.var["COMPILATION_MODE"]
123    workspace_prefix = "" if ctx.workspace_name == "rules_rust" else "external/rules_rust/"
124    pic_suffix = ".pic" if compilation_mode == "opt" else ""
125    if ctx.target_platform_has_constraint(ctx.attr._macos_constraint[platform_common.ConstraintValueInfo]):
126        want = [
127            "-lstatic=native_dep",
128            "link-arg=-Wl,-force_load,bazel-out/darwin-{}/bin/{}test/unit/native_deps/libalwayslink{}.lo".format(compilation_mode, workspace_prefix, pic_suffix),
129        ]
130    elif ctx.target_platform_has_constraint(ctx.attr._windows_constraint[platform_common.ConstraintValueInfo]):
131        want = [
132            "-lstatic=native_dep",
133            "link-arg=/WHOLEARCHIVE:bazel-out/x64_windows-{}/bin/{}test/unit/native_deps/alwayslink.lo.lib".format(compilation_mode, workspace_prefix),
134        ]
135    else:
136        want = [
137            "-lstatic=native_dep",
138            "link-arg=-Wl,--whole-archive",
139            "link-arg=bazel-out/k8-{}/bin/{}test/unit/native_deps/libalwayslink{}.lo".format(compilation_mode, workspace_prefix, pic_suffix),
140            "link-arg=-Wl,--no-whole-archive",
141        ]
142    asserts.equals(env, want, linker_args)
143    return analysistest.end(env)
144
145rlib_has_no_native_libs_test = analysistest.make(_rlib_has_no_native_libs_test_impl)
146staticlib_has_native_libs_test = analysistest.make(_staticlib_has_native_libs_test_impl, attrs = {
147    "_windows_constraint": attr.label(default = Label("@platforms//os:windows")),
148})
149cdylib_has_native_libs_test = analysistest.make(_cdylib_has_native_libs_test_impl, attrs = {
150    "_windows_constraint": attr.label(default = Label("@platforms//os:windows")),
151})
152proc_macro_has_native_libs_test = analysistest.make(_proc_macro_has_native_libs_test_impl, attrs = {
153    "_windows_constraint": attr.label(default = Label("@platforms//os:windows")),
154})
155bin_has_native_libs_test = analysistest.make(_bin_has_native_libs_test_impl, attrs = {
156    "_windows_constraint": attr.label(default = Label("@platforms//os:windows")),
157})
158bin_has_native_dep_and_alwayslink_test = analysistest.make(_bin_has_native_dep_and_alwayslink_test_impl, attrs = {
159    "_macos_constraint": attr.label(default = Label("@platforms//os:macos")),
160    "_windows_constraint": attr.label(default = Label("@platforms//os:windows")),
161})
162cdylib_has_native_dep_and_alwayslink_test = analysistest.make(_cdylib_has_native_dep_and_alwayslink_test_impl, attrs = {
163    "_macos_constraint": attr.label(default = Label("@platforms//os:macos")),
164    "_windows_constraint": attr.label(default = Label("@platforms//os:windows")),
165})
166
167def _native_dep_test():
168    rust_library(
169        name = "rlib_has_no_native_dep",
170        srcs = ["lib_using_native_dep.rs"],
171        edition = "2018",
172        deps = [":native_dep"],
173    )
174
175    rust_static_library(
176        name = "staticlib_has_native_dep",
177        srcs = ["lib_using_native_dep.rs"],
178        edition = "2018",
179        deps = [":native_dep"],
180    )
181
182    rust_shared_library(
183        name = "cdylib_has_native_dep",
184        srcs = ["lib_using_native_dep.rs"],
185        edition = "2018",
186        deps = [":native_dep"],
187    )
188
189    rust_proc_macro(
190        name = "proc_macro_has_native_dep",
191        srcs = ["proc_macro_using_native_dep.rs"],
192        edition = "2018",
193        deps = [":native_dep"],
194    )
195
196    rust_binary(
197        name = "bin_has_native_dep",
198        srcs = ["bin_using_native_dep.rs"],
199        edition = "2018",
200        deps = [":native_dep"],
201    )
202
203    rust_binary(
204        name = "bin_has_native_dep_and_alwayslink",
205        srcs = ["bin_using_native_dep.rs"],
206        edition = "2018",
207        deps = [":native_dep", ":alwayslink"],
208    )
209
210    cc_library(
211        name = "native_dep",
212        srcs = ["native_dep.cc"],
213        visibility = ["//test/unit:__subpackages__"],
214    )
215
216    cc_library(
217        name = "alwayslink",
218        srcs = ["alwayslink.cc"],
219        alwayslink = 1,
220    )
221
222    rust_shared_library(
223        name = "cdylib_has_native_dep_and_alwayslink",
224        srcs = ["lib_using_native_dep.rs"],
225        edition = "2018",
226        deps = [":native_dep", ":alwayslink"],
227    )
228
229    rlib_has_no_native_libs_test(
230        name = "rlib_has_no_native_libs_test",
231        target_under_test = ":rlib_has_no_native_dep",
232    )
233    staticlib_has_native_libs_test(
234        name = "staticlib_has_native_libs_test",
235        target_under_test = ":staticlib_has_native_dep",
236    )
237    cdylib_has_native_libs_test(
238        name = "cdylib_has_native_libs_test",
239        target_under_test = ":cdylib_has_native_dep",
240    )
241    proc_macro_has_native_libs_test(
242        name = "proc_macro_has_native_libs_test",
243        target_under_test = ":proc_macro_has_native_dep",
244    )
245    bin_has_native_libs_test(
246        name = "bin_has_native_libs_test",
247        target_under_test = ":bin_has_native_dep",
248    )
249    bin_has_native_dep_and_alwayslink_test(
250        name = "bin_has_native_dep_and_alwayslink_test",
251        target_under_test = ":bin_has_native_dep_and_alwayslink",
252    )
253    cdylib_has_native_dep_and_alwayslink_test(
254        name = "cdylib_has_native_dep_and_alwayslink_test",
255        target_under_test = ":cdylib_has_native_dep_and_alwayslink",
256    )
257
258def _linkopts_propagate_test_impl(ctx):
259    env = analysistest.begin(ctx)
260    tut = analysistest.target_under_test(env)
261    action = tut.actions[0]
262
263    # Ensure linkopts from direct (-Llinkoptdep1) and transitive
264    # (-Llinkoptdep2) dependencies are propagated.
265    # Consistently with cc rules, dependency linkopts take precedence over
266    # dependent linkopts (i.e. dependency linkopts appear later in the command
267    # line).
268    linkopt_args = [
269        arg
270        for arg in _extract_linker_args(action.argv)
271        if arg.startswith("link-args")
272    ][0].split(" ")
273    assert_list_contains_adjacent_elements(
274        env,
275        linkopt_args,
276        ["-Llinkoptdep1", "-Llinkoptdep2"],
277    )
278    return analysistest.end(env)
279
280linkopts_propagate_test = analysistest.make(_linkopts_propagate_test_impl)
281
282def _linkopts_test():
283    rust_binary(
284        name = "linkopts_rust_bin",
285        srcs = ["bin_using_native_dep.rs"],
286        edition = "2018",
287        deps = [":linkopts_native_dep_a"],
288    )
289
290    cc_library(
291        name = "linkopts_native_dep_a",
292        srcs = ["native_dep.cc"],
293        linkopts = ["-Llinkoptdep1"],
294        deps = [":linkopts_native_dep_b"],
295    )
296
297    cc_library(
298        name = "linkopts_native_dep_b",
299        linkopts = ["-Llinkoptdep2"],
300    )
301
302    linkopts_propagate_test(
303        name = "native_linkopts_propagate_test",
304        target_under_test = ":linkopts_rust_bin",
305    )
306
307def _check_additional_deps_test_impl(ctx, expect_additional_deps):
308    env = analysistest.begin(ctx)
309    tut = analysistest.target_under_test(env)
310    action = tut.actions[0]
311    additional_inputs = [inp.basename for inp in action.inputs.to_list()]
312    asserts.equals(env, "dynamic.lds" in additional_inputs, expect_additional_deps)
313    return analysistest.end(env)
314
315def _has_additional_deps_test_impl(ctx):
316    return _check_additional_deps_test_impl(ctx, expect_additional_deps = True)
317
318def _has_no_additional_deps_test_impl(ctx):
319    return _check_additional_deps_test_impl(ctx, expect_additional_deps = False)
320
321has_additional_deps_test = analysistest.make(_has_additional_deps_test_impl)
322has_no_additional_deps_test = analysistest.make(_has_no_additional_deps_test_impl)
323
324def _additional_deps_test():
325    rust_binary(
326        name = "bin_additional_deps",
327        srcs = ["bin_using_native_dep.rs"],
328        edition = "2018",
329        deps = [":additional_deps_cc"],
330    )
331
332    rust_shared_library(
333        name = "cdylib_additional_deps",
334        srcs = ["lib_using_native_dep.rs"],
335        edition = "2018",
336        deps = [":additional_deps_cc"],
337    )
338
339    rust_library(
340        name = "lib_additional_deps",
341        srcs = ["lib_using_native_dep.rs"],
342        edition = "2018",
343        deps = ["additional_deps_cc"],
344    )
345
346    cc_library(
347        name = "additional_deps_cc",
348        srcs = ["native_dep.cc"],
349        linkopts = ["-L$(execpath :dynamic.lds)"],
350        deps = [":dynamic.lds"],
351    )
352
353    has_additional_deps_test(
354        name = "bin_has_additional_deps_test",
355        target_under_test = ":bin_additional_deps",
356    )
357
358    has_additional_deps_test(
359        name = "cdylib_has_additional_deps_test",
360        target_under_test = ":cdylib_additional_deps",
361    )
362
363    has_no_additional_deps_test(
364        name = "lib_has_no_additional_deps_test",
365        target_under_test = ":lib_additional_deps",
366    )
367
368def native_deps_test_suite(name):
369    """Entry-point macro called from the BUILD file.
370
371    Args:
372        name: Name of the macro.
373    """
374    _native_dep_test()
375    _linkopts_test()
376    _additional_deps_test()
377
378    native.test_suite(
379        name = name,
380        tests = [
381            ":bin_has_additional_deps_test",
382            ":bin_has_native_dep_and_alwayslink_test",
383            ":bin_has_native_libs_test",
384            ":cdylib_has_additional_deps_test",
385            ":cdylib_has_native_dep_and_alwayslink_test",
386            ":cdylib_has_native_libs_test",
387            ":lib_has_no_additional_deps_test",
388            ":native_linkopts_propagate_test",
389            ":proc_macro_has_native_libs_test",
390            ":rlib_has_no_native_libs_test",
391            ":staticlib_has_native_libs_test",
392        ],
393    )