fork/training-mode-ce

git clone https://git.julia.blue/fork/training-mode-ce

AitchMerge pull request #237 from NickCondron/memcard-asm9280fdf

master
1.3 KiB48 linesraw
1    # To be inserted at 80266ce0
2    .include "../Globals.s"
3
4#######################################
5## Runs During CSS -> SSS Transition ##
6#######################################
7
8    .set REG_RandomStageField, 5
9    .set REG_RulesPointer, 6
10
11    # Ensure only all other legal stages are enabled
12    # Get Random Stage Select Bitflags
13    lwz REG_RulesPointer, MemcardData(r13)
14    addi REG_RulesPointer, REG_RulesPointer, 7344
15    lwz REG_RandomStageField, 0x18(REG_RulesPointer)
16    # Check if only all legal stages are on
17    load r3, 0xE70000B0
18    xor. r3, r3, REG_RandomStageField
19    beq CheckForTeams
20    # Check if the only other stage off is FoD
21    cmpwi r3, 0x20
22    beq CheckForTeams
23    b Exit
24
25CheckForTeams:
26    # Get Teams On/Off Bool
27    lwz r3, -0x49F0(r13)
28    lbz r3, 0x18(r3)
29    # Check If Teams is On or Off
30    cmpwi r3, 0x1
31    beq Doubles
32
33Singles:
34    # Flip FoD Bit On in Random Stage Bitflag (FoD is bit #26)
35    li r3, 0x1
36    rlwimi REG_RandomStageField, r3, 5, 26, 26
37    stw REG_RandomStageField, 0x18(REG_RulesPointer)
38    b Exit
39
40Doubles:
41    # Flip FoD Bit Off in Random Stage Bitflag (FoD is bit #26)
42    li r3, 0x0
43    rlwimi REG_RandomStageField, r3, 5, 26, 26
44    stw REG_RandomStageField, 0x18(REG_RulesPointer)
45    b Exit
46
47Exit:
48    li r3, 1