fork/rust

git clone https://git.julia.blue/fork/rust

borsAuto merge of #67350 - Mark-Simulacrum:stable-next, r=Mark-Simulacrum73528e339aa

1.40.0
9.3 KiB312 linesraw
1/*  This symbol is used at runtime to figure out the virtual address that the */
2/*  enclave is loaded at. */
3.section absolute
4.global IMAGE_BASE
5IMAGE_BASE:
6
7.section ".note.x86_64-fortanix-unknown-sgx", "", @note
8    .align 4
9    .long 1f - 0f              /* name length (not including padding) */
10    .long 3f - 2f              /* desc length (not including padding) */
11    .long 1                    /* type = NT_VERSION */
120:  .asciz "toolchain-version" /* name */
131:  .align 4
142:  .long 0                    /* desc - toolchain version number, 32-bit LE */
153:  .align 4
16
17.section .rodata
18/*  The XSAVE area needs to be a large chunk of readable memory, but since we are */
19/*  going to restore everything to its initial state (XSTATE_BV=0), only certain */
20/*  parts need to have a defined value. In particular: */
21/*  */
22/*    * MXCSR in the legacy area. This register is always restored if RFBM[1] or */
23/*      RFBM[2] is set, regardless of the value of XSTATE_BV */
24/*    * XSAVE header */
25.align 64
26.Lxsave_clear:
27.org .+24
28.Lxsave_mxcsr:
29    .int 0
30
31/*  We can store a bunch of data in the gap between MXCSR and the XSAVE header */
32
33/*  The following symbols point at read-only data that will be filled in by the */
34/*  post-linker. */
35
36/*  When using this macro, don't forget to adjust the linker version script! */
37.macro globvar name:req size:req
38    .global \name
39    .protected \name
40    .align \size
41    .size \name , \size
42    \name :
43        .org .+\size
44.endm
45    /*  The base address (relative to enclave start) of the heap area */
46    globvar HEAP_BASE 8
47    /*  The heap size in bytes */
48    globvar HEAP_SIZE 8
49    /*  Value of the RELA entry in the dynamic table */
50    globvar RELA 8
51    /*  Value of the RELACOUNT entry in the dynamic table */
52    globvar RELACOUNT 8
53    /*  The enclave size in bytes */
54    globvar ENCLAVE_SIZE 8
55    /*  The base address (relative to enclave start) of the enclave configuration area */
56    globvar CFGDATA_BASE 8
57    /*  Non-zero if debugging is enabled, zero otherwise */
58    globvar DEBUG 1
59    /*  The base address (relative to enclave start) of the enclave text section */
60    globvar TEXT_BASE 8
61    /*  The size in bytes of enclacve text section */
62    globvar TEXT_SIZE 8
63    /*  The base address (relative to enclave start) of the enclave EH_FRM_HDR section */
64    globvar EH_FRM_HDR_BASE 8
65    /*  The size in bytes of enclacve EH_FRM_HDR section */
66    globvar EH_FRM_HDR_SIZE 8
67
68.org .Lxsave_clear+512
69.Lxsave_header:
70    .int 0, 0 /*  XSTATE_BV */
71    .int 0, 0 /*  XCOMP_BV */
72    .org .+48 /*  reserved bits */
73
74.data
75.Laborted:
76    .byte 0
77
78/*  TCS local storage section */
79.equ tcsls_tos,                 0x00 /*  initialized by loader to *offset* from image base to TOS */
80.equ tcsls_flags,               0x08 /*  initialized by loader */
81.equ tcsls_flag_secondary,      0    /*  initialized by loader; 0 = standard TCS, 1 = secondary TCS */
82.equ tcsls_flag_init_once,      1    /*  initialized by loader to 0 */
83/*  14 unused bits */
84.equ tcsls_user_fcw,            0x0a
85.equ tcsls_user_mxcsr,          0x0c
86.equ tcsls_last_rsp,            0x10 /*  initialized by loader to 0 */
87.equ tcsls_panic_last_rsp,      0x18 /*  initialized by loader to 0 */
88.equ tcsls_debug_panic_buf_ptr, 0x20 /*  initialized by loader to 0 */
89.equ tcsls_user_rsp,            0x28
90.equ tcsls_user_retip,          0x30
91.equ tcsls_user_rbp,            0x38
92.equ tcsls_user_r12,            0x40
93.equ tcsls_user_r13,            0x48
94.equ tcsls_user_r14,            0x50
95.equ tcsls_user_r15,            0x58
96.equ tcsls_tls_ptr,             0x60
97.equ tcsls_tcs_addr,            0x68
98
99.macro load_tcsls_flag_secondary_bool reg:req comments:vararg
100    .ifne tcsls_flag_secondary /* to convert to a bool, must be the first bit */
101    .abort
102    .endif
103        mov $(1<<tcsls_flag_secondary),%e\reg
104        and %gs:tcsls_flags,%\reg
105.endm
106
107.text
108.global sgx_entry
109.type sgx_entry,function
110sgx_entry:
111/*  save user registers */
112    mov %rcx,%gs:tcsls_user_retip
113    mov %rsp,%gs:tcsls_user_rsp
114    mov %rbp,%gs:tcsls_user_rbp
115    mov %r12,%gs:tcsls_user_r12
116    mov %r13,%gs:tcsls_user_r13
117    mov %r14,%gs:tcsls_user_r14
118    mov %r15,%gs:tcsls_user_r15
119    mov %rbx,%gs:tcsls_tcs_addr
120    stmxcsr %gs:tcsls_user_mxcsr
121    fnstcw %gs:tcsls_user_fcw
122
123/*  reset user state */
124/*    - DF flag: x86-64 ABI requires DF to be unset at function entry/exit */
125/*    - AC flag: AEX on misaligned memory accesses leaks side channel info */
126    pushfq
127    andq $~0x40400, (%rsp)
128    popfq
129
130/*  check for debug buffer pointer */
131    testb  $0xff,DEBUG(%rip)
132    jz .Lskip_debug_init
133    mov %r10,%gs:tcsls_debug_panic_buf_ptr
134.Lskip_debug_init:
135/*  check for abort */
136    bt $0,.Laborted(%rip)
137    jc .Lreentry_panic
138/*  check if returning from usercall */
139    mov %gs:tcsls_last_rsp,%r11
140    test %r11,%r11
141    jnz .Lusercall_ret
142/*  setup stack */
143    mov %gs:tcsls_tos,%rsp /*  initially, RSP is not set to the correct value */
144                           /*  here. This is fixed below under "adjust stack". */
145/*  check for thread init */
146    bts $tcsls_flag_init_once,%gs:tcsls_flags
147    jc .Lskip_init
148/*  adjust stack */
149    lea IMAGE_BASE(%rip),%rax
150    add %rax,%rsp
151    mov %rsp,%gs:tcsls_tos
152/*  call tcs_init */
153/*  store caller-saved registers in callee-saved registers */
154    mov %rdi,%rbx
155    mov %rsi,%r12
156    mov %rdx,%r13
157    mov %r8,%r14
158    mov %r9,%r15
159    load_tcsls_flag_secondary_bool di /* RDI = tcs_init() argument: secondary: bool */
160    call tcs_init
161/*  reload caller-saved registers */
162    mov %rbx,%rdi
163    mov %r12,%rsi
164    mov %r13,%rdx
165    mov %r14,%r8
166    mov %r15,%r9
167.Lskip_init:
168/*  call into main entry point */
169    load_tcsls_flag_secondary_bool cx /* RCX = entry() argument: secondary: bool */
170    call entry /* RDI, RSI, RDX, R8, R9 passed in from userspace */
171    mov %rax,%rsi  /* RSI = return value */
172    /* NOP: mov %rdx,%rdx */ /*  RDX = return value */
173    xor %rdi,%rdi  /* RDI = normal exit */
174.Lexit:
175/*  clear general purpose register state */
176    /*  RAX overwritten by ENCLU */
177    /*  RBX set later */
178    /*  RCX overwritten by ENCLU */
179    /*  RDX contains return value */
180    /*  RSP set later */
181    /*  RBP set later */
182    /*  RDI contains exit mode */
183    /*  RSI contains return value */
184    xor %r8,%r8
185    xor %r9,%r9
186    xor %r10,%r10
187    xor %r11,%r11
188    /*  R12 ~ R15 set by sgx_exit */
189.Lsgx_exit:
190/*  clear extended register state */
191    mov %rdx, %rcx /*  save RDX */
192    mov $-1, %rax
193    mov %rax, %rdx
194    xrstor .Lxsave_clear(%rip)
195    mov %rcx, %rdx /*  restore RDX */
196/*  clear flags */
197    pushq $0
198    popfq
199/*  restore user registers */
200    mov %gs:tcsls_user_r12,%r12
201    mov %gs:tcsls_user_r13,%r13
202    mov %gs:tcsls_user_r14,%r14
203    mov %gs:tcsls_user_r15,%r15
204    mov %gs:tcsls_user_retip,%rbx
205    mov %gs:tcsls_user_rsp,%rsp
206    mov %gs:tcsls_user_rbp,%rbp
207    fldcw %gs:tcsls_user_fcw
208    ldmxcsr %gs:tcsls_user_mxcsr
209/*  exit enclave */
210    mov $0x4,%eax /*  EEXIT */
211    enclu
212/*  end sgx_entry */
213
214.Lreentry_panic:
215    orq $8,%rsp
216    jmp abort_reentry
217
218/*  This *MUST* be called with 6 parameters, otherwise register information */
219/*  might leak! */
220.global usercall
221usercall:
222    test %rcx,%rcx            /* check `abort` function argument */
223    jnz .Lusercall_abort      /* abort is set, jump to abort code (unlikely forward conditional) */
224    jmp .Lusercall_save_state /* non-aborting usercall */
225.Lusercall_abort:
226/* set aborted bit */
227    movb $1,.Laborted(%rip)
228/* save registers in DEBUG mode, so that debugger can reconstruct the stack */
229    testb $0xff,DEBUG(%rip)
230    jz .Lusercall_noreturn
231.Lusercall_save_state:
232/*  save callee-saved state */
233    push %r15
234    push %r14
235    push %r13
236    push %r12
237    push %rbp
238    push %rbx
239    sub $8, %rsp
240    fstcw 4(%rsp)
241    stmxcsr (%rsp)
242    movq %rsp,%gs:tcsls_last_rsp
243.Lusercall_noreturn:
244/*  clear general purpose register state */
245    /*  RAX overwritten by ENCLU */
246    /*  RBX set by sgx_exit */
247    /*  RCX overwritten by ENCLU */
248    /*  RDX contains parameter */
249    /*  RSP set by sgx_exit */
250    /*  RBP set by sgx_exit */
251    /*  RDI contains parameter */
252    /*  RSI contains parameter */
253    /*  R8 contains parameter */
254    /*  R9 contains parameter */
255    xor %r10,%r10
256    xor %r11,%r11
257    /*  R12 ~ R15 set by sgx_exit */
258/*  extended registers/flags cleared by sgx_exit */
259/*  exit */
260    jmp .Lsgx_exit
261.Lusercall_ret:
262    movq $0,%gs:tcsls_last_rsp
263/*  restore callee-saved state, cf. "save" above */
264    mov %r11,%rsp
265    ldmxcsr (%rsp)
266    fldcw 4(%rsp)
267    add $8, %rsp
268    pop %rbx
269    pop %rbp
270    pop %r12
271    pop %r13
272    pop %r14
273    pop %r15
274/*  return */
275    mov %rsi,%rax /*  RAX = return value */
276    /* NOP: mov %rdx,%rdx */ /*  RDX = return value */
277    ret
278
279/*
280The following functions need to be defined externally:
281```
282// Called by entry code on re-entry after exit
283extern "C" fn abort_reentry() -> !;
284
285// Called once when a TCS is first entered
286extern "C" fn tcs_init(secondary: bool);
287
288// Standard TCS entrypoint
289extern "C" fn entry(p1: u64, p2: u64, p3: u64, secondary: bool, p4: u64, p5: u64) -> (u64, u64);
290```
291*/
292
293.global get_tcs_addr
294get_tcs_addr:
295    mov %gs:tcsls_tcs_addr,%rax
296    ret
297
298.global get_tls_ptr
299get_tls_ptr:
300    mov %gs:tcsls_tls_ptr,%rax
301    ret
302
303.global set_tls_ptr
304set_tls_ptr:
305    mov %rdi,%gs:tcsls_tls_ptr
306    ret
307
308.global take_debug_panic_buf_ptr
309take_debug_panic_buf_ptr:
310    xor %rax,%rax
311    xchg %gs:tcsls_debug_panic_buf_ptr,%rax
312    ret