fork/rules_rust

git clone https://git.julia.blue/fork/rules_rust

UebelAndreAdded bzlmod support to core rules_rust (#3034)69ddb09d

main
17.9 KiB487 linesraw
1"""Unittests for rust rules."""
2
3load("@bazel_skylib//lib:unittest.bzl", "analysistest", "asserts")
4load("@rules_cc//cc:defs.bzl", "cc_library")
5load("//rust:defs.bzl", "rust_binary", "rust_library", "rust_proc_macro", "rust_shared_library", "rust_static_library")
6load(
7    "//test/unit:common.bzl",
8    "assert_argv_contains",
9    "assert_argv_contains_not",
10    "assert_argv_contains_prefix",
11    "assert_argv_contains_prefix_not",
12    "assert_argv_contains_prefix_suffix",
13    "assert_list_contains_adjacent_elements",
14)
15
16def _get_toolchain(ctx):
17    return ctx.attr._toolchain[platform_common.ToolchainInfo]
18
19def _get_darwin_component(arg):
20    # path/to/darwin_x86_64-fastbuild-fastbuild/package -> darwin_x86_64-fastbuild
21    darwin_component = [x for x in arg.split("/") if x.startswith("darwin")][0]
22
23    # darwin_x86_64-fastbuild -> darwin
24    return darwin_component.split("-")[0]
25
26def _rlib_has_no_native_libs_test_impl(ctx):
27    env = analysistest.begin(ctx)
28    tut = analysistest.target_under_test(env)
29    action = tut.actions[0]
30    assert_argv_contains(env, action, "--crate-type=rlib")
31    assert_argv_contains_not(env, action, "-lstatic=native_dep")
32    assert_argv_contains_not(env, action, "-ldylib=native_dep")
33    assert_argv_contains_prefix_not(env, action, "--codegen=linker=")
34    return analysistest.end(env)
35
36def _cdylib_has_native_libs_test_impl(ctx):
37    env = analysistest.begin(ctx)
38    tut = analysistest.target_under_test(env)
39    action = tut.actions[0]
40    toolchain = _get_toolchain(ctx)
41    compilation_mode = ctx.var["COMPILATION_MODE"]
42    pic_suffix = _get_pic_suffix(ctx, compilation_mode)
43    assert_argv_contains_prefix_suffix(env, action, "-Lnative=", "/native_deps")
44    assert_argv_contains(env, action, "--crate-type=cdylib")
45    assert_argv_contains(env, action, "-lstatic=native_dep{}".format(pic_suffix))
46    if toolchain.target_os == "windows":
47        if toolchain.target_triple.abi == "msvc":
48            native_link_arg = "-Clink-arg=native_dep.lib"
49        else:
50            native_link_arg = "-Clink-arg=-lnative_dep.lib"
51    else:
52        native_link_arg = "-Clink-arg=-lnative_dep{}".format(pic_suffix)
53    assert_argv_contains(env, action, native_link_arg)
54    assert_argv_contains_prefix(env, action, "--codegen=linker=")
55    return analysistest.end(env)
56
57def _staticlib_has_native_libs_test_impl(ctx):
58    env = analysistest.begin(ctx)
59    tut = analysistest.target_under_test(env)
60    action = tut.actions[0]
61    toolchain = _get_toolchain(ctx)
62    assert_argv_contains_prefix_suffix(env, action, "-Lnative=", "/native_deps")
63    assert_argv_contains(env, action, "--crate-type=staticlib")
64    assert_argv_contains(env, action, "-lstatic=native_dep")
65    if toolchain.target_os == "windows":
66        if toolchain.target_triple.abi == "msvc":
67            native_link_arg = "-Clink-arg=native_dep.lib"
68        else:
69            native_link_arg = "-Clink-arg=-lnative_dep.lib"
70    else:
71        native_link_arg = "-Clink-arg=-lnative_dep"
72    assert_argv_contains(env, action, native_link_arg)
73    assert_argv_contains_prefix(env, action, "--codegen=linker=")
74    return analysistest.end(env)
75
76def _proc_macro_has_native_libs_test_impl(ctx):
77    env = analysistest.begin(ctx)
78    tut = analysistest.target_under_test(env)
79    action = tut.actions[0]
80    toolchain = _get_toolchain(ctx)
81    compilation_mode = ctx.var["COMPILATION_MODE"]
82    pic_suffix = _get_pic_suffix(ctx, compilation_mode)
83    assert_argv_contains_prefix_suffix(env, action, "-Lnative=", "/native_deps")
84    assert_argv_contains(env, action, "--crate-type=proc-macro")
85    assert_argv_contains(env, action, "-lstatic=native_dep{}".format(pic_suffix))
86    if toolchain.target_os == "windows":
87        if toolchain.target_triple.abi == "msvc":
88            native_link_arg = "-Clink-arg=native_dep.lib"
89        else:
90            native_link_arg = "-Clink-arg=-lnative_dep.lib"
91    else:
92        native_link_arg = "-Clink-arg=-lnative_dep{}".format(pic_suffix)
93    assert_argv_contains(env, action, native_link_arg)
94    assert_argv_contains_prefix(env, action, "--codegen=linker=")
95    return analysistest.end(env)
96
97def _bin_has_native_libs_test_impl(ctx):
98    env = analysistest.begin(ctx)
99    tut = analysistest.target_under_test(env)
100    action = tut.actions[0]
101    toolchain = _get_toolchain(ctx)
102    assert_argv_contains_prefix_suffix(env, action, "-Lnative=", "/native_deps")
103    assert_argv_contains(env, action, "-lstatic=native_dep")
104    if toolchain.target_os == "windows":
105        if toolchain.target_triple.abi == "msvc":
106            native_link_arg = "-Clink-arg=native_dep.lib"
107        else:
108            native_link_arg = "-Clink-arg=-lnative_dep.lib"
109    else:
110        native_link_arg = "-Clink-arg=-lnative_dep"
111    assert_argv_contains(env, action, native_link_arg)
112    assert_argv_contains_prefix(env, action, "--codegen=linker=")
113    return analysistest.end(env)
114
115def _extract_linker_args(argv):
116    return [
117        a.removeprefix("--codegen=").removeprefix("-C").removeprefix("link-arg=").removeprefix("link-args=")
118        for a in argv
119        if (
120            a.startswith("--codegen=link-arg=") or
121            a.startswith("--codegen=link-args=") or
122            a.startswith("-Clink-args=") or
123            a.startswith("-Clink-arg=") or
124            a.startswith("link-args=") or
125            a.startswith("link-arg=") or
126            a.startswith("-l") or
127            a.endswith(".lo") or
128            a.endswith(".o")
129        )
130    ]
131
132def _get_workspace_prefix(ctx):
133    return "" if ctx.workspace_name in ["rules_rust", "_main"] else "external/rules_rust/"
134
135def _bin_has_native_dep_and_alwayslink_test_impl(ctx):
136    env = analysistest.begin(ctx)
137    tut = analysistest.target_under_test(env)
138    action = tut.actions[0]
139
140    toolchain = _get_toolchain(ctx)
141    compilation_mode = ctx.var["COMPILATION_MODE"]
142    workspace_prefix = _get_workspace_prefix(ctx)
143    link_args = _extract_linker_args(action.argv)
144    if toolchain.target_os == "darwin":
145        darwin_component = _get_darwin_component(link_args[-1])
146        want = [
147            "-lstatic=native_dep",
148            "-lnative_dep",
149            "-Wl,-force_load,bazel-out/{}-{}/bin/{}test/unit/native_deps/libalwayslink.lo".format(darwin_component, compilation_mode, workspace_prefix),
150        ]
151        assert_list_contains_adjacent_elements(env, link_args, want)
152    elif toolchain.target_os == "windows":
153        if toolchain.target_triple.abi == "msvc":
154            want = [
155                "-lstatic=native_dep",
156                "native_dep.lib",
157                "/WHOLEARCHIVE:bazel-out/x64_windows-{}/bin/{}test/unit/native_deps/alwayslink.lo.lib".format(compilation_mode, workspace_prefix),
158            ]
159        else:
160            want = [
161                "-lstatic=native_dep",
162                "native_dep.lib",
163                "-Wl,--whole-archive",
164                "bazel-out/x64_windows-{}/bin/{}test/unit/native_deps/alwayslink.lo.lib".format(compilation_mode, workspace_prefix),
165                "-Wl,--no-whole-archive",
166            ]
167    elif toolchain.target_arch == "s390x":
168        want = [
169            "-lstatic=native_dep",
170            "link-arg=-Wl,--whole-archive",
171            "link-arg=bazel-out/s390x-{}/bin/{}test/unit/native_deps/libalwayslink.lo".format(compilation_mode, workspace_prefix),
172            "link-arg=-Wl,--no-whole-archive",
173        ]
174    else:
175        want = [
176            "-lstatic=native_dep",
177            "-lnative_dep",
178            "-Wl,--whole-archive",
179            "bazel-out/k8-{}/bin/{}test/unit/native_deps/libalwayslink.lo".format(compilation_mode, workspace_prefix),
180            "-Wl,--no-whole-archive",
181        ]
182    assert_list_contains_adjacent_elements(env, link_args, want)
183    return analysistest.end(env)
184
185def _cdylib_has_native_dep_and_alwayslink_test_impl(ctx):
186    toolchain = _get_toolchain(ctx)
187
188    env = analysistest.begin(ctx)
189    tut = analysistest.target_under_test(env)
190    action = tut.actions[0]
191
192    linker_args = _extract_linker_args(action.argv)
193
194    toolchain = _get_toolchain(ctx)
195    compilation_mode = ctx.var["COMPILATION_MODE"]
196    workspace_prefix = _get_workspace_prefix(ctx)
197    pic_suffix = _get_pic_suffix(ctx, compilation_mode)
198    if toolchain.target_os == "darwin":
199        darwin_component = _get_darwin_component(linker_args[-1])
200        want = [
201            "-lstatic=native_dep{}".format(pic_suffix),
202            "-lnative_dep{}".format(pic_suffix),
203            "-Wl,-force_load,bazel-out/{}-{}/bin/{}test/unit/native_deps/libalwayslink{}.lo".format(darwin_component, compilation_mode, workspace_prefix, pic_suffix),
204        ]
205    elif toolchain.target_os == "windows":
206        if toolchain.target_triple.abi == "msvc":
207            want = [
208                "-lstatic=native_dep",
209                "native_dep.lib",
210                "/WHOLEARCHIVE:bazel-out/x64_windows-{}/bin/{}test/unit/native_deps/alwayslink.lo.lib".format(compilation_mode, workspace_prefix),
211            ]
212        else:
213            want = [
214                "-lstatic=native_dep",
215                "native_dep.lib",
216                "-Wl,--whole-archive",
217                "bazel-out/x64_windows-{}/bin/{}test/unit/native_deps/alwayslink.lo.lib".format(compilation_mode, workspace_prefix),
218                "-Wl,--no-whole-archive",
219            ]
220    elif toolchain.target_arch == "s390x":
221        want = [
222            "-lstatic=native_dep{}".format(pic_suffix),
223            "link-arg=-Wl,--whole-archive",
224            "link-arg=bazel-out/s390x-{}/bin/{}test/unit/native_deps/libalwayslink{}.lo".format(compilation_mode, workspace_prefix, pic_suffix),
225            "link-arg=-Wl,--no-whole-archive",
226        ]
227    else:
228        want = [
229            "-lstatic=native_dep{}".format(pic_suffix),
230            "-lnative_dep{}".format(pic_suffix),
231            "-Wl,--whole-archive",
232            "bazel-out/k8-{}/bin/{}test/unit/native_deps/libalwayslink{}.lo".format(compilation_mode, workspace_prefix, pic_suffix),
233            "-Wl,--no-whole-archive",
234        ]
235    assert_list_contains_adjacent_elements(env, linker_args, want)
236    return analysistest.end(env)
237
238def _get_pic_suffix(ctx, compilation_mode):
239    toolchain = _get_toolchain(ctx)
240    if toolchain.target_os == "darwin" or toolchain.target_os == "windows":
241        return ""
242    return ".pic" if compilation_mode == "opt" else ""
243
244rlib_has_no_native_libs_test = analysistest.make(_rlib_has_no_native_libs_test_impl)
245staticlib_has_native_libs_test = analysistest.make(_staticlib_has_native_libs_test_impl, attrs = {
246    "_toolchain": attr.label(default = Label("//rust/toolchain:current_rust_toolchain")),
247})
248cdylib_has_native_libs_test = analysistest.make(_cdylib_has_native_libs_test_impl, attrs = {
249    "_toolchain": attr.label(default = Label("//rust/toolchain:current_rust_toolchain")),
250})
251proc_macro_has_native_libs_test = analysistest.make(_proc_macro_has_native_libs_test_impl, attrs = {
252    "_toolchain": attr.label(default = Label("//rust/toolchain:current_rust_toolchain")),
253})
254bin_has_native_libs_test = analysistest.make(_bin_has_native_libs_test_impl, attrs = {
255    "_toolchain": attr.label(default = Label("//rust/toolchain:current_rust_toolchain")),
256})
257bin_has_native_dep_and_alwayslink_test = analysistest.make(_bin_has_native_dep_and_alwayslink_test_impl, attrs = {
258    "_toolchain": attr.label(default = Label("//rust/toolchain:current_rust_toolchain")),
259})
260cdylib_has_native_dep_and_alwayslink_test = analysistest.make(_cdylib_has_native_dep_and_alwayslink_test_impl, attrs = {
261    "_toolchain": attr.label(default = Label("//rust/toolchain:current_rust_toolchain")),
262})
263
264def _native_dep_test():
265    rust_library(
266        name = "rlib_has_no_native_dep",
267        srcs = ["lib_using_native_dep.rs"],
268        edition = "2018",
269        deps = [":native_dep"],
270    )
271
272    rust_static_library(
273        name = "staticlib_has_native_dep",
274        srcs = ["lib_using_native_dep.rs"],
275        edition = "2018",
276        deps = [":native_dep"],
277    )
278
279    rust_shared_library(
280        name = "cdylib_has_native_dep",
281        srcs = ["lib_using_native_dep.rs"],
282        edition = "2018",
283        deps = [":native_dep"],
284    )
285
286    rust_proc_macro(
287        name = "proc_macro_has_native_dep",
288        srcs = ["proc_macro_using_native_dep.rs"],
289        edition = "2018",
290        deps = [":native_dep"],
291    )
292
293    rust_binary(
294        name = "bin_has_native_dep",
295        srcs = ["bin_using_native_dep.rs"],
296        edition = "2018",
297        deps = [":native_dep"],
298    )
299
300    rust_binary(
301        name = "bin_has_native_dep_and_alwayslink",
302        srcs = ["bin_using_native_dep.rs"],
303        edition = "2018",
304        deps = [":native_dep", ":alwayslink"],
305    )
306
307    cc_library(
308        name = "native_dep",
309        srcs = ["native_dep.cc"],
310        visibility = ["//test/unit:__subpackages__"],
311    )
312
313    cc_library(
314        name = "alwayslink",
315        srcs = ["alwayslink.cc"],
316        alwayslink = 1,
317    )
318
319    rust_shared_library(
320        name = "cdylib_has_native_dep_and_alwayslink",
321        srcs = ["lib_using_native_dep.rs"],
322        edition = "2018",
323        deps = [":native_dep", ":alwayslink"],
324    )
325
326    rlib_has_no_native_libs_test(
327        name = "rlib_has_no_native_libs_test",
328        target_under_test = ":rlib_has_no_native_dep",
329    )
330    staticlib_has_native_libs_test(
331        name = "staticlib_has_native_libs_test",
332        target_under_test = ":staticlib_has_native_dep",
333    )
334    cdylib_has_native_libs_test(
335        name = "cdylib_has_native_libs_test",
336        target_under_test = ":cdylib_has_native_dep",
337    )
338    proc_macro_has_native_libs_test(
339        name = "proc_macro_has_native_libs_test",
340        target_under_test = ":proc_macro_has_native_dep",
341    )
342    bin_has_native_libs_test(
343        name = "bin_has_native_libs_test",
344        target_under_test = ":bin_has_native_dep",
345    )
346    bin_has_native_dep_and_alwayslink_test(
347        name = "bin_has_native_dep_and_alwayslink_test",
348        target_under_test = ":bin_has_native_dep_and_alwayslink",
349    )
350    cdylib_has_native_dep_and_alwayslink_test(
351        name = "cdylib_has_native_dep_and_alwayslink_test",
352        target_under_test = ":cdylib_has_native_dep_and_alwayslink",
353    )
354
355def _linkopts_propagate_test_impl(ctx):
356    env = analysistest.begin(ctx)
357    tut = analysistest.target_under_test(env)
358    action = tut.actions[0]
359
360    # Ensure linkopts from direct (-Llinkoptdep1) and transitive
361    # (-Llinkoptdep2) dependencies are propagated.
362    # Consistently with cc rules, dependency linkopts take precedence over
363    # dependent linkopts (i.e. dependency linkopts appear later in the command
364    # line).
365
366    linkopt_args = _extract_linker_args(action.argv)
367    assert_list_contains_adjacent_elements(
368        env,
369        linkopt_args,
370        ["-Llinkoptdep1", "-Llinkoptdep2"],
371    )
372    return analysistest.end(env)
373
374linkopts_propagate_test = analysistest.make(_linkopts_propagate_test_impl)
375
376def _linkopts_test():
377    rust_binary(
378        name = "linkopts_rust_bin",
379        srcs = ["bin_using_native_dep.rs"],
380        edition = "2018",
381        deps = [":linkopts_native_dep_a"],
382    )
383
384    cc_library(
385        name = "linkopts_native_dep_a",
386        srcs = ["native_dep.cc"],
387        linkopts = ["-Llinkoptdep1"],
388        deps = [":linkopts_native_dep_b"],
389    )
390
391    cc_library(
392        name = "linkopts_native_dep_b",
393        linkopts = ["-Llinkoptdep2"],
394    )
395
396    linkopts_propagate_test(
397        name = "native_linkopts_propagate_test",
398        target_under_test = ":linkopts_rust_bin",
399    )
400
401def _check_additional_deps_test_impl(ctx, expect_additional_deps):
402    env = analysistest.begin(ctx)
403    tut = analysistest.target_under_test(env)
404    action = tut.actions[0]
405    additional_inputs = [inp.basename for inp in action.inputs.to_list()]
406    asserts.equals(env, "dynamic.lds" in additional_inputs, expect_additional_deps)
407    return analysistest.end(env)
408
409def _has_additional_deps_test_impl(ctx):
410    return _check_additional_deps_test_impl(ctx, expect_additional_deps = True)
411
412def _has_no_additional_deps_test_impl(ctx):
413    return _check_additional_deps_test_impl(ctx, expect_additional_deps = False)
414
415has_additional_deps_test = analysistest.make(_has_additional_deps_test_impl)
416has_no_additional_deps_test = analysistest.make(_has_no_additional_deps_test_impl)
417
418def _additional_deps_test():
419    rust_binary(
420        name = "bin_additional_deps",
421        srcs = ["bin_using_native_dep.rs"],
422        edition = "2018",
423        deps = [":additional_deps_cc"],
424    )
425
426    rust_shared_library(
427        name = "cdylib_additional_deps",
428        srcs = ["lib_using_native_dep.rs"],
429        edition = "2018",
430        deps = [":additional_deps_cc"],
431    )
432
433    rust_library(
434        name = "lib_additional_deps",
435        srcs = ["lib_using_native_dep.rs"],
436        edition = "2018",
437        deps = ["additional_deps_cc"],
438    )
439
440    cc_library(
441        name = "additional_deps_cc",
442        srcs = ["native_dep.cc"],
443        linkopts = ["-L$(execpath :dynamic.lds)"],
444        deps = [":dynamic.lds"],
445    )
446
447    has_additional_deps_test(
448        name = "bin_has_additional_deps_test",
449        target_under_test = ":bin_additional_deps",
450    )
451
452    has_additional_deps_test(
453        name = "cdylib_has_additional_deps_test",
454        target_under_test = ":cdylib_additional_deps",
455    )
456
457    has_no_additional_deps_test(
458        name = "lib_has_no_additional_deps_test",
459        target_under_test = ":lib_additional_deps",
460    )
461
462def native_deps_test_suite(name):
463    """Entry-point macro called from the BUILD file.
464
465    Args:
466        name: Name of the macro.
467    """
468    _native_dep_test()
469    _linkopts_test()
470    _additional_deps_test()
471
472    native.test_suite(
473        name = name,
474        tests = [
475            ":bin_has_additional_deps_test",
476            ":bin_has_native_dep_and_alwayslink_test",
477            ":bin_has_native_libs_test",
478            ":cdylib_has_additional_deps_test",
479            ":cdylib_has_native_dep_and_alwayslink_test",
480            ":cdylib_has_native_libs_test",
481            ":lib_has_no_additional_deps_test",
482            ":native_linkopts_propagate_test",
483            ":proc_macro_has_native_libs_test",
484            ":rlib_has_no_native_libs_test",
485            ":staticlib_has_native_libs_test",
486        ],
487    )