fork/rules_rust

git clone https://git.julia.blue/fork/rules_rust

UebelAndreDrop references to `wasm-wasi` (#3027)ba6af156

main
5.7 KiB158 linesraw
1{
2  inputs = {
3
4    # Avoid need for https://github.com/nix-community/fenix/pull/180
5    nixpkgs = {
6      url = "github:NixOS/nixpkgs?rev=614462224f836ca340aed96b86799ad09b4c2298";
7    };
8
9    fenix = {
10      url = "github:nix-community/fenix";
11      inputs.nixpkgs.follows = "nixpkgs";
12    };
13
14    android-nixpkgs = {
15      url = "github:tadfisher/android-nixpkgs";
16      inputs.nixpkgs.follows = "nixpkgs";
17    };
18  };
19
20  outputs = { self, nixpkgs, fenix, android-nixpkgs, ... }:
21    let
22      pkgs = import nixpkgs { system = "x86_64-linux"; };
23
24      llvm = pkgs.llvmPackages_16;
25
26      rust = with fenix.packages."x86_64-linux"; combine [
27        complete.cargo
28        complete.clippy
29        complete.rustc
30        complete.rustfmt
31        complete.rust-src
32        targets."aarch64-apple-darwin".latest.rust-std
33        targets."aarch64-apple-ios".latest.rust-std
34        targets."aarch64-linux-android".latest.rust-std
35        targets."aarch64-unknown-linux-gnu".latest.rust-std
36        targets."wasm32-unknown-unknown".latest.rust-std
37        targets."wasm32-wasip1".latest.rust-std
38        targets."x86_64-apple-darwin".latest.rust-std
39        targets."x86_64-pc-windows-msvc".latest.rust-std
40        targets."x86_64-unknown-linux-gnu".latest.rust-std
41      ];
42
43      fetchVendor = { name, url, sha256, stripComponents ? 0 }:
44        let
45          authorization =
46            if (pkgs.lib.hasPrefix "https://raw.githubusercontent.com/<repo>/" url) then
47              ''-H "Authorization: Bearer <token>"''
48            else
49              "";
50        in
51        pkgs.runCommandLocal "vendor-${name}"
52          {
53            buildInputs = [ pkgs.cacert ];
54            outputHashMode = "recursive";
55            outputHashAlgo = "sha256";
56            outputHash = sha256;
57          } ''
58          # Empty URL special cased for example
59          mkdir --parents $out
60          if [ -n "${url}" ]; then
61            ${pkgs.curl}/bin/curl -s -S -L ${authorization} "${url}" | ${pkgs.libarchive}/bin/bsdtar -C $out -xf - --strip-components ${toString stripComponents}
62          fi
63        '';
64
65      libclang_rt_wasm32 = fetchVendor {
66        name = "libclang_rt_wasm32";
67        url = "https://github.com/WebAssembly/wasi-sdk/releases/download/wasi-sdk-20/libclang_rt.builtins-wasm32-wasi-20.0.tar.gz";
68        sha256 = "AdRe1XrGeBuai1p5IMUTR7T7nhNlD1RZ8grZjVoHAKs=";
69      };
70
71      sdk_aarch64-unknown-linux-gnu = fetchVendor {
72        name = "sdk_aarch64-unknown-linux-gnu";
73        url = "https://commondatastorage.googleapis.com/chrome-linux-sysroot/toolchain/80fc74e431f37f590d0c85f16a9d8709088929e8/debian_bullseye_arm64_sysroot.tar.xz";
74        sha256 = "VwHx6SjTmnGWvEoevjThR2oxNEe9NIdnSIJ9RBgKPE8=";
75      };
76
77      sdk_universal-apple-darwin = fetchVendor {
78        name = "sdk_universal-apple-darwin";
79        url = ""; # User needs to supply.
80        sha256 = "pQpattmS9VmO3ZIQUFn66az8GSmB4IvYhTTCFn6SUmo="; # User needs to supply.
81      };
82
83      sdk_universal-apple-ios = fetchVendor {
84        name = "sdk_universal-apple-ios";
85        url = ""; # User needs to supply.
86        sha256 = "pQpattmS9VmO3ZIQUFn66az8GSmB4IvYhTTCFn6SUmo="; # User needs to supply.
87      };
88
89      sdk_universal-linux-android = android-nixpkgs.sdk."x86_64-linux" (sdkPkgs: with sdkPkgs; [
90        cmdline-tools-latest
91        build-tools-33-0-2
92        platform-tools
93        platforms-android-33
94        ndk-25-2-9519653
95      ]);
96
97      sdk_wasm32-wasi = fetchVendor {
98        name = "sdk_wasm32-wasi";
99        url = "https://github.com/WebAssembly/wasi-sdk/releases/download/wasi-sdk-20/wasi-sysroot-20.0.tar.gz";
100        sha256 = "aePDwDYWopPPDSO802BO3YWM4d/J4a4CmGP/hDPF8FY=";
101      };
102
103      sdk_x86_64-pc-windows-msvc = fetchVendor {
104        name = "sdk_x86_64-pc-windows-msvc";
105        url = ""; # User needs to supply.
106        sha256 = "pQpattmS9VmO3ZIQUFn66az8GSmB4IvYhTTCFn6SUmo="; # User needs to supply.
107      };
108
109      sdk_x86_64-unknown-linux-gnu = fetchVendor {
110        name = "sdk_x86_64-unknown-linux-gnu";
111        url = "https://commondatastorage.googleapis.com/chrome-linux-sysroot/toolchain/f5f68713249b52b35db9e08f67184cac392369ab/debian_bullseye_amd64_sysroot.tar.xz";
112        sha256 = "+pqXDAsKY1BCBGFD3PDqMv1YiU+0/B2LXXryTFIUaWk=";
113      };
114
115      sdk_x86_64-unknown-nixos-gnu = pkgs.symlinkJoin {
116        name = "sdk_x86_64-unknown-nixos-gnu";
117        paths = [
118          llvm.libcxx.out
119          llvm.libcxx.dev
120          llvm.libunwind.out
121          pkgs.gcc13.cc.libgcc.out
122          pkgs.gcc13.cc.libgcc.libgcc
123          pkgs.glibc.dev
124          pkgs.glibc.libgcc.out
125          pkgs.glibc.out
126        ];
127      };
128    in
129    {
130      packages."x86_64-linux".bazel = {
131        config = pkgs.writeTextFile {
132          name = "bazel-config";
133          destination = "/config.bzl";
134          text = ''
135            LLVM = "${llvm.bintools-unwrapped}"
136            CLANG = "${llvm.clang-unwrapped}"
137            CLANG_LIB = "${llvm.clang-unwrapped.lib}"
138            CLANG_LIB_VERSION = "16"
139
140            NIXOS_DYNAMIC_LINKER = "${pkgs.glibc.out}/lib64/ld-linux-x86-64.so.2"
141            LIBCLANG_RT_WASM32 = "${libclang_rt_wasm32}"
142            ANDROID_NDK_VERSION = "25.2.9519653"
143
144            SDK_AARCH64_UNKNOWN_LINUX_GNU = "${sdk_aarch64-unknown-linux-gnu}"
145            SDK_UNIVERSAL_APPLE_DARWIN = "${sdk_universal-apple-darwin}"
146            SDK_UNIVERSAL_APPLE_IOS = "${sdk_universal-apple-ios}"
147            SDK_UNIVERSAL_LINUX_ANDROID = "${sdk_universal-linux-android}"
148            SDK_WASM32_WASI = "${sdk_wasm32-wasi}"
149            SDK_X86_64_PC_WINDOWS_MSVC = "${sdk_x86_64-pc-windows-msvc}"
150            SDK_X86_64_UNKNOWN_LINUX_GNU = "${sdk_x86_64-unknown-linux-gnu}"
151            SDK_X86_64_UNKNOWN_NIXOS_GNU = "${sdk_x86_64-unknown-nixos-gnu}"
152          '';
153        };
154
155        rust = rust;
156      };
157    };
158}