fork/training-mode-ce

git clone https://git.julia.blue/fork/training-mode-ce

AitchMerge pull request #243 from NickCondron/remove-asmf9241ee

master
11.6 KiB473 linesraw
1    # To be inserted at 801bf930
2    .include "../../Globals.s"
3
4    # Parameters
5    .set PromptSceneID, 8           # 0
6    .set ExitSceneID, 40
7    .set PromptCommonSceneID, 10
8    .set InitialSelection, 0
9    # Function Addresses
10    .set PostRetraceCallback, 0x800195fc
11    .set UnkPadStruct, 0x804329f0
12    .set REG_MinorSceneStruct, 31
13
14    # Init and backup
15    backup
16
17    # Init LagPrompt major struct
18    li r3, PromptSceneID
19    bl LagPrompt_MinorSceneStruct
20    mflr r4
21    bl LagPrompt_SceneLoad
22    mflr r5
23    bl InitializeMajorSceneStruct
24    # Override LagPrompt SceneLoad
25    li r3, PromptCommonSceneID
26    branchl r12, 0x801a4ce0
27    bl LagPrompt_SceneLoad
28    mflr r4
29    stw r4, 0x8(r3)
30    b CheckProgressive
31
32PointerConvert:
33    lwz r4, 0x0(r3)                 # Load bl instruction
34    rlwinm r5, r4, 8, 25, 29        # extract opcode bits
35    cmpwi r5, 0x48                  # if not a bl instruction, exit
36    bne PointerConvert_Exit
37    rlwinm r4, r4, 0, 6, 29         # extract offset bits
38    extsh r4, r4
39    add r4, r4, r3
40    stw r4, 0x0(r3)
41
42PointerConvert_Exit:
43    blr
44
45InitializeMajorSceneStruct:
46    .set REG_MajorScene, 31
47    .set REG_MinorStruct, 30
48    .set REG_SceneLoad, 29
49
50    # Init
51    backup
52    mr REG_MajorScene, r3
53    mr REG_MinorStruct, r4
54    mr REG_SceneLoad, r5
55
56    # Get major scene struct
57    branchl r12, 0x801a50ac
58
59GetMajorStruct_Loop:
60    lbz r4, 0x0001(r3)
61    cmpw r4, REG_MajorScene
62    beq GetMajorStruct_Exit
63    addi r3, r3, 20
64    b GetMajorStruct_Loop
65
66GetMajorStruct_Exit:
67InitMinorSceneStruct:
68    .set REG_MinorStructParse, 20
69    stw REG_MinorStruct, 0x10(r3)
70    mr REG_MinorStructParse, REG_MinorStruct
71
72InitMinorSceneStruct_Loop:
73    # Check if valid entry
74    lbz r3, 0x0(REG_MinorStructParse)
75    extsb r3, r3
76    cmpwi r3, -1
77    beq InitMinorSceneStruct_Exit
78    # Convert Pointers
79    addi r3, REG_MinorStructParse, 0x4
80    bl PointerConvert
81    addi r3, REG_MinorStructParse, 0x8
82    bl PointerConvert
83    addi REG_MinorStructParse, REG_MinorStructParse, 0x18
84    b InitMinorSceneStruct_Loop
85
86InitMinorSceneStruct_Exit:
87    restore
88    blr
89
90############################################
91
92LagPrompt_SceneLoad_TextProperties:
93    blrl
94    .set PromptX, 0x0
95    .set PromptY, 0x4
96    .set ZOffset, 0x8
97    .set CanvasScaling, 0xC
98    .set Scale, 0x10
99    .set YesX, 0x14
100    .set YesY, 0x18
101    .set YesScale, 0x1C
102    .set NoX, 0x20
103    .set NoY, 0x24
104    .set NoScale, 0x28
105    .set HighlightColor, 0x2C
106    .set NonHighlightColor, 0x30
107    .float 315                      # REG_TextGObj X pos
108    .float 200                      # REG_TextGObj Y pos
109    .float 0                        # Z offset
110    .float 1                        # Canvas Scaling
111    .float 1                        # Text scale
112    .float 265                      # Yes X pos
113    .float 300                      # Yes Y pos
114    .float 1                        # Yes scale
115    .float 365                      # No X pos
116    .float 300                      # No Y pos
117    .float 1                        # No scale
118    .byte 251, 199, 57, 255         # highlighted color
119    .byte 170, 170, 170, 255        # nonhighlighted color
120
121LagPrompt_SceneLoad_TopText:
122    blrl
123    .ascii "Are you using HDMI"
124    .short 0x8148
125    .byte 0
126    .align 2
127
128LagPrompt_SceneLoad_Yes:
129    blrl
130    .string "Yes"
131    .align 2
132
133LagPrompt_SceneLoad_No:
134    blrl
135    .string "No"
136    .align 2
137
138    # GObj Offsets
139    .set OFST_TextGObj, 0x0
140    .set OFST_Selection, 0x4
141
142LagPrompt_SceneLoad:
143    blrl
144
145    # Init
146    backup
147
148LagPrompt_SceneLoad_CreateText:
149    .set REG_GObjData, 27
150    .set REG_GObj, 28
151    .set REG_SubtextID, 29
152    .set REG_TextProp, 30
153    .set REG_TextGObj, 31
154
155    # GET PROPERTIES TABLE
156    bl LagPrompt_SceneLoad_TextProperties
157    mflr REG_TextProp
158
159    # Create canvas
160    li r3, 0
161    li r4, 0
162    li r5, 9
163    li r6, 13
164    li r7, 0
165    li r8, 14
166    li r9, 0
167    li r10, 19
168    branchl r12, 0x803a611c
169
170########################
171## Create Text Object ##
172########################
173
174    # CREATE TEXT OBJECT, RETURN POINTER TO STRUCT IN r3
175    li r3, 0
176    li r4, 0
177    branchl r12, Text_CreateTextStruct
178    # BACKUP STRUCT POINTER
179    mr REG_TextGObj, r3
180    stw REG_TextGObj, 0x0(REG_GObjData)
181    # SET TEXT SPACING TO TIGHT
182    li r4, 0x1
183    stb r4, 0x49(REG_TextGObj)
184    # SET TEXT TO CENTER AROUND X LOCATION
185    li r4, 0x1
186    stb r4, 0x4A(REG_TextGObj)
187    # Store Base Z Offset
188    lfs f1, ZOffset(REG_TextProp)   # Z offset
189    stfs f1, 0x8(REG_TextGObj)
190    # Scale Canvas Down
191    lfs f1, CanvasScaling(REG_TextProp)
192    stfs f1, 0x24(REG_TextGObj)
193    stfs f1, 0x28(REG_TextGObj)
194
195    # Create Prompt
196    # Initialize Subtext
197    mr r3, REG_TextGObj             # struct pointer
198    bl LagPrompt_SceneLoad_TopText
199    mflr r4
200    lfs f1, PromptX(REG_TextProp)
201    lfs f2, PromptY(REG_TextProp)
202    branchl r12, Text_InitializeSubtext
203    mr REG_SubtextID, r3
204    # Change Text Scale
205    mr r3, REG_TextGObj             # struct pointer
206    mr r4, REG_SubtextID
207    lfs f1, Scale(REG_TextProp)     # X offset of REG_TextGObj
208    lfs f2, Scale(REG_TextProp)     # Y offset of REG_TextGObj
209    branchl r12, Text_UpdateSubtextSize
210
211    # Create Yes
212    # Initialize Subtext
213    mr r3, REG_TextGObj             # struct pointer
214    bl LagPrompt_SceneLoad_Yes
215    mflr r4
216    lfs f1, YesX(REG_TextProp)
217    lfs f2, YesY(REG_TextProp)
218    branchl r12, Text_InitializeSubtext
219    mr REG_SubtextID, r3
220    # Change Text Scale
221    mr r3, REG_TextGObj             # struct pointer
222    mr r4, REG_SubtextID
223    lfs f1, YesScale(REG_TextProp)  # X offset of REG_TextGObj
224    lfs f2, YesScale(REG_TextProp)  # Y offset of REG_TextGObj
225    branchl r12, Text_UpdateSubtextSize
226
227    # Create No
228    # Initialize Subtext
229    mr r3, REG_TextGObj             # struct pointer
230    bl LagPrompt_SceneLoad_No
231    mflr r4
232    lfs f1, NoX(REG_TextProp)
233    lfs f2, NoY(REG_TextProp)
234    branchl r12, Text_InitializeSubtext
235    mr REG_SubtextID, r3
236    # Change Text Scale
237    mr r3, REG_TextGObj             # struct pointer
238    mr r4, REG_SubtextID
239    lfs f1, NoScale(REG_TextProp)   # X offset of REG_TextGObj
240    lfs f2, NoScale(REG_TextProp)   # Y offset of REG_TextGObj
241    branchl r12, Text_UpdateSubtextSize
242
243    # Create GObj
244    li r3, 13
245    li r4, 14
246    li r5, 0
247    branchl r12, GObj_Create
248    mr REG_GObj, r3
249    # Allocate Space
250    li r3, 64
251    branchl r12, HSD_MemAlloc
252    mr REG_GObjData, r3
253    # Zero
254    li r4, 64
255    branchl r12, ZeroAreaLength
256    # Initialize
257    mr r6, REG_GObjData
258    mr r3, REG_GObj
259    li r4, 4
260    load r5, 0x8037f1b0
261    branchl r12, GObj_AddUserData
262    # Add Proc
263    mr r3, REG_GObj
264    bl LagPrompt_SceneThink
265    mflr r4                         # Function to Run
266    li r5, 0                        # Priority
267    branchl r12, GObj_AddProc
268
269    # Store text gobj pointer
270    stw REG_TextGObj, OFST_TextGObj(REG_GObjData)
271    # Init Selection value
272    li r3, InitialSelection
273    stb r3, OFST_Selection(REG_GObjData)
274
275    # Highlight selection
276    mr r3, REG_TextGObj
277    li r4, InitialSelection+1
278    addi r5, REG_TextProp, HighlightColor
279    branchl r12, Text_ChangeTextColor
280
281LagPrompt_SceneLoad_Exit:
282    restore
283    blr
284
285############################################
286LagPrompt_SceneThink:
287    blrl
288
289    .set REG_TextProp, 28
290    .set REG_Inputs, 29
291    .set REG_GObjData, 30
292    .set REG_GObj, 31
293
294    # Init
295    backup
296    mr REG_GObj, r3
297    lwz REG_GObjData, 0x2C(REG_GObj)
298    bl LagPrompt_SceneLoad_TextProperties
299    mflr REG_TextProp
300
301    # Adjust Menu Choice
302    # Get all player inputs
303    li r3, 4
304    branchl r12, Inputs_GetPlayerRapidInputs
305    mr REG_Inputs, r3
306    # Check for movement to the right
307    rlwinm. r0, REG_Inputs, 0, 0x80
308    beq LagPrompt_SceneThink_SkipRight
309    # Adjust cursor
310    lbz r3, OFST_Selection(REG_GObjData)
311    addi r3, r3, 1
312    stb r3, OFST_Selection(REG_GObjData)
313    extsb r3, r3
314    cmpwi r3, 1
315    ble LagPrompt_SceneThink_HighlightSelection
316    li r3, 1
317    stb r3, OFST_Selection(REG_GObjData)
318    b LagPrompt_SceneThink_CheckForA
319
320LagPrompt_SceneThink_SkipRight:
321    # Check for movement to the left
322    rlwinm. r0, REG_Inputs, 0, 0x40
323    beq LagPrompt_SceneThink_CheckForA
324    # Adjust cursor
325    lbz r3, OFST_Selection(REG_GObjData)
326    subi r3, r3, 1
327    stb r3, OFST_Selection(REG_GObjData)
328    extsb r3, r3
329    cmpwi r3, 0
330    bge LagPrompt_SceneThink_HighlightSelection
331    li r3, 0
332    stb r3, OFST_Selection(REG_GObjData)
333    b LagPrompt_SceneThink_CheckForA
334
335LagPrompt_SceneThink_HighlightSelection:
336    # Unhighlight both options
337    lwz r3, OFST_TextGObj(REG_GObjData)
338    li r4, 1
339    addi r5, REG_TextProp, NonHighlightColor
340    branchl r12, Text_ChangeTextColor
341    lwz r3, OFST_TextGObj(REG_GObjData)
342    li r4, 2
343    addi r5, REG_TextProp, NonHighlightColor
344    branchl r12, Text_ChangeTextColor
345    # Highlight selection
346    lwz r3, OFST_TextGObj(REG_GObjData)
347    lbz r4, OFST_Selection(REG_GObjData)
348    addi r4, r4, 1
349    addi r5, REG_TextProp, HighlightColor
350    branchl r12, Text_ChangeTextColor
351    # Play SFX
352    branchl r12, 0x80174380
353
354LagPrompt_SceneThink_CheckForA:
355    li r3, 4
356    branchl r12, Inputs_GetPlayerInstantInputs
357    rlwinm. r0, r4, 0, 0x100
358    bne LagPrompt_SceneThink_Confirmed
359    rlwinm. r0, r4, 0, 0x1000
360    bne LagPrompt_SceneThink_Confirmed
361    b LagPrompt_SceneThink_Exit
362
363LagPrompt_SceneThink_Confirmed:
364    # Play Menu Sound
365    branchl r12, 0x80174338
366    # If yes, apply lag reduction
367    lbz r3, OFST_Selection(REG_GObjData)
368    cmpwi r3, 0
369    bne LagPrompt_SceneThink_ExitScene
370    .set REG_GeckoCode, 12
371    # Apply lag reduction
372    bl LagReductionGeckoCode
373    mflr r3
374    bl ApplyGeckoCode
375    # Reset some pad variables to cancel the current alarm
376    load r3, UnkPadStruct
377    li r4, 0
378    stw r4, 0x4(r3)
379    stw r4, 0x44(r3)
380    # Set new post retrace callback
381    load r3, PostRetraceCallback
382    branchl r12, 0x80375934
383    # Now flush the instruction cache
384    lis r3, 0x8000
385    load r4, 0x3b722c               # might be overkill but flush the entire dol file
386    branchl r12, 0x80328f50
387
388LagPrompt_SceneThink_ExitScene:
389    branchl r12, 0x801a4b60
390
391LagPrompt_SceneThink_Exit:
392    restore
393    blr
394
395LagPrompt_SceneDecide:
396    backup
397
398    # Exit Scene
399    li r3, ExitSceneID
400    branchl r12, 0x801a42e8
401    # Change Major
402    branchl r12, 0x801a42d4
403
404LagPrompt_SceneDecide_Exit:
405    restore
406    blr
407
408############################################
409LagReductionGeckoCode:
410    blrl
411    .long 0x04019860
412    .long 0x4BFFFD9D
413    .long 0x041a4c24
414    .long 0xC0429A7C
415    .long 0xFF000000
416
417ApplyGeckoCode:
418    .set REG_GeckoCode, 12
419    mr REG_GeckoCode, r3
420
421ApplyGeckoCode_Loop:
422    lbz r3, 0x0(REG_GeckoCode)
423    cmpwi r3, 0x4
424    beq ApplyGeckoCode_04
425    cmpwi r3, 0xFF
426    beq ApplyGeckoCode_Exit
427    b ApplyGeckoCode_Exit
428
429ApplyGeckoCode_04:
430    lwz r3, 0x0(REG_GeckoCode)
431    rlwinm r3, r3, 0, 8, 31
432    oris r3, r3, 0x8000
433    lwz r4, 0x4(REG_GeckoCode)
434    stw r4, 0x0(r3)
435    addi REG_GeckoCode, REG_GeckoCode, 0x8
436    b ApplyGeckoCode_Loop
437
438ApplyGeckoCode_Exit:
439    blr
440
441LagPrompt_MinorSceneStruct:
442    blrl
443    # Lag Prompt
444    .byte 0                         # Minor Scene ID
445    .byte 00                        # Amount of persistent heaps
446    .align 2
447    .long 0x00000000                # ScenePrep
448    bl LagPrompt_SceneDecide        # SceneDecide
449    .byte PromptCommonSceneID       # Common Minor ID
450    .align 2
451    .long 0x00000000                # Minor Data 1
452    .long 0x00000000                # Minor Data 2
453    # End
454    .byte -1
455    .align 2
456
457CheckProgressive:
458    # Check if progressive is enabled
459    branchl r12, 0x80349278
460    cmpwi r3, 0
461    beq NoProgressive
462
463IsProgressive:
464    # Load LagPrompt
465    li r3, PromptSceneID
466    b Injection_Exit
467
468NoProgressive:
469    # Exit Scene
470    li r3, ExitSceneID
471
472Injection_Exit:
473    restore