fork/rules_rust

git clone https://git.julia.blue/fork/rules_rust

Repana-ChowdappaAdd s390x arch support (#2616)3d1856b6

main
3.4 KiB93 linesraw
1"""Utility functions for use with the `crates_vendor` rule"""
2
3load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_file")
4load("@bazel_tools//tools/build_defs/repo:utils.bzl", "maybe")
5
6_BUILDIFIER_VERSION = "7.3.1"
7_BUILDIFIER_URL_TEMPLATE = "https://github.com/bazelbuild/buildtools/releases/download/v{version}/{bin}"
8_BUILDIFIER_INTEGRITY = {
9    "buildifier-darwin-amd64": "sha256-N1+CMQPQFiCq7CCgwpxsvKmfT9ByWuMLk2VcZwT0TXE=",
10    "buildifier-darwin-arm64": "sha256-Wmr8asegn1RVuguJvZnVriO0F03F3J1sDtXOjKrD+BM=",
11    "buildifier-linux-amd64": "sha256-VHTMUSinToBng9VAgfWBZixL6K5lAi9VfpKB7V3IgAk=",
12    "buildifier-linux-arm64": "sha256-C/hsS//69PCO7Xe95bIILkrlA5oR4uiwOYTBc8NKVhw=",
13    "buildifier-linux-s390x": "sha256-4tef9YhdRSdPdlMfGtvHtzoSn1nnZ/d36PveYz2dTi4=",
14    "buildifier-windows-amd64.exe": "sha256-NwzVdgda0pkwqC9d4TLxod5AhMeEqCUUvU2oDIWs9Kg=",
15}
16
17def crates_vendor_deps():
18    """Define dependencies of the `crates_vendor` rule
19
20    Returns:
21        list[struct(repo=str, is_dev_dep=bool)]: List of the dependency repositories.
22    """
23    direct_deps = []
24
25    for bin, integrity in _BUILDIFIER_INTEGRITY.items():
26        repo = "cargo_bazel.{}".format(bin)
27        maybe(
28            http_file,
29            name = repo,
30            urls = [_BUILDIFIER_URL_TEMPLATE.format(
31                bin = bin,
32                version = _BUILDIFIER_VERSION,
33            )],
34            integrity = integrity,
35            downloaded_file_path = "buildifier.exe" if bin.endswith(".exe") else "buildifier",
36            executable = True,
37        )
38        direct_deps.append(struct(repo = repo, is_dev_dep = False))
39
40    return direct_deps
41
42# buildifier: disable=unnamed-macro
43def crates_vendor_deps_targets():
44    """Define dependencies of the `crates_vendor` rule"""
45
46    native.config_setting(
47        name = "linux_amd64",
48        constraint_values = ["@platforms//os:linux", "@platforms//cpu:x86_64"],
49        visibility = ["//visibility:public"],
50    )
51
52    native.config_setting(
53        name = "linux_arm64",
54        constraint_values = ["@platforms//os:linux", "@platforms//cpu:arm64"],
55        visibility = ["//visibility:public"],
56    )
57
58    native.config_setting(
59        name = "linux_s390x",
60        constraint_values = ["@platforms//os:linux", "@platforms//cpu:s390x"],
61        visibility = ["//visibility:public"],
62    )
63
64    native.config_setting(
65        name = "macos_amd64",
66        constraint_values = ["@platforms//os:macos", "@platforms//cpu:x86_64"],
67        visibility = ["//visibility:public"],
68    )
69
70    native.config_setting(
71        name = "macos_arm64",
72        constraint_values = ["@platforms//os:macos", "@platforms//cpu:arm64"],
73        visibility = ["//visibility:public"],
74    )
75
76    native.config_setting(
77        name = "windows",
78        constraint_values = ["@platforms//os:windows"],
79        visibility = ["//visibility:public"],
80    )
81
82    native.alias(
83        name = "buildifier",
84        actual = select({
85            ":linux_amd64": "@cargo_bazel.buildifier-linux-amd64//file",
86            ":linux_arm64": "@cargo_bazel.buildifier-linux-arm64//file",
87            ":linux_s390x": "@cargo_bazel.buildifier-linux-s390x//file",
88            ":macos_amd64": "@cargo_bazel.buildifier-darwin-amd64//file",
89            ":macos_arm64": "@cargo_bazel.buildifier-darwin-arm64//file",
90            ":windows": "@cargo_bazel.buildifier-windows-amd64.exe//file",
91        }),
92        visibility = ["//visibility:public"],
93    )