fork/training-mode-ce

git clone https://git.julia.blue/fork/training-mode-ce

Nick CondronFix restore human player on cssf45f9ab

master
4.3 KiB186 linesraw
1    # To be inserted at 80264578
2    .include "../../../../Globals.s"
3    .include "../../../../m-ex/Header.s"
4
5    backup
6
7    .set REG_GObj, 31
8    .set REG_Data, 30
9    .set REG_HmnWhitelist, 29
10
11    # Ensure this is event mode
12    load r3, SceneController
13    lbz r3, Scene.CurrentMajor(r3)
14    cmpwi r3, Scene.EventMode
15    bne Original
16
17    # Create GObj
18    li r3, 4
19    li r4, 5
20    li r5, 0
21    branchl r12, GObj_Create
22    mr REG_GObj, r3
23
24    # Create Data
25    li r3, 8
26    branchl r12, HSD_MemAlloc
27    mr REG_Data, r3
28
29    # Attach Data
30    mr r3, REG_GObj
31    li r4, 14
32    load r5, HSD_Free
33    mr r6, REG_Data
34    branchl r12, GObj_AddUserData
35
36    # Attach Process
37    bl ToggleCSSIcon
38    mflr r4
39    li r5, 2                    # Priority (after CSS_BigFunctionMonitorInputsAndMore)
40    branchl r12, GObj_AddProc
41
42    # Store Whitelist to GObj Data
43    # Get Current Event Number
44    lwz r4, MemcardData(r13)
45    lbz r3, 0x0535(r4)
46    # Get Current Page
47    lbz r4, CurrentEventPage(r4)
48    rtocbl r12, TM_GetEventCharList
49    stw r3, 0x0(REG_Data)
50    lwz REG_HmnWhitelist, 0x0(r3)
51    # Check if exists
52    cmpwi REG_HmnWhitelist, -1
53    beq Original
54
55    # Make P1 Undecided
56    lwz r20, CSS_Data(r13)      # CSS Match Info
57    addi r4, r20, 0x70          # Get Player Info Start
58    lhz r5, 0x0(r20)            # Get Player in control of CSS
59    subi r5, r5, 1              # Zero index cause Yasuyuki Nagashima is dumb
60    mulli r5, r5, 36
61    add r4, r4, r5              # r4 now contains the players info
62    # Check if 0x21(N/A)
63    li r3, 0x21
64    stb r3, 0x0(r4)
65    b Original
66
67#######################
68ToggleCSSIcon:
69    blrl
70    .set REG_Whitelist, 31
71
72    backup
73
74    # Get Whitelist
75    lwz r3, 0x2C(r3)
76    lwz REG_Whitelist, 0x0(r3)
77    # Check if whitelist exists
78    cmpwi REG_Whitelist, -1
79    beq ToggleCSSIcon_Exit
80
81ToggleCSSIcon_Start:
82    # Get P1's Cursor Data
83    load r3, CSS_CursorPointers # Load CSS Cursor Pointers
84    lwz r5, 0x0(r3)             # Get P1's Cursor Data
85
86    # Check if holding a puck
87    lbz r3, 0x5(r5)             # Check hand state
88    cmpwi r3, 0x1
89    bne ToggleCSSIcon_HoldingP1Puck
90    # Check if holding P1's puck
91    lbz r3, 0x6(r5)
92    cmpwi r3, 0x0
93    beq ToggleCSSIcon_HoldingP1Puck
94    # Check if holding CPU's puck
95    cmpwi r3, 0x1
96    beq ToggleCSSIcon_HoldingCPUPuck
97    b ToggleCSSIcon_Exit
98
99ToggleCSSIcon_HoldingP1Puck:
100    mr r3, REG_Whitelist
101    bl ToggleCSSIcon_ToggleSelectedIcons
102    b ToggleCSSIcon_Exit
103
104ToggleCSSIcon_HoldingCPUPuck:
105    addi r3, REG_Whitelist, 0x4 # CPU List is at 0x4
106    bl ToggleCSSIcon_ToggleSelectedIcons
107    b ToggleCSSIcon_Exit
108
109ToggleCSSIcon_Exit:
110    restore
111    blr
112
113# ******************************#
114
115############################
116## Show Whitelisted Chars ##
117############################
118ToggleCSSIcon_ToggleSelectedIcons:
119    .set REG_IconDataStart, 31
120    .set REG_Whitelist, 30
121    .set REG_IconData, 29
122    .set REG_VisibilityBool, 28
123    .set REG_LoopCount, 27
124
125    backup
126
127ToggleCSSIcon_ToggleSelectedIconsInit:
128    # Init Stuff
129    lwz REG_Whitelist, 0x0(r3)
130    li REG_LoopCount, 25
131    load REG_IconDataStart, 0x803f0b24
132    b ToggleCSSIcon_ToggleSelectedIconsIncLoop
133
134ToggleCSSIcon_ToggleSelectedIconsLoop:
135    # Get Icons Data
136    mulli r3, REG_LoopCount, 0x1C
137    add REG_IconData, r3, REG_IconDataStart
138    # Check if icon should be visible
139    li r3, 1
140    slw r0, r3, REG_LoopCount
141    and. r0, r0, REG_Whitelist
142    bne ToggleCSSIcon_ToggleSelectedIcons_Display
143
144ToggleCSSIcon_ToggleSelectedIcons_Hide:
145    li REG_VisibilityBool, 0
146    b 0x8
147
148ToggleCSSIcon_ToggleSelectedIcons_Display:
149    li REG_VisibilityBool, 1
150    # Set Invisible
151    # Get JObj
152    lwz r3, -0x49E0(r13)
153    addi r4, sp, 0x80
154    lbz r5, 0x5(REG_IconData)
155    crclr 6
156    li r6, -1
157    branchl r12, 0x80011e24
158    # Toggle invisibility flag
159    lwz r3, 0x80(sp)
160    li r5, 1
161    cmpwi REG_VisibilityBool, 0
162    beq 0x8
163    li r5, 0
164    lwz r4, 0x14(r3)
165    rlwimi r4, r5, 4, 27, 27
166    stw r4, 0x14(r3)
167    # Set interactable
168    li r3, 0
169    cmpwi REG_VisibilityBool, 0
170    beq 0x8
171    li r3, 2
172    stb r3, 0x2(REG_IconData)
173
174ToggleCSSIcon_ToggleSelectedIconsIncLoop:
175    subi REG_LoopCount, REG_LoopCount, 1
176    cmpwi REG_LoopCount, 0
177    bge ToggleCSSIcon_ToggleSelectedIconsLoop
178
179ToggleCSSIcon_ToggleSelectedIconsExit:
180    restore
181    blr
182
183# ******************************#
184Original:
185    restore
186    lbz r4, -0x3E57(r13)