fork/training-mode-ce

git clone https://git.julia.blue/fork/training-mode-ce

AitchMerge pull request #88 from NickCondron/remove-asm2c08d3a

master
3.1 KiB116 linesraw
1    # To be inserted @ 803d7074
2    .include "../../Globals.s"
3    .include "../Header.s"
4
5    ###########################################
6    # Intialize pointers
7    .set REG_Count, 12
8    .set REG_Code, 11
9    .set REG_RelocTable, 10
10    mr REG_Count, r3
11    mr REG_Code, r4
12    mr REG_RelocTable, r5
13
14Reloc_Loop:
15    .set REG_CodePointer, 9
16    .set REG_FuncPointer, 8
17    .set REG_Flag, 7
18    lwz r3, 0x0(REG_RelocTable)
19    rlwinm REG_Flag, r3, 8, 0x000000FF          # get flag
20    rlwinm r3, r3, 0, 0x00FFFFFF
21    add REG_CodePointer, r3, REG_Code           # get code offset
22
23    # First check if a bl to an dol address
24    lwz r3, 0x4(REG_RelocTable)
25    rlwinm r0, r3, 8, 0x000000F0
26    cmpwi r0, 0x80
27    beq Reloc_DOLAddr
28
29Reloc_CodeAddr:
30    add REG_FuncPointer, r3, REG_Code           # get func offset
31    b Reloc_CheckType
32
33Reloc_DOLAddr:
34    lwz REG_FuncPointer, 0x4(REG_RelocTable)    # get func offset
35
36Reloc_CheckType:
37    # Check flag type
38    cmpwi REG_Flag, 1
39    beq Reloc_StaticAddress
40    cmpwi REG_Flag, 4
41    beq Reloc_LoadAddress
42    cmpwi REG_Flag, 6
43    beq Reloc_LoadAddress
44    cmpwi REG_Flag, 10
45    beq Reloc_Branch
46    cmpwi REG_Flag, 26
47    beq Reloc_Relative32Bit
48    b Reloc_IncLoop
49
50Reloc_StaticAddress:
51    # lwz r3, 0x0(REG_FuncPointer)
52    stw REG_FuncPointer, 0x0(REG_CodePointer)
53    b Reloc_IncLoop
54
55############################################
56Reloc_LoadAddress:
57    # Now check if the low bits are signed
58    rlwinm. r3, REG_FuncPointer, 17, 0x1
59    beq Reloc_CheckFlag
60    # Adjust this address to load a negative offset
61    .set REG_NewHigh, 6
62    .set REG_NewLow, 5
63    # High bits
64    rlwinm r3, REG_FuncPointer, 16, 0x0000FFFF
65    addi r3, r3, 1
66    slwi REG_NewHigh, r3, 16
67    # Low bits
68    sub r3, REG_FuncPointer, REG_NewHigh
69    rlwinm REG_NewLow, r3, 0, 0x0000FFFF
70    or REG_FuncPointer, REG_NewHigh, REG_NewLow
71
72Reloc_CheckFlag:
73    # Check flag type
74    cmpwi REG_Flag, 4
75    beq Reloc_Low16
76    cmpwi REG_Flag, 6
77    beq Reloc_High16
78
79Reloc_High16:
80    rlwinm r3, REG_FuncPointer, 16, 0x0000FFFF
81    b Reloc_Store
82
83Reloc_Low16:
84    rlwinm r3, REG_FuncPointer, 0, 0x0000FFFF
85    b Reloc_Store
86
87Reloc_Store:
88    sth r3, 0x0(REG_CodePointer)
89    b Reloc_IncLoop
90
91############################################
92Reloc_Branch:
93    # Store branch to this code
94    sub r3, REG_FuncPointer, REG_CodePointer    # Difference relative to branch addr
95    rlwinm r3, r3, 0, 6, 29                     # extract bits for offset
96    lwz r4, 0x0(REG_CodePointer)                # place branch instruction
97    or r3, r3, r4
98    stw r3, 0x0(REG_CodePointer)                # place branch instruction
99    b Reloc_IncLoop
100
101############################################
102Reloc_Relative32Bit:
103    # Store offset?
104    # Store branch to this code
105    sub r3, REG_FuncPointer, REG_CodePointer    # Difference relative to branch addr
106    stw r3, 0x0(REG_CodePointer)                # place branch instruction
107    b Reloc_IncLoop
108
109############################################
110Reloc_IncLoop:
111    addi REG_RelocTable, REG_RelocTable, 8
112    subi REG_Count, REG_Count, 1
113    cmpwi REG_Count, 0
114    bgt Reloc_Loop
115    blr
116##############################################