fork/training-mode-ce

git clone https://git.julia.blue/fork/training-mode-ce

AitchMerge pull request #88 from NickCondron/remove-asm2c08d3a

nix
2.9 KiB126 linesraw
1    # To be inserted at 8016721c
2    .include "../Globals.s"
3
4    .set PlayerSlot, 27
5    .set StaticBlock, 26
6    .set SpawnTable, 25
7    .set SpawnOrder, 24
8    .set SpawnID, 23
9
10    backup
11
12    # Don't run in singleplayer
13    branchl r12, 0x8016b41c
14    cmpwi r3, 0
15    bne Original
16    # Don't run for players 5 and 6
17    cmpwi PlayerSlot, 5
18    bge Original
19
20    # Get static block
21    mr r3, PlayerSlot
22    branchl r12, Playerblock_LoadStaticBlock
23    mr StaticBlock, r3
24
25    # Get Neutral Spawn Table
26    bl NeutralRespawnTable
27    mflr SpawnTable
28
29    # Get this players spawn order
30    mr r3, PlayerSlot
31    bl GetSpawnOrder
32    mr SpawnOrder, r3
33
34    # Get stage ID
35    lwz r6, -0x6CB8(r13)
36    li r5, 0
37
38# Get stage's spawn info
39StageSearchLoop:
40    mulli r4, r5, 0x5               # table length
41    add r4, r4, SpawnTable          # get stage start
42    lbz r3, 0x0(r4)                 # get stage ID
43    extsb r3, r3
44    cmpwi r3, -1                    # check for end of table
45    beq Original
46    cmpw r3, r6                     # check for matching stage ID
47    addi r5, r5, 1                  # inc count
48    bne StageSearchLoop
49
50    # Get ID
51    addi r4, r4, 1                  # Skip past stage ID
52    lbzx r3, SpawnOrder, r4
53
54    b Exit
55
56######################
57GetSpawnOrder:
58    .set LoopCount, 31
59    .set SpawnOrder, 30
60    .set PlayerSlot, 28
61
62    backup
63    # Init variables
64    mr PlayerSlot, r3
65    li SpawnOrder, 0
66    li LoopCount, 0
67
68# Start Loop
69GetSpawnOrder_Loop:
70    # Load slot type
71    mr r3, LoopCount
72    branchl r12, PlayerBlock_LoadSlotType
73    cmpwi r3, 0x1
74    bgt GetSpawnOrder_IncLoop       # If >1, no player present
75    # Player is present, check if this is the one were looking for
76    cmpw PlayerSlot, LoopCount
77    beq GetSpawnOrder_Exit
78    # Increment offset
79    addi SpawnOrder, SpawnOrder, 1
80
81GetSpawnOrder_IncLoop:
82    addi LoopCount, LoopCount, 1
83    cmpwi LoopCount, 4
84    ble GetSpawnOrder_Loop
85
86GetSpawnOrder_Exit:
87    mr r3, SpawnOrder               # Return spawn order
88    restore
89    blr
90
91######################
92NeutralRespawnTable:
93    blrl
94    # FD
95    .byte 0x20                      # Stage ID
96    .byte 0x00, 0x01, 0x02, 0x03    # Nuetral Spawn Index
97    # Battlefield
98    .byte 0x1F                      # Stage ID
99    .byte 0x02, 0x03, 0x00, 0x01    # Nuetral Spawn Index
100    # Yoshi's Story
101    .byte 0x08                      # Stage ID
102    .byte 0x00, 0x01, 0x03, 0x02    # Nuetral Spawn Index
103    # Dream Land
104    .byte 0x1C                      # Stage ID
105    .byte 0x01, 0x03, 0x00, 0x02    # Nuetral Spawn Index
106    # FoD
107    .byte 0x02                      # Stage ID
108    .byte 0x00, 0x01, 0x02, 0x03    # Nuetral Spawn Index
109    # Pokemon Stadium
110    .byte 0x03                      # Stage ID
111    .byte 0x00, 0x01, 0x02, 0x03    # Nuetral Spawn Index
112    # Terminator
113    .byte 0xFF
114    .align 2
115
116######################
117
118Original:
119    restore
120    addi r3, r27, 0
121    b Skip
122
123Exit:
124    restore
125
126Skip: