fork/training-mode-ce

git clone https://git.julia.blue/fork/training-mode-ce

AitchMerge pull request #88 from NickCondron/remove-asm2c08d3a

master
2.6 KiB110 linesraw
1    # To be inserted @ 803d7080
2    .include "../../Globals.s"
3    .include "../Header.s"
4
5# args are
6# r3 = file name
7# r4 = array to store function pointers to
8# r5 = symbol
9
10# returns
11# r3 = file data
12
13    .set REG_FileName, 31
14    .set REG_Return, 30
15    .set REG_Symbol, 29
16    .set REG_FileSize, 28
17    .set REG_File, 27
18    .set REG_Header, 26
19    .set REG_mexData, 25
20
21    backup
22    mr REG_FileName, r3
23    mr REG_Return, r4
24    mr REG_Symbol, r5
25
26    # Load file
27    mr r3, REG_FileName
28    addi r4, sp, 0x80
29    mr r5, REG_Symbol
30    li r6, 0
31    branchl r12, 0x80016c64
32    mr REG_Header, r3
33    # Check if exists
34    lwz REG_mexData, 0x80(sp)
35    cmpwi REG_mexData, 0
36    beq mexPatch_Skip
37    # Reloc
38    lwz r3, ftX_InstructionRelocTableCount(REG_mexData) # count
39    lwz r4, ftX_Code(REG_mexData)                       # code
40    lwz r5, ftX_InstructionRelocTable(REG_mexData)      # reloc table
41    branchl r12, Reloc
42    # Overload
43    mr r3, REG_mexData
44    mr r4, REG_Return
45    bl Overload
46
47mexPatch_Skip:
48    # Flush instruction cache so code can be run from this file
49    lwz r3, 0x20(REG_Header)                            # file start
50    lwz r4, 0x0(REG_Header)                             # file size
51    branchl r12, 0x80328f50
52
53    mr r3, REG_Header
54    restore
55    blr
56
57###########################################
58
59    # ftX struct
60    .set ftX_Code, 0x0
61    .set ftX_InstructionRelocTable, 0x4
62    .set ftX_InstructionRelocTableCount, 0x8
63    .set ftX_FunctionRelocTable, 0xC
64    .set FunctionRelocTable_ReplaceThis, 0x0
65    .set FunctionRelocTable_ReplaceWith, 0x4
66    .set ftX_FunctionRelocTableCount, 0x10
67
68Overload:
69    # r3 = ftX
70    # r4 = table
71    # Copy function pointers - init
72    .set REG_ftX, 12
73    .set REG_ThisElement, 11
74    .set REG_Code, 10
75    .set REG_OverloadTable, 9
76    .set REG_Count, 8
77    .set REG_RelocTable, 7
78    mr REG_ftX, r3
79    mr REG_OverloadTable, r4
80    lwz REG_RelocTable, ftX_FunctionRelocTable(REG_ftX)
81    lwz REG_Code, 0x0(REG_ftX)
82    li REG_Count, 0
83    b Overload_CheckLoop
84
85Overload_Loop:
86    # Get this element
87    mulli r3, REG_Count, 8
88    add REG_ThisElement, r3, REG_RelocTable
89
90Overload_TableIndex:
91    # Get ram offset for this function
92    lwz r3, FunctionRelocTable_ReplaceWith(REG_ThisElement)
93    add r3, r3, REG_Code
94    # Update table
95    lwz r4, FunctionRelocTable_ReplaceThis(REG_ThisElement)
96    mulli r4, r4, 4
97    stwx r3, r4, REG_OverloadTable
98    b Overload_IncLoop
99
100Overload_IncLoop:
101    addi REG_Count, REG_Count, 1
102
103Overload_CheckLoop:
104    lwz r3, ftX_FunctionRelocTableCount(REG_ftX)
105    cmpw REG_Count, r3
106    blt Overload_Loop
107
108Overload_Exit:
109    blr
110############################################