fork/training-mode-ce

git clone https://git.julia.blue/fork/training-mode-ce

AitchMerge pull request #88 from NickCondron/remove-asm2c08d3a

nix
10.1 KiB454 linesraw
1    # To be inserted at 80225554
2    .include "../../Globals.s"
3
4    .set GObj_Create, 0x803901f0
5    .set GObj_AddUserData, 0x80390b68
6    .set GObj_AddProc, 0x8038fd54
7    .set HSD_MemAlloc, 0x8037f1e4
8    .set DevelopText_CreateDataTable, 0x80302834
9    .set DevelopText_Activate, 0x80302810
10    .set DevelopText_AddString, 0x80302be4
11    .set DevelopText_FormatAndPrint, 0x80302d4c
12    .set DevelopText_EraseAllText, 0x80302bb0
13    .set DevelopMode_Text_ResetCursorXY, 0x80302a3c
14    .set DevelopText_StoreBGColor, 0x80302b90
15    .set DevelopText_HideText, 0x80302b00
16    .set DevelopText_HideBG, 0x80302ae0
17    .set DevelopText_ShowText, 0x80302af0
18    .set DevelopText_ShowBG, 0x80302ad0
19    .set DevelopText_StoreTextScale, 0x80302b10
20    .set DevelopText_ResetCursorX, 0x80302a88
21    .set sprintf, 0x80323cf4
22
23    .set WindowData_Text, 0x0
24    .set WindowData_State, 0x4
25
26    .set REG_DevelopText, 31
27    .set REG_GObjData, 30
28    .set REG_GObj, 29
29
30    stw r0, -0x4B7C(r13)
31
32    backup
33
34    # Create Rectangle
35    li r3, 0x1000
36    branchl r12, HSD_MemAlloc
37    mr r8, r3
38    li r3, 12
39    li r4, 0
40    li r5, 0
41    li r6, 39
42    li r7, 10
43    branchl r12, DevelopText_CreateDataTable
44    mr REG_DevelopText, r3
45    # Activate Text
46    lwz r3, -0x4884(r13)
47    mr r4, REG_DevelopText
48    branchl r12, DevelopText_Activate
49    # Hide blinking cursor
50    li r3, 0
51    stb r3, 0x26(REG_DevelopText)
52    # Change BG Color
53    mr r3, REG_DevelopText
54    bl BGColor
55    mflr r4
56    branchl r12, DevelopText_StoreBGColor
57    # Hide by default
58    mr r3, REG_DevelopText
59    branchl r12, DevelopText_HideText
60    mr r3, REG_DevelopText
61    branchl r12, DevelopText_HideBG
62    # Change Text Size
63    mr r3, REG_DevelopText
64    bl TextFloats
65    mflr r4
66    lfs f1, 0x0(r4)
67    lfs f2, 0x4(r4)
68    branchl r12, DevelopText_StoreTextScale
69    # Create Background GObj
70    li r3, 0
71    li r4, 0
72    li r5, 0
73    branchl r12, GObj_Create
74    mr REG_GObj, r3
75    # Allocate Space
76    li r3, 64
77    branchl r12, HSD_MemAlloc
78    mr REG_GObjData, r3
79    # Zero
80    li r4, 64
81    branchl r12, ZeroAreaLength
82    # Initialize
83    mr r6, REG_GObjData
84    mr r3, REG_GObj
85    li r4, 4
86    load r5, HSD_Free
87    branchl r12, GObj_AddUserData
88    # Add Process
89    mr r3, REG_GObj
90    bl DebugLogThink
91    mflr r4
92    li r5, 7
93    li r6, 0
94    branchl r12, GObj_AddGXLink
95    # branchl r12, GObj_AddProc
96    # Store pointer to dev text
97    stw REG_DevelopText, WindowData_Text(REG_GObjData)
98    # Initialize State
99    li r3, 0
100    stw r3, WindowData_State(REG_GObjData)
101    b Exit
102
103########################################
104TextFloats:
105    blrl
106    .float 7.5
107    .float 10
108
109########################################
110
111DebugLogThink:
112    blrl
113    .set REG_GObjData, 31
114    .set REG_PlayerData, 30
115    backup
116
117    # Only run during pass 0
118    cmpwi r4, 0
119    bne DebugLogThink_Exit
120
121    lwz REG_GObjData, 0x2C(r3)
122
123    # Check for state change
124    bl GetInputs
125    rlwinm. r0, r3, 0, 0x200
126    beq DebugLogThink_StateChangeEnd
127    bl GetInputs
128    rlwinm. r0, r4, 0, 0x2
129    beq DebugLogThink_StateChangeEnd
130    # Inc state
131    lwz r3, WindowData_State(REG_GObjData)
132    addi r3, r3, 1
133    stw r3, WindowData_State(REG_GObjData)
134    cmpwi r3, 4
135    ble DebugLogThink_ShowWindow
136    # Loop back to hidden
137    li r3, 0
138    stw r3, WindowData_State(REG_GObjData)
139    # Hide
140    lwz r3, WindowData_Text(REG_GObjData)
141    branchl r12, DevelopText_HideText
142    lwz r3, WindowData_Text(REG_GObjData)
143    branchl r12, DevelopText_HideBG
144    b DebugLogThink_StateChangeEnd
145
146DebugLogThink_ShowWindow:
147    # Show
148    lwz r3, WindowData_Text(REG_GObjData)
149    branchl r12, DevelopText_ShowText
150    lwz r3, WindowData_Text(REG_GObjData)
151    branchl r12, DevelopText_ShowBG
152
153DebugLogThink_StateChangeEnd:
154    # Check to update text
155    lwz r3, WindowData_State(REG_GObjData)
156    cmpwi r3, 0
157    beq DebugLogThink_Exit
158
159    # Erase all text
160    lwz r3, WindowData_Text(REG_GObjData)
161    branchl r12, DevelopText_EraseAllText
162    lwz r3, WindowData_Text(REG_GObjData)
163    li r4, 0
164    li r5, 0
165    branchl r12, DevelopMode_Text_ResetCursorXY
166
167    # Output player number
168    lwz r3, WindowData_Text(REG_GObjData)
169    bl String_Player
170    mflr r4
171    lwz r5, WindowData_State(REG_GObjData)
172    branchl r12, DevelopText_FormatAndPrint
173
174    # Get current player data
175    lwz r3, WindowData_State(REG_GObjData)
176    subi r3, r3, 1
177    branchl r12, PlayerBlock_LoadMainCharDataOffset
178    cmpwi r3, 0
179    beq DebugLogThink_Exit
180    # Backup data
181    lwz REG_PlayerData, 0x2C(r3)
182
183    # vprintf string
184    lwz r3, WindowData_Text(REG_GObjData)
185    bl String_LStick
186    mflr r4
187    lfs f1, 0x620(REG_PlayerData)
188    lfs f2, 0x624(REG_PlayerData)
189    crset 6
190    branchl r12, DevelopText_FormatAndPrint
191
192    # vprintf string
193    lwz r3, WindowData_Text(REG_GObjData)
194    bl String_RStick
195    mflr r4
196    lfs f1, 0x638(REG_PlayerData)
197    lfs f2, 0x63C(REG_PlayerData)
198    crset 6
199    branchl r12, DevelopText_FormatAndPrint
200
201    # vprintf string
202    lwz r3, WindowData_Text(REG_GObjData)
203    bl String_CVel
204    mflr r4
205    lfs f1, 0x80(REG_PlayerData)
206    lfs f2, 0x84(REG_PlayerData)
207    crset 6
208    branchl r12, DevelopText_FormatAndPrint
209    # vprintf string
210    lwz r3, WindowData_Text(REG_GObjData)
211    bl String_KBVel
212    mflr r4
213    lfs f1, 0x8C(REG_PlayerData)
214    lfs f2, 0x90(REG_PlayerData)
215    crset 6
216    branchl r12, DevelopText_FormatAndPrint
217    # vprintf string
218    lwz r3, WindowData_Text(REG_GObjData)
219    bl String_Pos
220    mflr r4
221    lfs f1, 0xB0(REG_PlayerData)
222    lfs f2, 0xB4(REG_PlayerData)
223    crset 6
224    branchl r12, DevelopText_FormatAndPrint
225
226    # Output ECB Lock info
227    lwz r3, WindowData_Text(REG_GObjData)
228    bl String_ECBLock
229    mflr r4
230    lwz r5, 0x88C(REG_PlayerData)
231    crset 6
232    branchl r12, DevelopText_FormatAndPrint
233    # Output ECB Bottom info
234    lwz r3, WindowData_Text(REG_GObjData)
235    li r4, 18
236    branchl r12, DevelopText_ResetCursorX
237    lwz r3, WindowData_Text(REG_GObjData)
238    bl String_ECBBottom
239    mflr r4
240    lfs f1, 0x780(REG_PlayerData)
241    crset 6
242    branchl r12, DevelopText_FormatAndPrint
243
244    # Output State info
245    mr r3, REG_PlayerData
246    addi r4, sp, 0x88
247    bl GetStateInfo
248    stfs f1, 0x80(sp)
249    stfs f2, 0x84(sp)
250    mr r5, r3
251    lwz r3, WindowData_Text(REG_GObjData)
252    bl String_State
253    mflr r4
254    crset 6
255    branchl r12, DevelopText_FormatAndPrint
256    # Move cursor
257    lwz r3, WindowData_Text(REG_GObjData)
258    li r4, 25
259    branchl r12, DevelopText_ResetCursorX
260    # Output frames
261    lwz r3, WindowData_Text(REG_GObjData)
262    bl String_StateFrame
263    mflr r4
264    lfs f1, 0x80(sp)
265    lfs f2, 0x84(sp)
266    crset 6
267    branchl r12, DevelopText_FormatAndPrint
268
269DebugLogThink_Exit:
270    restore
271    blr
272
273#############################
274String_Player:
275    blrl
276    .string "Player %d X Y\n"
277    .align 2
278
279String_LStick:
280    blrl
281    .string "LStick: %1.4f %1.4f\n"
282    .align 2
283
284String_RStick:
285    blrl
286    .string "RStick: %1.4f %1.4f\n"
287    .align 2
288
289String_CVel:
290    blrl
291    .string "SelfVel: %3.4f %3.4f\n"
292    .align 2
293
294String_KBVel:
295    blrl
296    .string "KBVel: %3.4f %3.4f\n"
297    .align 2
298
299String_XVel:
300    blrl
301    .string "XVel: %3.4f %3.4f\n"
302    .align 2
303
304String_Pos:
305    blrl
306    .string "Pos: %3.4f %3.4f\n\n"
307    .align 2
308
309String_State:
310    blrl
311    .string "State: %s"
312    .align 2
313
314String_StateFrame:
315    blrl
316    .string "f: %03.2f/%1.0f"
317    .align 2
318
319String_ECBBottom:
320    blrl
321    .string "ECB_Bot: %03.2f\n\n"
322    .align 2
323
324String_ECBLock:
325    blrl
326    .string "ECB_Lock: %d"
327    .align 2
328
329BGColor:
330    blrl
331    .byte 21, 20, 59, 135
332
333###############################
334
335GetInputs:
336    .set REG_InputStruct, 11
337    .set REG_Count, 10
338    .set REG_HeldInputs, 9
339    .set REG_InstantInputs, 8
340
341    # Load Input Struct
342    load REG_InputStruct, 0x804c1fac
343
344    # Init loop
345    li REG_Count, 0
346    li REG_HeldInputs, 0
347    li REG_InstantInputs, 0
348
349GetInputs_Loop:
350    # Get to inputs
351    mulli r3, REG_Count, 68
352    add r5, r3, REG_InputStruct
353    # Grab Inputs
354    lwz r3, 0x0(r5)
355    lwz r4, 0xC(r5)
356    # OR all inputs
357    or REG_HeldInputs, REG_HeldInputs, r3
358    or REG_InstantInputs, REG_InstantInputs, r4
359    # Inc
360    addi REG_Count, REG_Count, 1
361    cmpwi REG_Count, 4
362    blt GetInputs_Loop
363
364GetInputs_Exit:
365    mr r3, REG_HeldInputs
366    mr r4, REG_InstantInputs
367    blr
368
369######################################
370GetStateInfo:
371    .set REG_PlayerData, 31
372    .set REG_StateString, 30
373
374    backup
375
376    mr REG_PlayerData, r3
377    mr REG_StateString, r4
378
379    # Check if common move
380    lwz r3, 0x10(REG_PlayerData)
381    cmpwi r3, 341
382    bge GetStateInfo_SpecialMove
383
384GetStateInfo_SharedMove:
385    mulli r3, r3, 4
386    lwz r4, -0x4B78(r13)
387    lwzx r4, r3, r4
388    mr r3, REG_StateString
389    branchl r12, strcpy
390    b GetStateInfo_GetRemainingFrames
391
392GetStateInfo_SpecialMove:
393    # Get Animation Data Pointer
394    mr r3, REG_PlayerData
395    lwz r4, 0x14(REG_PlayerData)
396    branchl r12, 0x80085fd4
397
398    # Get Move Name String
399    lwz r3, 0x0(r3)
400    cmpwi r3, 0
401    beq GetStateInfo_Unknown
402
403# Get Start of Move Name
404GetStateInfo_StringSearchLoop:
405    lbzu r4, 0x1(r3)
406    cmpwi r4, 0x4E                  # Check For "N"
407    bne GetStateInfo_StringSearchLoop
408    lbzu r4, 0x1(r3)
409    cmpwi r4, 0x5F                  # Check for Underscore
410    bne GetStateInfo_StringSearchLoop
411    addi r3, r3, 0x1                # Start of Move Name in r3
412    # Copy Move Name To Cut Off "fiagtree" Text
413    subi r4, REG_StateString, 0x1
414    subi r3, r3, 0x1
415
416GetStateInfo_StringCopyLoop:
417    lbzu r6, 0x1(r3)
418    cmpwi r6, 0x5F                  # Check for Underscore
419    beq GetStateInfo_ExitCopyLoop
420    stbu r6, 0x1(r4)
421    b GetStateInfo_StringCopyLoop
422
423GetStateInfo_ExitCopyLoop:
424    li r3, 0x0
425    stbu r3, 0x1(r4)
426    b GetStateInfo_GetRemainingFrames
427
428GetStateInfo_Unknown:
429    bl GetStateInfo_UnkString
430    mflr r4
431    mr r3, REG_StateString
432    branchl r12, strcpy
433
434GetStateInfo_GetRemainingFrames:
435    # Get Remaining Frames
436    lwz r3, 0x590(REG_PlayerData)   # get anim data
437    lfs f2, 0x008(r3)               # get anim length (float)
438
439GetStateInfo_Exit:
440    mr r3, REG_StateString
441    lfs f1, 0x894(REG_PlayerData)
442    restore
443    blr
444
445##########################################
446GetStateInfo_UnkString:
447    blrl
448    .string "UnkState"
449    .align 2
450
451##########################################
452
453Exit:
454    restore