fork/training-mode-ce

git clone https://git.julia.blue/fork/training-mode-ce

AitchMerge pull request #242 from NickCondron/remove-asm96edbd1

nix
3.9 KiB163 linesraw
1    # To be inserted at 803753b0
2    .include "../../Globals.s"
3    .include "../../m-ex/Header.s"
4    .include "../../m-ex/Header.s"
5
6    # ftX struct
7    .set ftX_Code, 0x0
8    .set ftX_InstructionRelocTable, 0x4
9    .set ftX_InstructionRelocTableCount, 0x8
10    .set ftX_FunctionRelocTable, 0xC
11    .set FunctionRelocTable_ReplaceThis, 0x0
12    .set FunctionRelocTable_ReplaceWith, 0x4
13    .set ftX_FunctionRelocTableCount, 0x10
14
15    .set REG_HeapLo, 31
16    .set REG_FileSize, 28
17    .set REG_File, 27
18    .set REG_HeapID, 26
19    .set REG_Header, 25
20    .set REG_mexData, 24
21
22    stw r31, -0x3FE8(r13)
23
24    backup
25
26    # Check if file exists
27    bl FileName
28    mflr r3
29    branchl r12, 0x8033796c
30    cmpwi r3, -1
31    beq Exit
32    # Get size of TmDt.dat
33    bl FileName
34    mflr r3
35    branchl r12, 0x800163d8
36    addi REG_FileSize, r3, 0
37    # ALlign
38    addi REG_FileSize, REG_FileSize, 31
39    rlwinm REG_FileSize, REG_FileSize, 0, 0, 26
40    # Create heap of this size
41    add r4, REG_HeapLo, REG_FileSize                    # heap hi = start + filesize
42    addi r4, r4, 32*5                                   # plus 96 for header
43    mr r3, REG_HeapLo                                   # heap lo = start
44    mr REG_HeapLo, r4                                   # new start = heap hi
45    branchl r12, 0x803440e8
46    mr REG_HeapID, r3
47    # Alloc header
48    li r4, 68
49    branchl r12, 0x80343ef0
50    mr REG_Header, r3
51    # Alloc from this heap
52    mr r3, REG_HeapID
53    mr r4, REG_FileSize
54    branchl r12, 0x80343ef0
55    mr REG_File, r3
56    # Load file here
57    bl FileName
58    mflr r3
59    mr r4, REG_File
60    addi r5, sp, 0x80
61    branchl r12, 0x8001668C
62    # Init Archive
63    lwz r5, 0x80(sp)
64    mr r3, REG_Header                                   # store header
65    mr r4, REG_File                                     # file
66    branchl r12, 0x80016a54
67    # Get symbol offset
68    mr r3, REG_Header
69    bl SymbolName
70    mflr r4
71    branchl r12, 0x80380358
72    mr. REG_mexData, r3
73    beq mexPatch_Skip
74    # Reloc
75    lwz r3, ftX_InstructionRelocTableCount(REG_mexData) # count
76    lwz r4, ftX_Code(REG_mexData)                       # code
77    lwz r5, ftX_InstructionRelocTable(REG_mexData)      # reloc table
78    branchl r12, Reloc
79    # Overload
80    mr r3, REG_mexData
81    addi r4, rtoc, TM_tmFunction
82    bl Overload
83
84mexPatch_Skip:
85    # Flush instruction cache so code can be run from this file
86    mr r3, REG_File
87    mr r4, REG_FileSize
88    branchl r12, 0x80328f50
89
90    # Run TM_OnFileLoad
91    lwz r12, TM_OnFileLoad(rtoc)
92    cmpwi r12, 0
93    beq Skip_OnFileLoad
94    mr r3, REG_Header
95    mtctr r12
96    bctrl
97
98Skip_OnFileLoad:
99    b Exit
100
101###########################################
102
103Overload:
104    # r3 = ftX
105    # r4 = table
106    # Copy function pointers - init
107    .set REG_ftX, 12
108    .set REG_ThisElement, 11
109    .set REG_Code, 10
110    .set REG_OverloadTable, 9
111    .set REG_Count, 8
112    .set REG_RelocTable, 7
113    mr REG_ftX, r3
114    mr REG_OverloadTable, r4
115    lwz REG_RelocTable, ftX_FunctionRelocTable(REG_ftX)
116    lwz REG_Code, 0x0(REG_ftX)
117    li REG_Count, 0
118    b Overload_CheckLoop
119
120Overload_Loop:
121    # Get this element
122    mulli r3, REG_Count, 8
123    add REG_ThisElement, r3, REG_RelocTable
124
125Overload_TableIndex:
126    # Get ram offset for this function
127    lwz r3, FunctionRelocTable_ReplaceWith(REG_ThisElement)
128    add r3, r3, REG_Code
129    # Update table
130    mulli r4, REG_Count, 4
131    stwx r3, r4, REG_OverloadTable
132    b Overload_IncLoop
133
134Overload_IncLoop:
135    addi REG_Count, REG_Count, 1
136
137Overload_CheckLoop:
138    lwz r3, ftX_FunctionRelocTableCount(REG_ftX)
139    cmpw REG_Count, r3
140    blt Overload_Loop
141
142Overload_Exit:
143    blr
144
145############################################
146
147FileName:
148    blrl
149    .string "TM/eventMenu.dat"
150    .align 2
151
152SymbolName:
153    blrl
154    .string "tmFunction"
155    .align 2
156
157Exit:
158    mr r3, REG_HeapLo
159    restore
160    mr r31, r3
161    stw r31, -0x3FE8(r13)
162    mr r3, r31
163    mr r4, r29