fork/training-mode-ce

git clone https://git.julia.blue/fork/training-mode-ce

AitchMerge pull request #243 from NickCondron/remove-asmf9241ee

nix
3.2 KiB143 linesraw
1    # To be inserted at 8024d80c
2    .include "../../../../Globals.s"
3    .include "../../../../m-ex/Header.s"
4
5    .set HeaderLength, 0xB
6
7    .set EventID, 30
8
9    # Get Event ID
10    lbz r3, 0x0(r31)
11    lwz r4, 0x4(r31)
12    add r4, r3, r4
13    # Get page number
14    lwz r3, MemcardData(r13)
15    lbz r3, CurrentEventPage(r3)
16    # Get Event Description ASCII
17    rtocbl r12, TM_GetEventDescription
18
19CustomEvent:
20    .set text, 24
21    .set ascii, 23
22
23    mflr r0
24    stw r0, 0x4(r1)
25    stwu r1, -0x200(r1)         # make space for 12 registers
26    stmw r20, 0x8(r1)
27
28    # Backup ASCII
29    mr ascii, r3
30
31    # Create Text
32    li r3, 0
33    li r4, 0
34    branchl r12, Text_CreateTextStruct
35    mr text, r3
36    # Store pointer to text so it can be removed by the game
37    stw text, 0x78(r31)
38    # Set Text Values
39    lfs f1, -0x384C(rtoc)
40    lfs f2, -0x3848(rtoc)
41    lfs f3, -0x3874(rtoc)
42    lfs f4, -0x386C(rtoc)
43    lfs f5, -0x3868(rtoc)
44    stfs f1, 0x00(text)
45    stfs f2, 0x04(text)
46    stfs f3, 0x08(text)
47    stfs f4, 0x0C(text)
48    stfs f5, 0x10(text)
49    lfs f0, -0x3844(rtoc)
50    stfs f0, 0x0024(text)
51    stfs f0, 0x0028(text)
52
53    # Convert To Menu Text
54    mr r4, ascii                # ASCII To Store
55    addi r3, sp, 0x40
56    branchl r12, 0x803a67ec
57    # Backup Length
58    mr r20, r3
59
60    # Get Allocation Info Pointer
61    lwz r21, 0x64(text)
62    # Check To Adjust Allocation
63    lwz r22, 0x0004(r21)        # Get old menu text allocation
64    lwz r0, 0(r21)
65    lwz r4, 0x0008(r21)         # Get size of allocation
66    sub r3, r0, r22
67    addi r0, r3, 17
68    add r0, r20, r0
69    cmplw r4, r0
70    bge- NoAdjustAllocation
71    sub r0, r0, r4
72    rlwinm r3, r0, 25, 7, 31
73    addi r0, r3, 1
74    rlwinm r0, r0, 7, 0, 24
75    add r0, r4, r0
76    stw r0, 0x0008(r21)
77    lwz r3, 0x0008(r21)
78    branchl r12, 0x803A5798
79    addi r5, r22, 0
80    addi r4, r3, 0
81    li r7, 0
82    b ReAllocateLoop_Inc
83
84ReAllocateLoop:
85    lbz r0, 0(r5)
86    addi r7, r7, 1
87    addi r5, r5, 1
88    stb r0, 0(r4)
89    addi r4, r4, 1
90
91ReAllocateLoop_Inc:
92    lwz r6, 0x0004(r21)
93    lwz r0, 0(r21)
94    sub r6, r0, r6
95    addi r0, r6, 1
96    cmpw r7, r0
97    blt+ ReAllocateLoop
98    stw r3, 0x0004(r21)
99    stw r3, 0x005C(text)
100    lwz r0, 0(r21)
101    sub r0, r0, r22
102    add r0, r3, r0
103    stw r0, 0(r21)
104    mr r3, r22
105    branchl r12, 0x803A594C
106
107NoAdjustAllocation:
108    # Copy Header to Text Allocation
109    lwz r3, 0x5C(text)          # Get Pointer to Next Available Menu Text Location
110    bl DescriptionHeader
111    mflr r4
112    li r5, HeaderLength
113    branchl r12, memcpy
114
115    # Copy Text to Text Allocation
116    mr r5, r20                  # Length
117    lwz r3, 0x5C(text)          # Get Pointer to Next Available Menu Text Location
118    addi r3, r3, HeaderLength   # Skip Past Header
119    addi r4, sp, 0x40
120    branchl r12, memcpy
121
122    # Add Terminator
123    li r3, 0x1900
124    lwz r4, 0x5C(text)
125    addi r4, r4, HeaderLength   # Skip Header Length
126    add r4, r4, r20             # Skip Text Length
127    sth r3, 0x0(r4)
128
129Exit:
130    lmw r20, 0x8(r1)
131    lwz r0, 0x204(r1)
132    addi r1, r1, 0x200          # release the space
133    mtlr r0
134    branch r12, 0x8024d84c
135
136DescriptionHeader:
137    blrl
138    .long 0x160caaaa
139    .long 0xaa0e00b3
140    .long 0x00b31800
141
142VanillaEvent:
143    rlwinm r3, r30, 1, 0, 30