fork/training-mode-ce

git clone https://git.julia.blue/fork/training-mode-ce

AitchMerge pull request #243 from NickCondron/remove-asmf9241ee

nix
4.5 KiB204 linesraw
1    # To be inserted at 80040fa4
2    .include "../../../Globals.s"
3    .include "../../../m-ex/Header.s"
4
5    .set entity, 31
6    .set playerdata, 31
7    .set player, 30
8    .set text, 29
9    .set ComboCount, 28
10    .set hitbool, 27
11
12    .set MessageAreaLength, 0x100
13    .set PerPlayerMessageStructLength, 0x28
14
15    backup
16
17    # Backup Combo Count
18    lhz ComboCount, 0x14(r3)
19
20    # CHECK IF ENABLED
21    li r0, OSD.ComboCounter         # PowerShield ID
22    # lwz r4, -0xdbc(rtoc) #get frame data toggle bits
23    lwz r4, MemcardData(r13)
24    lwz r4, 0x1F24(r4)
25    li r3, 1
26    slw r0, r3, r0
27    and. r0, r0, r4
28    beq Exit
29
30    # Get Playerdata
31    mr r3, r27
32    branchl r12, PlayerBlock_LoadMainCharDataOffset
33    mr player, r3
34    lwz playerdata, 0x2C(player)
35
36CheckForFollower:
37    mr r3, playerdata
38    branchl r12, 0x80005510
39    cmpwi r3, 0x1
40    beq Exit
41
42    # Check If Combo Count is 2 Hits or Higher
43    cmpwi ComboCount, 2
44    blt Exit
45
46    # get damage dealt
47    branchl r12, 0x80041300
48    mr r8, r3
49    mr r3, 13                   # id
50    lbz r4, 0xC(playerdata)     # queue
51    li r5, MSGCOLOR_WHITE
52    bl Text
53    mflr r6
54    mr r7, ComboCount
55    Message_Display
56
57    # Store Per Frame Function to Monitor When Hitstun Runs Out
58    lwz r3, 0x2094(playerdata)
59    # Check If Valid Player GObj
60    branchl r12, 0x80086960
61    cmpwi r3, 0
62    beq Exit
63    # Store Function
64    bl HitstunMonitor
65    mflr r3
66    lwz r4, 0x2094(playerdata)
67    lwz r4, 0x2C(r4)
68    stw r3, TM_AnimCallback(r4)
69
70    b Exit
71
72###################
73## TEXT CONTENTS ##
74###################
75
76Text:
77    blrl
78    .string "Combo Count\n%d Hits / %d%"
79    .align 2
80
81##############################
82
83HitstunMonitor:
84    blrl
85
86    backup
87
88    # Get Pointers
89    mr player, r3
90    lwz playerdata, 0x2C(player)
91
92    # Get Damage Source (Person Combo'ing Me)
93    lwz r3, 0x1868(playerdata)
94    # Ensure It's a Player
95    branchl r12, 0x80086960
96    cmpwi r3, 0x0
97    beq HitstunMonitor_SelfDestruct
98    lwz r28, 0x1868(playerdata)
99    lwz r28, 0x2C(r28)              # Save For Later
100
101    # Check If Combo Has Ended
102    # Am I in Hitstun?
103    lbz r0, 0x221C(playerdata)
104    rlwinm. r0, r0, 31, 31, 31
105    bne HitstunMonitor_ContinueCombo
106    # Am I in Missfoot?
107    lwz r3, 0x10(playerdata)
108    cmpwi r3, 0xFB
109    beq HitstunMonitor_ContinueCombo
110    # Am I in Non-IASA Landing?
111    cmpwi r3, 0x2A
112    bne HitstunMonitor_SkipIASALandingCheck
113    lfs f1, 0x0894(playerdata)
114    lfs f0, 0x01F4(playerdata)
115    fcmpo cr0, f1, f0
116    blt HitstunMonitor_ContinueCombo
117
118HitstunMonitor_SkipIASALandingCheck:
119    # Am I in Missed Tech, Tech Roll, Slow Getup, Or Getup Attack
120    lwz r0, 0x10(playerdata)
121    cmpwi r0, 0xB7
122    blt HitstunMonitor_EndCombo
123    cmpwi r0, 0xC9
124    bgt HitstunMonitor_CheckGrab
125    b HitstunMonitor_ContinueCombo
126
127HitstunMonitor_CheckGrab:
128    cmpwi r0, 0xDF
129    blt HitstunMonitor_EndCombo
130    cmpwi r0, 0xE8
131    bgt HitstunMonitor_CheckThrow
132    b HitstunMonitor_ContinueCombo
133
134HitstunMonitor_CheckThrow:
135    cmpwi r0, 0xEF
136    blt HitstunMonitor_EndCombo
137    cmpwi r0, 0xF3
138    bgt HitstunMonitor_CheckSpecialThrows
139    b HitstunMonitor_ContinueCombo
140
141HitstunMonitor_CheckSpecialThrows:
142    cmpwi r0, 0x10A
143    blt HitstunMonitor_EndCombo
144    cmpwi r0, 0x130
145    bgt HitstunMonitor_EndCombo
146    b HitstunMonitor_ContinueCombo
147
148HitstunMonitor_EndCombo:
149    # Find MessageBox Pointer
150    # Get Player's Message Struct in r29
151    load r3, 0x804a1f58
152    lwz r29, 0x4(r3)
153    lbz r3, 0xC(r28)
154    mulli r4, r3, PerPlayerMessageStructLength
155    add r29, r29, r4
156    # Init Search Loop
157    li r27, 0
158
159HitstunMonitor_SearchLoop:
160    mulli r3, r27, 8
161    add r3, r3, r29
162    lhz r4, 0x6(r3)                 # Get OSD ID
163    cmpwi r4, 13
164    beq HitstunMonitor_EditOSD
165    addi r27, r27, 1
166    cmpwi r27, 4
167    ble HitstunMonitor_SearchLoop
168
169    # OSD Not Found, Self Destruct
170    b HitstunMonitor_SelfDestruct
171
172HitstunMonitor_EditOSD:
173    mr r26, r3                      # Backup OSD Info
174    # Set Time To Expire
175    li r3, 60
176    sth r3, 0x4(r26)
177    # Get Green On Stack
178    load r3, 0x8dff6eff
179    stw r3, 0xF0(sp)
180    # Change Subtext's Colors
181    lwz r3, 0x0(r26)
182    li r4, 1
183    addi r5, sp, 0xF0
184    branchl r12, Text_ChangeTextColor # Text_SetColor
185    lwz r3, 0x0(r26)
186    li r4, 2
187    addi r5, sp, 0xF0
188    branchl r12, Text_ChangeTextColor
189
190HitstunMonitor_SelfDestruct:
191    li r3, 0
192    stw r3, TM_AnimCallback(playerdata)
193
194HitstunMonitor_ContinueCombo:
195
196HitstunMonitor_Exit:
197    restore
198    blr
199
200##############################
201
202Exit:
203    restore
204    lmw r27, 0x0024(sp)