fork/slippi-nix

git clone https://git.julia.blue/fork/slippi-nix

Julia RyanCreate mime type for slippi files0da163f

xdg-mime
7.3 KiB229 linesraw
1{
2  lib,
3  pkgs,
4  config,
5  ...
6}:
7let
8  hashes = import ../../hashes.nix;
9  inherit (lib)
10    mkEnableOption
11    mkOption
12    types
13    mkIf
14    ;
15  cfg = config.slippi-launcher;
16  netplay-beta-package =
17    version: hash:
18    pkgs.callPackage ../../packages/slippi-netplay-beta.nix {
19      inherit version hash;
20    };
21  netplay-package =
22    version: hash:
23    pkgs.callPackage ../../packages/slippi-netplay.nix {
24      inherit version hash;
25    };
26  playback-package =
27    version: hash:
28    pkgs.callPackage ../../packages/slippi-playback.nix {
29      inherit version hash;
30    };
31  launcher-package =
32    version: hash:
33    pkgs.callPackage ../../packages/slippi-launcher.nix {
34      inherit version hash;
35    };
36in
37{
38  options.slippi-launcher = {
39    enable = mkEnableOption "Install Slippi Launcher" // {
40      default = true;
41    };
42
43    netplayVersion = mkOption {
44      default = hashes.netplay.version;
45      type = types.str;
46      description = "The version of Slippi Netplay to install.";
47    };
48    netplayHash = mkOption {
49      default = hashes.netplay.hash;
50      type = types.str;
51      description = "The hash of the Slippi Netplay AppImage to install.";
52    };
53
54    netplayBetaVersion = mkOption {
55      default = hashes.netplay-beta.version;
56      type = types.str;
57      description = "The version of Slippi Netplay (Mainline beta) to install.";
58    };
59    netplayBetaHash = mkOption {
60      default = hashes.netplay-beta.hash;
61      type = types.str;
62      description = "The hash of the Slippi Netplay (Mainline beta) AppImage to install.";
63    };
64
65    playbackVersion = mkOption {
66      default = hashes.playback.version;
67      type = types.str;
68      description = "The version of Slippi Playback to install.";
69    };
70    playbackHash = mkOption {
71      default = hashes.playback.hash;
72      type = types.str;
73      description = "The hash of the Slippi Playback AppImage to install.";
74    };
75
76    launcherVersion = mkOption {
77      default = hashes.launcher.version;
78      type = types.str;
79      description = "The version of Slippi Launcher to install.";
80    };
81    launcherHash = mkOption {
82      default = hashes.launcher.hash;
83      type = types.str;
84      description = "The hash of the Slippi Launcher AppImage to install.";
85    };
86
87    isoPath = mkOption {
88      default = "";
89      type = types.str;
90      description = "The path to an NTSC Melee ISO.";
91    };
92    useNetplayBeta = mkEnableOption "Use the mainline Dolphin instead of the stable version." // {
93      default = false;
94    };
95
96    launchMeleeOnPlay = mkEnableOption "Launch Melee in Dolphin when the Play button is pressed." // {
97      default = true;
98    };
99
100    enableJukebox =
101      mkEnableOption "Enable in-game music via Slippi Jukebox. Incompatible with WASAPI."
102      // {
103        default = true;
104      };
105
106    rootSlpPath = mkOption {
107      default = "${config.home.homeDirectory}/Slippi";
108      type = types.str;
109      description = "The folder where your SLP replays should be saved.";
110    };
111
112    useMonthlySubfolders = mkEnableOption "Save replays to monthly subfolders";
113
114    spectateSlpPath = mkOption {
115      default = "${cfg.rootSlpPath}/Spectate";
116      type = types.nullOr types.str;
117      description = "The folder where spectated games should be saved.";
118    };
119
120    extraSlpPaths = mkOption {
121      default = [ ];
122      type = types.listOf types.str;
123      description = "Choose any additional SLP directories that should show up in the replay browser.";
124    };
125  };
126  config = mkIf cfg.enable (
127    let
128      cfgNetplayPackage = netplay-package cfg.netplayVersion cfg.netplayHash;
129      cfgNetplayBetaPackage = netplay-beta-package cfg.netplayBetaVersion cfg.netplayBetaHash;
130      cfgPlaybackPackage = playback-package cfg.playbackVersion cfg.playbackHash;
131      cfgLauncherPackage = launcher-package cfg.launcherVersion cfg.launcherHash;
132    in
133    {
134      home.packages = [ cfgLauncherPackage ];
135      home.file.".config/Slippi Launcher/netplay/Slippi_Online-x86_64.AppImage" = {
136        source = "${lib.getExe cfgNetplayPackage}";
137        recursive = false;
138      };
139      home.file.".config/Slippi Launcher/netplay/Sys" = {
140        source = "${cfgNetplayPackage.raw-zip}/Sys";
141        recursive = false;
142      };
143      home.file.".config/Slippi Launcher/netplay-beta/Slippi_Netplay_Mainline-x86_64.AppImage" = {
144        source = "${lib.getExe cfgNetplayBetaPackage}";
145        recursive = false;
146      };
147      home.file.".config/Slippi Launcher/netplay-beta/Sys" = {
148        source = "${cfgNetplayBetaPackage.raw-zip}/Sys";
149        recursive = false;
150      };
151      home.file.".config/Slippi Launcher/playback/Slippi_Playback-x86_64.AppImage" = {
152        source = "${lib.getExe cfgPlaybackPackage}";
153        recursive = false;
154      };
155      home.file.".config/Slippi Launcher/playback/Sys" = {
156        source = "${cfgPlaybackPackage.raw-zip}/Sys";
157        recursive = false;
158      };
159
160      xdg = {
161        mimeApps.defaultApplications = {
162          "application/x-slippi" = "slippi-launcher.desktop";
163        };
164        dataFile."mime/packages/x-slippi.xml".text = ''
165          <?xml version="1.0" encoding="UTF-8"?>
166          <mime-info xmlns="http://www.freedesktop.org/standards/shared-mime-info">
167            <mime-type type="application/x-slippi">
168              <comment>Slippi Replay</comment>
169              <glob pattern="*.slp"/>
170              <icon name="slippi-launcher"/>
171            </mime-type>
172          </mime-info>
173        '';
174      };
175
176      # Use an activation script instead of xdg.configFile so the settings
177      # file is mutable. The launcher needs to write to it (e.g. login
178      # credentials). Nix-managed settings are merged on each activation,
179      # preserving any extra keys the launcher has written.
180      home.activation.slippiLauncherSettings =
181        let
182          jsonFormat = pkgs.formats.json { };
183          settingsFile = jsonFormat.generate "slippi-config" {
184            settings = {
185              isoPath = cfg.isoPath;
186
187              launchMeleeOnPlay = cfg.launchMeleeOnPlay;
188              enableJukebox = cfg.enableJukebox;
189              useNetplayBeta = cfg.useNetplayBeta;
190
191              rootSlpPath = cfg.rootSlpPath;
192              useMonthlySubfolders = cfg.useMonthlySubfolders;
193              spectateSlpPath = cfg.spectateSlpPath;
194              extraSlpPaths = cfg.extraSlpPaths;
195
196              netplayDolphinPath = "${
197                if cfg.useNetplayBeta then cfgNetplayBetaPackage else cfgNetplayPackage
198              }/bin/";
199              playbackDolphinPath = "${cfgPlaybackPackage}/bin/";
200
201              autoUpdateLauncher = false;
202            };
203          };
204        in
205        lib.hm.dag.entryAfter [ "writeBoundary" ] ''
206          slippi_dir="${config.xdg.configHome}/Slippi Launcher"
207          slippi_settings="$slippi_dir/Settings"
208
209          mkdir -p "$slippi_dir"
210
211          # Remove stale symlink from previous module version
212          if [ -L "$slippi_settings" ]; then
213            rm "$slippi_settings"
214          fi
215
216          if [ -f "$slippi_settings" ]; then
217            # Merge existing settings with Nix-managed settings (Nix wins on conflicts)
218            ${pkgs.jq}/bin/jq -s '.[0] * .[1]' \
219              "$slippi_settings" \
220              "${settingsFile}" > "$slippi_settings.tmp"
221            mv "$slippi_settings.tmp" "$slippi_settings"
222          else
223            cp "${settingsFile}" "$slippi_settings"
224            chmod u+w "$slippi_settings"
225          fi
226        '';
227    }
228  );
229}