fork/rust

git clone https://git.julia.blue/fork/rust

borsAuto merge of #68568 - pietroalbini:stable-next, r=pietroalbini5e1a799842b

1.41.0
2.6 KiB87 linesraw
1#define CFG_RELEASE_NUM GetEnv("CFG_RELEASE_NUM")
2#define CFG_RELEASE GetEnv("CFG_RELEASE")
3#define CFG_PACKAGE_NAME GetEnv("CFG_PACKAGE_NAME")
4#define CFG_BUILD GetEnv("CFG_BUILD")
5
6[Setup]
7
8SetupIconFile=rust-logo.ico
9AppName=Rust
10AppVersion={#CFG_RELEASE}
11AppCopyright=Copyright (C) 2006-2014 Mozilla Foundation, MIT license
12AppPublisher=Mozilla Foundation
13AppPublisherURL=http://www.rust-lang.org
14VersionInfoVersion={#CFG_RELEASE_NUM}
15LicenseFile=LICENSE.txt
16
17PrivilegesRequired=lowest
18DisableWelcomePage=true
19DisableProgramGroupPage=true
20DisableReadyPage=true
21DisableStartupPrompt=true
22
23OutputDir=.\
24SourceDir=.\
25OutputBaseFilename={#CFG_PACKAGE_NAME}-{#CFG_BUILD}
26DefaultDirName={sd}\Rust
27
28Compression=lzma2/normal
29InternalCompressLevel=normal
30SolidCompression=no
31
32ChangesEnvironment=true
33ChangesAssociations=no
34AllowUNCPath=false
35AllowNoIcons=true
36Uninstallable=yes
37
38[Tasks]
39Name: modifypath; Description: &Add {app}\bin to your PATH (recommended)
40
41[Components]
42Name: rust; Description: "Rust compiler and standard crates"; Types: full compact custom; Flags: fixed
43#ifdef MINGW
44Name: gcc; Description: "Linker and platform libraries"; Types: full
45#endif
46Name: docs; Description: "HTML documentation"; Types: full
47Name: cargo; Description: "Cargo, the Rust package manager"; Types: full
48Name: std; Description: "The Rust Standard Library"; Types: full
49// tool-rls-start
50Name: rls; Description: "RLS, the Rust Language Server"
51// tool-rls-end
52
53[Files]
54Source: "rustc/*.*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs; Components: rust
55#ifdef MINGW
56Source: "rust-mingw/*.*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs; Components: gcc
57#endif
58Source: "rust-docs/*.*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs; Components: docs
59Source: "cargo/*.*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs; Components: cargo
60Source: "rust-std/*.*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs; Components: std
61// tool-rls-start
62Source: "rls/*.*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs; Components: rls
63Source: "rust-analysis/*.*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs; Components: rls
64// tool-rls-end
65
66[Code]
67const
68	ModPathName = 'modifypath';
69	ModPathType = 'user';
70
71function ModPathDir(): TArrayOfString;
72begin
73	setArrayLength(Result, 1)
74	Result[0] := ExpandConstant('{app}\bin');
75end;
76
77#include "modpath.iss"
78#include "upgrade.iss"
79
80// Both modpath.iss and upgrade.iss want to overload CurStepChanged.
81// This version does the overload then delegates to each.
82
83procedure CurStepChanged(CurStep: TSetupStep);
84begin
85  UpgradeCurStepChanged(CurStep);
86  ModPathCurStepChanged(CurStep);
87end;