fork/training-mode-ce

git clone https://git.julia.blue/fork/training-mode-ce

AitchMerge pull request #243 from NickCondron/remove-asmf9241ee

nix
5.7 KiB258 linesraw
1    # To be inserted at 801a10e8
2    .include "../../../Globals.s"
3    .include "../../../m-ex/Header.s"
4
5    .set text, 31
6    .set textproperties, 30
7    .set staticTextData, 29
8    .set inputStruct, 28
9    .set GObj, 31
10
11    backup
12
13    # Only in Event Mode
14    load r3, SceneController
15    lbz r3, Scene.CurrentMajor(r3)
16    cmpwi r3, Scene.EventMode
17    bne Exit
18
19    load staticTextData, 0x804a1f58
20
21    # CREATE TEXT OBJECT, RETURN POINTER TO STRUCT IN r3
22    li r3, 2
23    lwz r4, 0x0(staticTextData)
24    branchl r12, Text_CreateTextStruct
25    mr text, r3
26
27    # Store pointer to text
28    stw r3, 0x8(staticTextData)
29
30    # Get Properties
31    bl Text_Properties
32    mflr textproperties
33
34    # Check Who Paused
35    load r3, 0x8046b69c
36    lbz r3, 0x5(r3)
37    # Get Inputs
38    mulli r3, r3, 68
39    load r4, 0x804c21cc
40    add inputStruct, r3, r4
41
42    # SET TEXT SPACING TO TIGHT
43    li r4, 0x0
44    stb r4, 0x49(text)
45
46    # SET TEXT TO NOT CENTER AROUND X LOCATION
47    li r4, 0x0
48    stb r4, 0x4A(text)
49
50    # Change Background Text Color
51    li r3, 0x0
52    stw r3, 0x30(text)
53    # Init Background Text
54    mr r3, text                     # struct pointer
55    lfs f1, 0x10(textproperties)    # X offset of text
56    lfs f2, 0x14(textproperties)    # Y offset of text
57    bl TextBackground
58    mflr r4
59    branchl r12, Text_InitializeSubtext
60    # set size/scaling
61    mr r4, r3
62    mr r3, text
63    lfs f1, 0x18(textproperties)    # get text scaling value from table
64    lfs f2, 0x1C(textproperties)    # get text scaling value from table
65    branchl r12, Text_UpdateSubtextSize
66
67    # SET TEXT SPACING TO TIGHT
68    li r4, 0x1
69    stb r4, 0x49(text)
70
71    # Init Textline X
72    mr r3, text                     # struct pointer
73    lfs f1, 0x0(textproperties)     # X offset of text
74    lfs f2, 0x4(textproperties)     # Y offset of text
75    bl TextX
76    mflr r4
77    lbz r5, 0x18(inputStruct)
78    lfs f3, 0x20(inputStruct)
79    crset 6
80    branchl r12, Text_InitializeSubtext
81    # set size/scaling
82    mr r4, r3
83    mr r3, text
84    lfs f1, 0x8(textproperties)     # get text scaling value from table
85    lfs f2, 0x8(textproperties)     # get text scaling value from table
86    branchl r12, Text_UpdateSubtextSize
87
88    # Init Textline Y
89    mr r3, text                     # struct pointer
90    lfs f1, 0x0(textproperties)     # X offset of text
91    lfs f2, 0xC(textproperties)     # Y offset of text
92    bl TextY
93    mflr r4
94    lbz r5, 0x19(inputStruct)
95    lfs f3, 0x24(inputStruct)
96    crset 6
97    branchl r12, Text_InitializeSubtext
98    # set size/scaling
99    mr r4, r3
100    mr r3, text
101    lfs f1, 0x8(textproperties)     # get text scaling value from table
102    lfs f2, 0x8(textproperties)     # get text scaling value from table
103    branchl r12, Text_UpdateSubtextSize
104
105###############################
106## Schedule Updater Function ##
107###############################
108
109    # Create GObj
110    li r3, 6
111    li r4, 0
112    li r5, 128
113    branchl r12, GObj_Create
114    mr GObj, r3
115
116    # Store Pointer
117    stw GObj, 0xC(staticTextData)
118
119    # Attach Per Frame Process
120    mr r3, GObj
121    bl TextUpdateFunction
122    mflr r4
123    li r5, 10
124    branchl r12, GObj_AddProc
125
126    b Exit
127
128# **************************************************#
129
130TextBackground:
131    blrl
132    .long 0x815B0000
133
134TextX:
135    blrl
136    .long 0x583a2025
137    .long 0x342e3466
138    .long 0x20815e20
139    .long 0x25640000
140
141TextY:
142    blrl
143    .long 0x593a2025
144    .long 0x342e3466
145    .long 0x20815e20
146    .long 0x25640000
147
148# **************************************************#
149
150Text_Properties:
151    blrl
152    .long 0xC1D80000                # X VALUE x offset (-27)
153    .long 0xC1B80000                # X VALUE y offset (-23)
154    .long 0x3D4CCCCD                # XANDY text scaling
155    .long 0xC1A80000                # Y VALUE y offset (-21)
156    .long 0xC1E80000                # background x offset (-29)
157    .long 0xC1000000                # background y offset (-8)
158    .float 0.50                     # background X text scaling #0.56
159    .float 1.08                     # background Y text scaling #1.08
160
161# ***************************************************#
162
163TextUpdateFunction:
164    blrl
165    backup
166
167    # Get Text Info
168    load staticTextData, 0x804a1f58
169    lwz text, 0x8(staticTextData)
170
171    # Check Who Paused
172    load r3, 0x8046b69c
173    lbz r3, 0x5(r3)
174    # Get Inputs
175    mulli r3, r3, 68
176    load r4, 0x804c21cc
177    add inputStruct, r3, r4
178
179    # Update X Color
180    lbz r6, 0x18(inputStruct)
181    extsb r6, r6
182    cmpwi r6, 0x0
183    blt XNeg
184
185XPos:
186    load r3, 0x8dff6eff
187    b XUpdateColor
188
189XNeg:
190    load r3, 0xffa2baff
191    b XUpdateColor
192
193XUpdateColor:
194    stw r3, 0xF8(sp)
195    mr r3, text
196    li r4, 1
197    addi r5, sp, 0xF8
198    branchl r12, Text_ChangeTextColor
199
200    # Update Textline X
201    mr r3, text                     # struct pointer
202    li r4, 1
203    bl TextX
204    mflr r5
205    lbz r6, 0x18(inputStruct)
206    extsb r6, r6
207    cmpwi r6, 0
208    bge 0x8
209    neg r6, r6
210    lfs f1, 0x20(inputStruct)
211    fabs f1, f1
212    crset 6
213    branchl r12, Text_UpdateSubtextContents
214
215    # Update Y Color
216    lbz r6, 0x19(inputStruct)
217    extsb r6, r6
218    cmpwi r6, 0x0
219    blt YNeg
220
221YPos:
222    load r3, 0x8dff6eff
223    b YUpdateColor
224
225YNeg:
226    load r3, 0xffa2baff
227    b YUpdateColor
228
229YUpdateColor:
230    stw r3, 0xF8(sp)
231    mr r3, text
232    li r4, 2
233    addi r5, sp, 0xF8
234    branchl r12, Text_ChangeTextColor
235
236    # Update Textline Y
237    mr r3, text                     # struct pointer
238    li r4, 2
239    bl TextY
240    mflr r5
241    lbz r6, 0x19(inputStruct)
242    extsb r6, r6
243    cmpwi r6, 0
244    bge 0x8
245    neg r6, r6
246    lfs f1, 0x24(inputStruct)
247    fabs f1, f1
248    crset 6
249    branchl r12, Text_UpdateSubtextContents
250
251    restore
252    blr
253
254# ***************************************************#
255
256Exit:
257    restore
258    lmw r26, 0x0018(sp)