fork/training-mode-ce

git clone https://git.julia.blue/fork/training-mode-ce

AitchMerge pull request #243 from NickCondron/remove-asmf9241ee

master
9.9 KiB373 linesraw
1    # To be inserted at 80005928
2    .include "../../../Globals.s"
3    .include "../../../m-ex/Header.s"
4
5    .set playerdata, 31
6    .set messageStruct, 30
7    .set text, 29
8    .set textprop, 28
9    .set texttimer, 27
10    .set AreaID, 26
11    .set overlayID, 25
12    .set MaxWindows, 24
13
14    .set messageAreaStructLength, 0x100
15    .set messageStructLength, 0x28
16
17##########################################################
18## 804a1f5c -> 804a1fd4 = Static Stock Icon Text Struct ##
19## Is 0x80 long and is zero'd at the start ##
20## of every VS Match ##
21## Store Text Info here ##
22##########################################################
23
24# Message Area Struct Layout
25##0x00 = P1 Area
26##0x28 = P2 Area
27##0x50 = P3 Area
28##0x78 = P4 Area
29
30# PX Area
31# 0x0 = 32-bit int, number of active windows in this area
32# 0x4 = Start Individual Message Struct
33# 0x0 = Text Pointer
34# 0x4 = Countdown Until Expiration
35# 0x6 = Unique Message ID(which text prompt this is)
36
37    backup
38
39    mr playerdata, r3
40    mr texttimer, r4
41    mr AreaID, r5               # custom window struct in the stock text match struct
42    mr overlayID, r6
43    mr textprop, r7
44
45    # Load Max Number of Windows Variable From OSD Menu
46    lwz r3, MemcardData(r13)        # Get Memcard Data
47    lbz MaxWindows, 0x1f28(r3)
48
49    # Get Window's Area in the Message Struct in r3
50    load r3, 0x804a1f58
51    lwz r3, 0x4(r3)
52    mulli r4, AreaID, messageAreaStructLength
53    add r3, r3, r4
54
55    # Check If Area 3(No Shift or anything Special)
56    cmpwi AreaID, 0x2
57    blt GetPlayersArea
58    mr messageStruct, r3
59
60    # Remove Old Area 3 Window
61    lwz r3, 0x0(messageStruct)
62    branchl r12, Text_RemoveText
63    b CreateText
64
65GetPlayersArea:
66    # Get to the player's area
67    lbz r4, 0xC(playerdata)
68    mulli r4, r4, messageStructLength
69    add messageStruct, r3, r4
70
71    # Search Queue For This Text ID(Loop)
72    mr r3, overlayID
73    mr r4, MaxWindows
74    mr r5, messageStruct
75    bl CheckForDuplicates
76
77    # Shift Queue To Make Room For New Message
78    CallShiftFunction:
79
80    mr r3, MaxWindows
81    bl ShiftQueue
82
83CreateText:
84    # CREATE TEXT ABOVE PLAYERS HUD ELEMENT
85    li r3, 0x2
86    load r4, 0x804a1f58         # get text objects ID?
87    lwz r4, 0x0(r4)
88    branchl r12, Text_CreateTextStruct
89
90    # STORE PLAYERS TEXT POINTER
91    mr r29, r3                  # backup text pointer
92    stw r3, 0x0(messageStruct)
93
94    # STORE PLAYERS TEXT TIMEOUT
95    sth texttimer, 0x4(messageStruct)
96
97    # STORE OVERLAY ID
98    sth overlayID, 0x6(messageStruct)
99
100    # SET TEXT TO CENTER AROUND X LOCATION AND BE CLOSE
101    li r3, 0x1
102    stb r3, 0x4A(r29)
103    stb r3, 0x49(r29)
104
105    # SET X AND Y VALUES
106    # Get Area's Text Properties
107    bl TextProperties
108    mflr textprop
109    mulli r3, AreaID, 0x1C
110    add textprop, textprop, r3
111
112    # Check To Override HUD Location
113    lwz r3, 0x0(textprop)       # base X value
114    cmpwi r3, 0x0
115    bne GetHUDLocation
116    lfs f1, 0x8(textprop)       # base X value
117    b GetYLocation
118
119# Get HUD Location
120GetHUDLocation:
121    lbz r3, 0xC(playerdata)
122    load r4, 0x804a0ff0
123    mulli r3, r3, 0xC           # HUD Info is 0xC Long Per Player
124    lfsx f1, r3, r4             # Get This Players HUD Info
125
126GetYLocation:
127    lfs f2, 0x4(textprop)       # players Y value
128    stfs f1, 0x0(text)          # store X value to struct
129    stfs f2, 0x4(text)          # store Y value to struct
130
131    # SET TEXT SIZE
132    lfs f1, 0xC(textprop)
133    stfs f1, 0x24(text)         # X stretch
134    stfs f1, 0x28(text)         # Y stretch
135
136    # INIT BACKGROUND(HYPHEN)
137    mr r3, r29                  # text pointer
138    bl TextASCII3
139    mflr r4                     # get ASCII to print
140    lfs f1, -0x37B4(rtoc)       # default text X/Y
141    lfs f2, 0x10(textprop)      # background Y
142    branchl r12, Text_InitializeSubtext
143
144    # CHANGE TEXT COLOR TO BLACK
145    mr r3, text
146    li r4, 0x0
147    li r5, 0x0
148    stw r5, 0xF0(sp)
149    addi r5, sp, 0xF0
150    branchl r12, Text_ChangeTextColor
151
152    # CHANGE TEXT SIZE
153    mr r3, text
154    li r4, 0x0
155    lfs f1, 0x14(textprop)      # stretch X (12)
156    lfs f2, 0x18(textprop)      # stretch Y (30)
157    branchl r12, Text_UpdateSubtextSize
158
159    b Exit
160
161#######################################################################
162
163####################
164## Shift Messages ##
165####################
166
167ShiftQueue:
168    backup
169
170    mr r31, r3                  # Max Windows
171
172    # Remove Last Message if Exists
173    mulli r3, r31, 0x8
174    lwzx r3, r3, messageStruct
175    cmpwi r3, 0x0
176    beq ShiftQueue_CheckForOneWindowOnly
177
178    # Remove Message
179    branchl r12, Text_RemoveText
180
181    # Zero Out Entry
182    mulli r4, r31, 0x8
183    add r4, r4, messageStruct
184    li r3, 0
185    stw r3, 0x0(r4)
186    stw r3, 0x4(r4)
187
188ShiftQueue_CheckForOneWindowOnly:
189    # Check If Only 1 Message
190    cmpwi r31, 0
191    beq ShiftQueue_Exit
192
193ShiftQueue_Loop:
194    # Shift This Message Upwards in the Queue
195    mulli r3, r31, 0x8
196    add r3, r3, messageStruct   # Get to the nth Message
197    lwz r4, 0x0(r3)             # Load Text Pointer into r4
198    lwz r5, 0x4(r3)             # Load Timer and ID into r5
199    stw r4, 0x8(r3)             # Push up
200    stw r5, 0xC(r3)             # Push up
201    li r4, 0x0
202    stw r4, 0x0(r3)             # Zero Out
203    stw r4, 0x4(r3)             # Zero Out
204
205    # Move This Message Upwards Onscreen
206    lwz r4, 0x8(r3)             # Text Pointer
207    cmpwi r4, 0x0
208    beq ShiftQueue_IncLoop
209
210    # Move Message Downwards/Upwards Depending On The Area
211    bl ShiftQueue_Floats
212    mflr r3
213    mulli r5, AreaID, 0x4       # Area ID into offset
214    lfsx f1, r3, r5
215    lfs f2, 0x4(r4)             # Get Text's Y Value
216    fadds f1, f1, f2
217    stfs f1, 0x4(r4)            # Store Text's Y Value
218
219# Next Message
220ShiftQueue_IncLoop:
221    subi r31, r31, 0x1
222    cmpwi r31, 0x0
223    bge ShiftQueue_Loop
224
225ShiftQueue_Exit:
226    restore
227    blr
228
229################################################
230
231#####################
232## Check For Dupes ##
233#####################
234
235# Inputs:
236# r3 = OverlayID
237# r4 = Max Window Count
238# r5 = Message Queue Start
239
240CheckForDuplicates:
241    backup
242
243    mr r31, r3
244    mr r30, r4
245    mr r29, r5
246
247    # Search Loop For Matching Window
248    # Init Loop
249    li r28, 0x0                 # Matching Window Loop Count
250
251CheckForDuplicates_MatchingWindowLoop:
252    mulli r5, r28, 0x8          # Get Message's Offset
253    add r4, r5, r29             # Get Message's Location in Memory
254    lwz r3, 0x0(r4)             # Get Text Pointer
255    cmpwi r3, 0x0               # Check If This Entry Exists
256    beq CheckForDuplicates_MatchingWindowIncLoop
257    lhz r3, 0x6(r4)             # Get Window ID
258    cmpw r3, r31                # Check If They Match
259    bne CheckForDuplicates_MatchingWindowIncLoop
260
261    # Upon Finding a Match
262    # Remove This Window
263    lwz r3, 0x0(r4)
264    branchl r12, Text_RemoveText
265
266    # Zero Out Entry
267    mulli r5, r28, 0x8          # Get Message's Offset
268    add r4, r5, r29             # Get Message's Location in Memory
269    li r3, 0x0
270    stw r3, 0x0(r4)
271    stw r3, 0x4(r4)
272
273    # Init Shift Loop Count
274    addi r27, r28, 0x1          # Window After Matching Window ID = Shift Loop Count Starting Value
275
276# Loop - Move All Windows After This Down
277CheckForDuplicates_MatchingWindowShiftLoop:
278    mulli r5, r27, 0x8          # Get Message's Offset
279    add r4, r5, r29             # Get Message's Location in Memory
280    lwz r5, 0x0(r4)             # Load Text Pointer
281    lwz r6, 0x4(r4)             # Load Text Timer and ID
282    stw r5, -0x8(r4)            # Store Text Pointer
283    stw r6, -0x4(r4)            # Store Text Timer and ID
284    li r3, 0x0
285    stw r3, 0x0(r4)             # Zero Out
286    stw r3, 0x4(r4)             # Zero Out
287
288    # Move Message Downwards/Upwards Depending On The Area
289    lwz r3, -0x8(r4)            # Get Text Pointer
290    cmpwi r3, 0x0               # Check If This Entry Is Active
291    beq CheckForDuplicates_MatchingWindowShiftIncLoop
292    bl CheckForDuplicates_Floats
293    mflr r4
294    mulli r5, AreaID, 0x4       # Area ID into offset
295    lfsx f1, r4, r5
296    lfs f2, 0x4(r3)             # Get Text's Y Value
297    fadds f1, f1, f2
298    stfs f1, 0x4(r3)            # Store Text's Y Value
299
300CheckForDuplicates_MatchingWindowShiftIncLoop:
301    addi r27, r27, 0x1
302    cmpw r27, r30
303    blt CheckForDuplicates_MatchingWindowShiftLoop
304
305    b CheckForDuplicates_Exit
306
307CheckForDuplicates_MatchingWindowIncLoop:
308    addi r28, r28, 0x1
309    cmpw r28, r30
310    blt CheckForDuplicates_MatchingWindowLoop
311
312CheckForDuplicates_Exit:
313    restore
314    blr
315
316##############################
317
318TextProperties:
319    blrl
320
321    # Area 1(Above HUD)
322    .long 0xC1A80000            # X Base
323    .long 0x41300000            # Y Value
324    .long 0x41600000            # X Difference Between Players
325    .long 0x3D23D70A            # Text Size
326    .long 0xC3CD0000            # background Y position
327    .long 0x41400000            # background X stretch
328    .long 0x41E00000            # background Y stretch
329
330    # Area 2(top of screen)
331    .long 0xC1A80000            # X Base
332    .long 0xC1A00000            # Y Value
333    .long 0x41600000            # X Difference Between Players
334    .long 0x3D23D70A            # Text Size
335    .long 0xC3CD0000            # background Y position
336    .long 0x41180000            # background X stretch
337    .long 0x41E00000            # background Y stretch
338
339    # Area 3(Event Popup)
340    .long 0x00000000            # Whether to Use HUD Location, 0 = no
341    .float -15                  # Y Value
342    .float 19                   # X Value
343    .float 0.04                 # Canvas Size
344    .float -410                 # background Y position
345    .float 13.5                 # background X stretch
346    .float 28                   # background Y stretch
347
348##############################
349
350# ******************#
351ShiftQueue_Floats:
352    blrl
353    .long 0xC0900000            # Area 1
354    .long 0x40900000            # Area 2
355
356# ******************#
357
358# ******************#
359CheckForDuplicates_Floats:
360    blrl
361    .long 0x40900000            # Area 1
362    .long 0xC0900000            # Area 2
363
364# ******************#
365
366TextASCII3:
367    blrl
368    .long 0x815B0000
369
370Exit:
371    mr r3, text                 # return text pointer
372    restore
373    blr