fork/training-mode-ce

git clone https://git.julia.blue/fork/training-mode-ce

AitchMerge pull request #88 from NickCondron/remove-asm2c08d3a

nix
2.1 KiB83 linesraw
1    # To be inserted at 80375384
2    .include "../Globals.s"
3
4    .set GeckoCodehandler, 0x8040a5e4
5    .set HeaderSize, 32
6
7    #########################
8    ## LOAD FILE FROM DISC ##
9    #########################
10    backup
11
12    # Backup ArenaLo to r25
13    mr r25, r31
14
15    # Get File Name
16    bl fileName
17    mflr r3
18
19    # Get File Length For Heap Creation
20    mr r29, r3
21    branchl r12, 0x800163D8
22
23    # Check If File Exists
24    cmpwi r3, -1
25    bne CreateHeapBoundaries
26    mr r3, r25
27    b exit
28
29    # Create Heap Boundaries
30    .set REG_FileSize, 28
31
32CreateHeapBoundaries:
33    addi r3, r3, HeaderSize             # add some extra space for the header
34    addi r0, r3, 31                     # allign to something
35    rlwinm REG_FileSize, r0, 0, 0, 26   # allign to something
36    mr r3, r25                          # r3 = start of heap
37    add r25, r3, REG_FileSize           # ArenaHi = ArenaLo+ .gct size
38    addi r25, r25, 0x500                # ArenaHi = ArenaHi+ 0x500(misc space for file loading)
39    mr r4, r25                          # r4= end of heap
40    branchl r12, 0x803440e8             # Create Heap
41    stw r3, -0x5688(r13)                # Store Active Heap
42
43    # Allocate persistent file space
44    .set REG_Codeset, 27
45    li r3, 0
46    mr r4, REG_FileSize
47    branchl r12, 0x80015BD0
48    # Load File
49    addi REG_Codeset, r3, 0
50    addi r3, r29, 0
51    addi r4, REG_Codeset, HeaderSize
52    addi r5, sp, 12
53    branchl r12, 0x8001668C
54
55    # Store codeset pointer and length
56    stw REG_Codeset, CodesetPointer(rtoc)
57    stw REG_FileSize, 0x0(REG_Codeset)
58
59    # Run Codehandler
60    addi r4, REG_Codeset, HeaderSize
61    branchl r12, GeckoCodehandler
62
63    # Now flush the instruction cache
64    lis r3, 0x8000
65    load r4, 0x3b722c                   # might be overkill but flush the entire dol file
66    branchl r12, 0x80328f50
67
68    # Return End of Heap
69    mr r3, r25
70
71    b exit
72
73fileName:
74    blrl
75
76    .string "codes.gct"
77    .align 2
78
79# EXIT
80exit:
81    restore
82    mr r31, r3                          # r31 = start of next heap
83    addi r3, r31, 31                    # original codeline