fork/training-mode-ce

git clone https://git.julia.blue/fork/training-mode-ce

AitchOverhaul build process (again) (#296)31e781a

nix
3.5 KiB176 linesraw
1    # To be inserted at 8000551c
2    .include "../../../Globals.s"
3    .include "../../../m-ex/Header.s"
4
5    .set playerdata, 31
6    .set player, 30
7    .set FramesSince, 28
8    .set ASBeforeWait, 27
9
10    backupall
11
12    # Get Player Pointers
13    mr player, r3
14    lwz playerdata, 0x2c(player)
15
16CheckForFollower:
17    mr r3, playerdata
18    branchl r12, 0x80005510
19    cmpwi r3, 0x1
20    beq Exit
21
22    # Calculate Frames Since Wait and Get AS Before Wait
23    li r5, 0                                    # Loop Count
24    li r4, TM_PrevASStart
25
26WaitSearchLoop:
27    mulli r3, r5, 0x2
28    add r3, r3, r4
29    lhzx r3, r3, playerdata
30    
31    cmpwi r3, ASID_Wait
32    beq WaitSearchExit_Wait
33    
34    cmpwi r3, ASID_Landing
35    beq WaitSearchExit_Landing
36    
37    addi r5, r5, 1
38    cmpwi r5, 6
39    bge Exit
40    b WaitSearchLoop
41    
42WaitSearchExit_Landing:
43    li FramesSince, -3
44    b WaitSearchExit
45    
46WaitSearchExit_Wait:
47    li FramesSince, 1
48
49WaitSearchExit:
50    # Get AS Before Wait
51    addi r3, r5, 1
52    mulli r3, r3, 0x2
53    add r3, r3, r4
54    lhzx ASBeforeWait, r3, playerdata
55    # Get Frames In Wait
56    
57    li r4, TM_FramesInPrevASStart               # Frame Count Start
58FrameCountLoop:
59    cmpwi r5, 0
60    blt FrameCountLoopFinish
61    mulli r3, r5, 0x2
62    add r3, r3, r4
63    
64    subi r6, r3, 12
65    lhzx r6, r6, playerdata
66    
67    # Subtract 1 unavoidable frame if in Turn
68    cmpwi r6, ASID_Turn
69    bne TurnFinish
70    subi FramesSince, FramesSince, 1
71TurnFinish:
72
73    # Remove psuedo Wait frame
74    cmpwi r6, ASID_Wait
75    bne WaitFinish
76    subi FramesSince, FramesSince, 1
77WaitFinish:
78
79    lhzx r3, r3, playerdata
80    add FramesSince, r3, FramesSince
81    subi r5, r5, 1
82    b FrameCountLoop
83
84FrameCountLoopFinish:
85    # Check If Under 13 Frames
86    cmpwi FramesSince, 13
87    bgt Exit
88
89    # Only Coming from Throws, Aerial Landing, and Teching/Getups
90    # Aerial Landing
91    cmpwi ASBeforeWait, ASID_LandingAirN
92    blt NotAerialLanding
93    cmpwi ASBeforeWait, ASID_LandingAirLw
94    bgt NotAerialLanding
95    b ComingFromWhitelist
96NotAerialLanding:
97
98    # Throws
99    cmpwi ASBeforeWait, ASID_ThrowF
100    blt NotThrow
101    cmpwi ASBeforeWait, ASID_ThrowLw
102    bgt NotThrow
103    b ComingFromWhitelist
104NotThrow:
105
106    # Teching/Getups
107    cmpwi ASBeforeWait, ASID_DownBoundU
108    blt NotTeching
109    cmpwi ASBeforeWait, ASID_PassiveStandB
110    bgt NotTeching
111    b ComingFromWhitelist
112NotTeching:
113
114    # Wavedash
115    cmpwi ASBeforeWait, ASID_LandingFallSpecial
116    bne NotWavedash
117    b ComingFromWhitelist
118NotWavedash:
119
120    cmpwi ASBeforeWait, ASID_AttackAirN
121    blt NotAerial
122    cmpwi ASBeforeWait, ASID_AttackAirLw
123    bgt NotAerial
124    b ComingFromWhitelist
125    
126NotAerial:
127    b Exit
128
129ComingFromWhitelist:
130SpawnText:
131    # Change Text Color
132    cmpwi FramesSince, 0x1
133    bne RedText
134
135GreenText:
136    load r3, 0x8dff6eff                         # green
137    b StoreTextColor
138
139RedText:
140    load r3, 0xffa2baff
141
142StoreTextColor:
143    stw r3, 0x80(sp)
144
145    # Create Text
146    li r3, 5                                    # Message Kind
147    lbz r4, 0xC(playerdata)                     # Message Queue
148    li r5, MSGCOLOR_WHITE
149    bl TechText
150    mflr r6
151    mr r7, FramesSince
152    Message_Display
153
154ChangeColor:
155    lwz r3, 0x2C(r3)
156    lwz r3, MsgData_Text(r3)
157    li r4, 1
158    addi r5, sp, 0x80
159    branchl r12, Text_ChangeTextColor
160
161    b Exit
162
163###################
164## TEXT CONTENTS ##
165###################
166
167TechText:
168    blrl
169    .string "Act OoWait\nFrame: %d"
170    .align 2
171
172##############################
173
174Exit:
175    restoreall
176    blr