fork/training-mode-ce

git clone https://git.julia.blue/fork/training-mode-ce

AitchMerge pull request #243 from NickCondron/remove-asmf9241ee

nix
7.5 KiB298 linesraw
1    # To be inserted at 8024e568
2    .include "../../../../Globals.s"
3    .include "../../../../m-ex/Header.s"
4
5    .set text, 31
6    .set textproperties, 30
7
8    .set MainTextOffset, -0x4EB4
9    .set LeftArrowTextOffset, -0x4EB0
10    .set RightArrowTextOffset, -0x4EAC
11    .set MenuBackgroundPointer, -0x4EA4
12    .set MenuTextPointer, -0x4EA0
13
14    backup
15
16    # GET PROPERTIES TABLE
17    bl TEXTPROPERTIES
18    mflr textproperties
19
20    # Init background pointer
21    li r3, 0
22    stw r3, MenuBackgroundPointer(r13)
23
24########################
25## Create Text Object ##
26########################
27
28    # CREATE TEXT OBJECT, RETURN POINTER TO STRUCT IN r3
29    li r3, 0
30    li r4, 0
31    branchl r12, Text_CreateTextStruct
32    # BACKUP STRUCT POINTER
33    mr text, r3
34    # STORE POINTER
35    stw text, MainTextOffset(r13)
36    # SET TEXT SPACING TO TIGHT
37    li r4, 0x1
38    stb r4, 0x49(text)
39    # SET TEXT TO CENTER AROUND X LOCATION
40    li r4, 0x1
41    stb r4, 0x4A(text)
42    # Store Base Z Offset
43    lfs f1, ZOffset(textproperties)     # Z offset
44    stfs f1, 0x8(text)
45    # Scale Canvas Down
46    lfs f1, CanvasScaling(textproperties)
47    stfs f1, 0x24(text)
48    stfs f1, 0x28(text)
49
50###############
51## Page Name ##
52###############
53
54    # Get Current Page
55    lwz r3, MemcardData(r13)
56    lbz r3, CurrentEventPage(r3)
57    rtocbl r12, TM_GetPageName
58    # Initialize Subtext
59    mr r4, r3
60    lfs f1, PageX(textproperties)       # X offset of text
61    lfs f2, PageY(textproperties)       # Y offset of text
62    mr r3, text                         # struct pointer
63    branchl r12, Text_InitializeSubtext
64
65#############
66## L = OSD ##
67#############
68
69    # Initialize Subtext
70    lfs f1, LX(textproperties)          # X offset of text
71    lfs f2, LY(textproperties)          # Y offset of text
72    mr r3, text                         # struct pointer
73    bl LText
74    mflr r4                             # pointer to ASCII
75    branchl r12, Text_InitializeSubtext
76    # Change scale
77    mr r4, r3
78    mr r3, text
79    lfs f1, RScale(textproperties)
80    lfs f2, RScale(textproperties)
81    branchl r12, Text_UpdateSubtextSize
82
83##################
84## Version Text ##
85##################
86
87    # Get version string
88    rtocbl r12, TM_GetTMVersLong
89    mr r4, r3
90    # Initialize Subtext
91    lfs f1, VersionX(textproperties)    # X offset of text
92    lfs f2, VersionY(textproperties)    # Y offset of text
93    mr r3, text                         # struct pointer
94    branchl r12, Text_InitializeSubtext
95    # Temp remember subtext ID
96    mr r20, r3
97    # Change scale
98    mr r4, r20
99    mr r3, text
100    lfs f1, VersionScale(textproperties)
101    lfs f2, VersionScale(textproperties)
102    branchl r12, Text_UpdateSubtextSize
103
104    # Change Color
105    mr r4, r20                          # subtext id
106    mr r3, text                         # text pointer
107    load r5, 0x8dff6eff
108    stw r5, 0xF0(sp)
109    addi r5, sp, 0xF0
110    branchl r12, Text_ChangeTextColor
111
112    /*
113#################
114## Z = Options ##
115#################
116
117    # Initialize Subtext
118    lfs f1, OptionsX(textproperties)    # X offset of text
119    lfs f2, OptionsY(textproperties)    # Y offset of text
120    mr r3, text                         # struct pointer
121    bl OptionsText
122    mflr r4                             # pointer to ASCII
123    branchl r12, Text_InitializeSubtext
124    # Change scale
125    mr r4, r3
126    mr r3, text
127    lfs f1, OptionsScale(textproperties)
128    lfs f2, OptionsScale(textproperties)
129    branchl r12, Text_UpdateSubtextSize
130    */
131
132###############################
133## Left Page Arrow Indicator ##
134###############################
135
136    # CREATE TEXT OBJECT, RETURN POINTER TO STRUCT IN r3
137    li r3, 0
138    li r4, 0
139    branchl r12, Text_CreateTextStruct
140    # BACKUP STRUCT POINTER
141    mr text, r3
142    # STORE POINTER
143    stw text, LeftArrowTextOffset(r13)
144    # SET TEXT SPACING TO TIGHT
145    li r4, 0x1
146    stb r4, 0x49(text)
147    # SET TEXT TO CENTER AROUND X LOCATION
148    li r4, 0x1
149    stb r4, 0x4A(text)
150    # Store Base Z Offset
151    lfs f1, ZOffset(textproperties)     # Z offset
152    stfs f1, 0x8(text)
153    # Scale Canvas Down
154    lfs f1, CanvasScaling(textproperties)
155    stfs f1, 0x24(text)
156    stfs f1, 0x28(text)
157
158    # Initialize Subtext
159    lfs f1, LeftArrowX(textproperties)  # X offset of text
160    lfs f2, ArrowY(textproperties)      # Y offset of text
161    mr r3, text                         # struct pointer
162    bl PageArrowLeft
163    mflr r4
164    branchl r12, Text_InitializeSubtext
165    # Change scale
166    mr r4, r3
167    mr r3, text
168    lfs f1, ArrowScale(textproperties)
169    lfs f2, ArrowScale(textproperties)
170    branchl r12, Text_UpdateSubtextSize
171
172###############################
173## Right Page Arrow Indicator ##
174###############################
175
176    # CREATE TEXT OBJECT, RETURN POINTER TO STRUCT IN r3
177    li r3, 0
178    li r4, 0
179    branchl r12, Text_CreateTextStruct
180    # BACKUP STRUCT POINTER
181    mr text, r3
182    # STORE POINTER
183    stw text, RightArrowTextOffset(r13)
184    # SET TEXT SPACING TO TIGHT
185    li r4, 0x1
186    stb r4, 0x49(text)
187    # SET TEXT TO CENTER AROUND X LOCATION
188    li r4, 0x1
189    stb r4, 0x4A(text)
190    # Store Base Z Offset
191    lfs f1, ZOffset(textproperties)     # Z offset
192    stfs f1, 0x8(text)
193    # Scale Canvas Down
194    lfs f1, CanvasScaling(textproperties)
195    stfs f1, 0x24(text)
196    stfs f1, 0x28(text)
197
198    # Initialize Subtext
199    lfs f1, RightArrowX(textproperties) # X offset of text
200    lfs f2, ArrowY(textproperties)      # Y offset of text
201    mr r3, text                         # struct pointer
202    bl PageArrowRight
203    mflr r4
204    branchl r12, Text_InitializeSubtext
205
206    # Change scale
207    mr r4, r3
208    mr r3, text
209    lfs f1, ArrowScale(textproperties)
210    lfs f2, ArrowScale(textproperties)
211    branchl r12, Text_UpdateSubtextSize
212
213    b end
214
215# **************************************************#
216TEXTPROPERTIES:
217    blrl
218    .set PageX, 0x0
219    .set PageY, 0x4
220    .set ZOffset, 0x8
221    .set RX, 0xC
222    .set RY, 0x10
223    .set RScale, 0x14
224    .set LX, 0x18
225    .set LY, 0x1C
226    .set VersionX, 0x20
227    .set VersionY, 0x24
228    .set VersionScale, 0x28
229    .set CanvasScaling, 0x2C
230    .set ArrowY, 0x30
231    .set LeftArrowX, 0x34
232    .set RightArrowX, 0x38
233    .set ArrowScale, 0x3C
234    .set OptionsX, 0x40
235    .set OptionsY, 0x44
236    .set OptionsScale, 0x48
237
238    # Page
239    .float 0                            # text X pos
240    .float -240                         # text Y pos
241    .float 17                           # Z offset
242
243    # Press R
244    .float 310                          # text X pos
245    .float -230                         # text Y pos
246    .float 0.8                          # scale
247
248    # Press L
249    .float -310                         # text X pos
250    .float -230                         # text Y pos
251
252    # Version
253    .float 0                            # text X pos
254    .float -212                         # text Y pos
255    .float 0.6                          # text scale
256
257    .float 0.035                        # Canvas Scaling
258
259    # Arrows
260    .float -215                         # Y coordinate
261    .float -210                         # left X
262    .float 210                          # Right X
263    .float 0.7                          # Scale
264
265    # Options
266    .float 299                          # text X pos
267    .float -282                         # text Y pos
268    .float 0.8                          # text scale
269
270NullString:
271    blrl
272    .string "Null"
273    .align 2
274
275PageArrowLeft:
276    blrl
277    .string "<"
278    .align 2
279
280PageArrowRight:
281    blrl
282    .string ">"
283    .align 2
284
285LText:
286    blrl
287    .string "L = OSD"
288    .align 2
289
290OptionsText:
291    blrl
292    .string "Z = Options"
293    .align 2
294
295# **************************************************#
296end:
297    restore
298    lwz r3, 0(r30)