fork/slippi-nix

git clone https://git.julia.blue/fork/slippi-nix

Daniel FlanaganMerge pull request #34 from lytedev/standalone-launchera561543

xdg-mime
2.0 KiB61 linesraw
1# A wrapped slippi-launcher that works standalone (without the Home Manager
2# module) by seeding the config directory with correct Dolphin paths and
3# AppImage symlinks on each launch.
4{
5  lib,
6  writeShellApplication,
7  jq,
8  slippi-launcher,
9  slippi-netplay,
10  slippi-netplay-beta,
11  slippi-playback,
12  formats,
13}:
14let
15  managedSettings = (formats.json { }).generate "slippi-managed-settings" {
16    settings = {
17      netplayDolphinPath = "${slippi-netplay}/bin/";
18      playbackDolphinPath = "${slippi-playback}/bin/";
19      autoUpdateLauncher = false;
20    };
21  };
22in
23writeShellApplication {
24  name = "slippi-launcher";
25  runtimeInputs = [ jq ];
26  text = ''
27    slippi_dir="''${XDG_CONFIG_HOME:-$HOME/.config}/Slippi Launcher"
28    settings="$slippi_dir/Settings"
29
30    mkdir -p "$slippi_dir/netplay" "$slippi_dir/netplay-beta" "$slippi_dir/playback"
31
32    # Symlink Nix-wrapped AppImages and Sys directories so the launcher
33    # can detect versions and Dolphin can find its system files.
34    ln -sfn ${lib.getExe slippi-netplay} "$slippi_dir/netplay/Slippi_Online-x86_64.AppImage"
35    ln -sfn ${slippi-netplay.raw-zip}/Sys "$slippi_dir/netplay/Sys"
36    ln -sfn ${lib.getExe slippi-netplay-beta} "$slippi_dir/netplay-beta/Slippi_Netplay_Mainline-x86_64.AppImage"
37    ln -sfn ${slippi-netplay-beta.raw-zip}/Sys "$slippi_dir/netplay-beta/Sys"
38    ln -sfn ${lib.getExe slippi-playback} "$slippi_dir/playback/Slippi_Playback-x86_64.AppImage"
39    ln -sfn ${slippi-playback.raw-zip}/Sys "$slippi_dir/playback/Sys"
40
41    # Remove stale symlink from older module versions
42    if [ -L "$settings" ]; then
43      rm "$settings"
44    fi
45
46    if [ -f "$settings" ]; then
47      # Merge Nix-managed settings on top of existing (Nix paths win)
48      jq -s '.[0] * .[1]' "$settings" ${managedSettings} > "$settings.tmp"
49      mv "$settings.tmp" "$settings"
50    else
51      cp ${managedSettings} "$settings"
52      chmod u+w "$settings"
53    fi
54
55    exec ${lib.getExe slippi-launcher} "$@"
56  '';
57
58  meta = slippi-launcher.meta // {
59    description = "Slippi Launcher (standalone, pre-configured for NixOS)";
60  };
61}