fork/training-mode-ce

git clone https://git.julia.blue/fork/training-mode-ce

AitchMerge pull request #242 from NickCondron/remove-asm96edbd1

master
4.5 KiB184 linesraw
1    # To be inserted at 8008d770
2    .include "../../Globals.s"
3    .include "../../m-ex/Header.s"
4
5    .set entity, 31
6    .set REG_FighterData, 31
7    .set player, 30
8    .set text, 29
9    .set textprop, 28
10    .set REG_TextColor, 27
11    .set REG_String, 26
12
13##########################################################
14## 804a1f5c -> 804a1fd4 = Static Stock Icon Text Struct ##
15## Is 0x80 long and is zero'd at the start ##
16## of every VS Match ##
17## Store Text Info here ##
18##########################################################
19
20    backupall
21    lwz REG_FighterData, 0x2c(player)
22
23    # CHECK IF ENABLED
24    li r0, OSD.LCancel              # wavedash ID
25    # lwz r4, -0xdbc(rtoc) #get frame data toggle bits
26    lwz r4, MemcardData(r13)
27    lwz r4, 0x1F24(r4)
28    li r3, 1
29    slw r0, r3, r0
30    and. r0, r0, r4
31    beq Exit
32
33CheckForFollower:
34    mr r3, REG_FighterData
35    branchl r12, 0x80005510
36    cmpwi r3, 0x1
37    beq Exit
38
39    # Check if succeeded
40    lbz r5, 0x67F(REG_FighterData)  # get decimal to print
41    cmpwi r5, 0x7
42    blt SuccessLCancel
43
44FailedLCancel:
45    li REG_TextColor, MSGCOLOR_RED
46    mr r3, REG_FighterData
47    bl DecLCRate
48    b DetermineString
49
50SuccessLCancel:
51    li REG_TextColor, MSGCOLOR_GREEN
52    mr r3, REG_FighterData
53    bl IncLCRate
54    b DetermineString
55
56DetermineString:
57    # If under 40 frames, qualify as an attempt
58    lbz r8, 0x67F(REG_FighterData)  # get decimal to print
59    cmpwi r8, 40
60    bgt DetermineString_NoPress
61    bl LCancel_Press
62    mflr REG_String
63    b PrintMessage
64
65DetermineString_NoPress:
66    bl LCancel_NoPress
67    mflr REG_String
68    b PrintMessage
69
70PrintMessage:
71    mr r7, r3                       # LCancel Percent
72    li r3, 1                        # Message Kind
73    lbz r4, 0xC(REG_FighterData)    # Message Queue
74    mr r5, REG_TextColor
75    mr r6, REG_String
76    lbz r8, 0x67F(REG_FighterData)  # get decimal to print
77    addi r8, r8, 1
78    Message_Display
79
80    # Make Top Line White
81    lwz r3, 0x2C(r3)
82    lwz r3, MsgData_Text(r3)
83    li r4, 0
84    bl Color_White
85    mflr r5
86    branchl r12, Text_ChangeTextColor
87
88    b Exit
89
90#########################
91### LC Rate Functions ###
92#########################
93
94IncLCRate:
95    stwu r1, -0x100(r1)             # make space for 12 registers
96    mflr r0
97    stw r0, 0xFC(sp)
98    lbz r3, 0xC(r3)                 # get player slot
99    load r4, 0x804a1fa8             # get LC rate mem location
100    mulli r3, r3, 0x4               # length of players DB info
101    add r8, r3, r4                  # players LC info in r8
102    lhz r3, 0x0(r8)                 # successful LCs
103    addi r3, r3, 0x1
104    sth r3, 0x0(r8)                 # successful LCs
105    lhz r3, 0x2(r8)                 # total LCs
106    addi r3, r3, 0x1
107    sth r3, 0x2(r8)                 # total LCs
108    mr r3, r8
109    bl GetLCRate
110    lwz r0, 0xFC(sp)
111    mtlr r0
112    addi r1, r1, 0x100              # release the space
113    blr
114
115DecLCRate:
116    stwu r1, -0x100(r1)             # make space for 12 registers
117    mflr r0
118    stw r0, 0xFC(sp)
119    lbz r3, 0xC(r3)                 # get player slot
120    load r4, 0x804a1fa8             # get DB rate mem location
121    mulli r3, r3, 0x4               # length of players DB info
122    add r8, r3, r4                  # players DB info in r8
123    lhz r3, 0x2(r8)                 # total DBs
124    addi r3, r3, 0x1
125    sth r3, 0x2(r8)                 # total DBs
126    mr r3, r8
127    bl GetLCRate
128    lwz r0, 0xFC(sp)
129    mtlr r0
130    addi r1, r1, 0x100              # release the space
131    blr
132
133GetLCRate:
134    # Get Values
135    lhz r4, 0x0(r3)                 # successful LCs
136    lhz r5, 0x2(r3)                 # total LCs
137    # Get as Floats (f1 = successful, f2 = total
138    lis r0, 0x4330
139    lfd f5, -0x6758(rtoc)
140    xoris r6, r4, 0x8000
141    xoris r7, r5, 0x8000
142    stw r0, 0xF0(sp)
143    # Successful DB
144    stw r6, 0xF4(sp)
145    lfd f1, 0xF0(sp)
146    fsubs f1, f1, f5
147    # Total DB
148    stw r7, 0xF4(sp)
149    lfd f2, 0xF0(sp)
150    fsubs f2, f2, f5
151    # 100f
152    li r4, 100
153    xoris r4, r4, 0x8000
154    stw r4, 0xF4(sp)
155    lfd f3, 0xF0(sp)
156    fsubs f3, f3, f5
157    fdivs f1, f1, f2                # successful LC / total LC
158    fmuls f1, f1, f3                # times 100
159    # Back to Int
160    fctiwz f1, f1
161    stfd f1, 0xF0(sp)
162    lwz r3, 0xF4(sp)
163    blr
164
165LCancel_Press:
166    blrl
167    .string "L-Cancel %d%%\nFrame %d/7"
168    .align 2
169
170LCancel_NoPress:
171    blrl
172    .string "L-Cancel %d%%\nNo Press"
173    .align 2
174
175Color_White:
176    blrl
177    .long 0xFFFFFFFF
178
179##############################
180
181Exit:
182    restoreall
183
184    lwz r0, 0x0034(sp)