fork/training-mode-ce

git clone https://git.julia.blue/fork/training-mode-ce

AitchMerge pull request #243 from NickCondron/remove-asmf9241ee

master
7.3 KiB241 linesraw
1    # To be inserted at 802ff4e8
2    .include "../../../Globals.s"
3    .include "../../../m-ex/Header.s"
4
5    .set MessageStructTotalSize, 0x300
6    .set MessageAreaLength, 0x100
7    .set PerPlayerMessageStructLength, 0x28
8
9########################################################
10## Allocate 0x300 Bytes and Store Pointer at 804a1f5c ##
11########################################################
12
13    li r3, MessageStructTotalSize
14    branchl r12, HSD_MemAlloc
15    stw r3, 0x4(r31)
16
17    # Zero Space
18    li r4, MessageStructTotalSize
19    branchl r12, ZeroAreaLength
20
21##############################################
22## Create Message Management Think Function ##
23##############################################
24
25    # Create GObj
26    li r3, 0xE
27    li r4, 0x7
28    li r5, 0x0
29    branchl r12, GObj_Create
30
31    # Attach Think Function
32    bl MessageThink
33    mflr r4                                                 # Get Function Address
34    li r5, 0x0
35    branchl r12, GObj_AddProc
36
37    b exit
38
39#################################################################
40
41################
42## MessageThink ##
43################
44
45MessageThink:
46    blrl
47
48    backup
49
50###############################################
51## Update Message Area 1(Above Player HUDs) ##
52###############################################
53
54    # Init Loop
55    li r31, 0x0                                             # Loop Count
56
57MessageThink_UpdateArea1Loop:
58    li r3, 0x0                                              # Area 1
59    mr r4, r31                                              # Player
60    bl MessageThink_Updater
61
62MessageThink_UpdateArea1IncLoop:
63    addi r31, r31, 0x1
64    cmpwi r31, 0x4
65    blt MessageThink_UpdateArea1Loop
66
67###########################################
68## Update Message Area 2(Top of Screen) ##
69###########################################
70
71    # Init Loop
72    li r31, 0x0                                             # Loop Count
73
74MessageThink_UpdateArea2Loop:
75    li r3, 1                                                # Area 2
76    mr r4, r31                                              # Player
77    bl MessageThink_Updater
78
79MessageThink_UpdateArea2IncLoop:
80    addi r31, r31, 0x1
81    cmpwi r31, 0x4
82    blt MessageThink_UpdateArea2Loop
83
84#################################################
85## Update Message Area 3(Right Side of Screen ##
86#################################################
87
88    li r3, 2                                                # Area 3
89    bl MessageThink_Updater
90
91MessageThink_Exit:
92    restore
93    blr
94
95##################################################################
96
97##########################
98## MessageThink_Updater ##
99##########################
100
101MessageThink_Updater:
102    backup
103
104    mr r31, r3                                              # Area ID
105    mr r30, r4                                              # Player ID
106
107    # Get Area's Message Struct in r29
108    load r3, 0x804a1f58
109    lwz r3, 0x4(r3)
110    mulli r4, r31, MessageAreaLength
111    add r29, r3, r4
112
113    # Check For Area 3, No Player Dependent Stuff If So
114    cmpwi r31, 0x2
115    bge MessageThink_Updater_NonPlayerArea
116
117######################################################################################
118
119MessageThink_Updater_PlayerAreaLoopInit:
120    mulli r4, r30, PerPlayerMessageStructLength
121    add r29, r29, r4
122    li r28, 0x0                                             # Offset In Player's Area
123
124MessageThink_Updater_PlayerAreaLoop:
125    add r27, r28, r29
126    lwz r3, 0x0(r27)                                        # Get Text Pointer
127    cmpwi r3, 0                                             # If There's No Text Here, Skip
128    beq MessageThink_Updater_PlayerAreaIncLoop
129
130    # Check If No Timer (-1)
131    lhz r3, 0x4(r27)                                        # Get Timer
132    cmpwi r3, -1
133    beq MessageThink_Updater_PlayerAreaIncLoop
134
135    # Decrement Timer
136    # lhz r3, 0x4(r27) #Get Timer
137    subi r3, r3, 0x1
138    sth r3, 0x4(r27)
139
140    # Check If Expired
141    cmpwi r3, 0x0
142    bgt MessageThink_Updater_PlayerAreaIncLoop
143
144    # Remove Text
145    lwz r3, 0x0(r27)                                        # Get Text Pointer
146    branchl r12, Text_RemoveText
147
148    # Zero Out Entry
149    li r3, 0x0
150    stw r3, 0x0(r27)
151    stw r3, 0x4(r27)
152
153    # Check To Shift Upwards
154    addi r26, r28, 0x8                                      # Next Offset
155    cmpwi r26, PerPlayerMessageStructLength                 # Check If There's Nothing Left to Shift
156    bge MessageThink_Updater_PlayerAreaIncLoop              # Skip Shift Code
157
158# Shift Everything Below it Upwards
159MessageThink_Updater_PlayerAreaShiftMessagesLoop:
160    add r5, r26, r29                                        # Get Next Individual Message Struct
161    lwz r3, 0x0(r5)                                         # Get Messages Text Pointer
162    lwz r4, 0x4(r5)                                         # Get Messages Timer and ID
163    stw r3, -0x8(r5)                                        # Push Up
164    stw r4, -0x4(r5)                                        # Push Up
165
166    # Check If This Entry Is Live
167    cmpwi r3, 0x0
168    beq MessageThink_Updater_PlayerAreaShiftMessagesIncLoop
169
170    # Move Message Downwards/Upwards Depending On The Area
171    bl MessageThink_Floats
172    mflr r4
173    mulli r5, r31, 0x4                                      # Area ID into offset
174    lfsx f1, r4, r5
175    lfs f2, 0x4(r3)                                         # Get Text's Y Value
176    fadds f1, f1, f2
177    stfs f1, 0x4(r3)                                        # Store Text's Y Value
178
179# Go To Next Message's Offset
180MessageThink_Updater_PlayerAreaShiftMessagesIncLoop:
181    addi r26, r26, 0x8                                      # Next Offset
182    cmpwi r26, PerPlayerMessageStructLength                 # Check If There's Nothing Left to Shift
183    blt MessageThink_Updater_PlayerAreaShiftMessagesLoop    # Run Code if There Is
184
185MessageThink_Updater_PlayerAreaIncLoop:
186    addi r28, r28, 0x8                                      # Length of Each Message Data
187    cmpwi r28, PerPlayerMessageStructLength
188    blt MessageThink_Updater_PlayerAreaLoop
189
190    b MessageThink_Updater_Exit
191
192######################################################################################
193
194MessageThink_Updater_NonPlayerArea:
195    lwz r3, 0x0(r29)                                        # Get Text Pointer
196    cmpwi r3, 0                                             # If There's No Text Here, Skip
197    beq MessageThink_Updater_Exit
198
199    # Check If No Timer (-1)
200    lhz r3, 0x4(r29)                                        # Get Timer
201    cmpwi r3, -1
202    beq MessageThink_Updater_Exit
203
204    # Decrement Timer
205    # lhz r3, 0x4(r29) #Get Timer
206    subi r3, r3, 0x1
207    sth r3, 0x4(r29)
208
209    # Check If Expired
210    cmpwi r3, 0x0
211    bgt MessageThink_Updater_Exit
212
213    # Remove Text
214    lwz r3, 0x0(r29)                                        # Get Text Pointer
215    branchl r12, Text_RemoveText
216
217    # Zero Out Entry
218    li r3, 0x0
219    stw r3, 0x0(r29)
220    stw r3, 0x4(r29)
221
222    b MessageThink_Updater_Exit
223
224######################################################################################
225
226# ******************#
227MessageThink_Floats:
228    blrl
229    .long 0x40900000                                        # Area 1
230    .long 0xC0900000                                        # Area 2
231
232# ******************#
233
234MessageThink_Updater_Exit:
235    restore
236    blr
237
238#################################################################
239
240exit:
241    lwz r0, 0x001C(sp)