fork/training-mode-ce

git clone https://git.julia.blue/fork/training-mode-ce

AitchMerge pull request #242 from NickCondron/remove-asm96edbd1

nix
1.5 KiB78 linesraw
1    # To be inserted at 80005514
2    .include "../../../../Globals.s"
3    .include "../../../../m-ex/Header.s"
4
5    .set playerdata, 31
6    .set player, 30
7    .set REG_isAerialInterrupt, 28
8    .set REG_GALINT, 27
9
10    backupall
11
12    mr player, r3
13    lwz playerdata, 0x2c(player)
14    mr REG_isAerialInterrupt, r4
15
16    # CHECK IF ENABLED
17    li r0, OSD.Ledge                # PowerShield ID
18    lwz r4, MemcardData(r13)
19    lwz r4, 0x1F24(r4)
20    li r3, 1
21    slw r0, r3, r0
22    and. r0, r0, r4
23    beq Exit
24
25CheckForFollower:
26    mr r3, playerdata
27    branchl r12, 0x80005510
28    cmpwi r3, 0x1
29    beq Exit
30
31    # Check if Over 20 Frames past GALINT
32    lhz r3, TM_TangibleFrameCount(playerdata)
33    cmpwi r3, 20
34    bgt Exit
35
36    # Get GALINT Frames (Ledge Intang - Landing Lag)
37    lwz REG_GALINT, 0x1990(playerdata)
38    cmpwi REG_isAerialInterrupt, 0
39    beq SkipAI
40    lfs f1, 0x1F4(playerdata)
41    fctiwz f1, f1
42    stfd f1, 0x80(sp)
43    lwz r3, 0x84(sp)
44    sub REG_GALINT, REG_GALINT, r3
45SkipAI:
46
47SetColor:
48    load r5, MSGCOLOR_RED
49    lhz r7, TM_TangibleFrameCount(playerdata)
50    neg r7, r7
51    cmpwi REG_GALINT, 0x0
52    ble EndSetColor
53    load r5, MSGCOLOR_GREEN
54    mr r7, REG_GALINT
55EndSetColor:
56
57    li r3, 19                   # ID
58    lbz r4, 0xC(playerdata)     # queue
59    bl Text
60    mflr r6
61    Message_Display
62
63    b Exit
64
65###################
66## TEXT CONTENTS ##
67###################
68
69Text:
70    blrl
71    .string "GALINT\nFrames: %d"
72    .align 2
73
74##############################
75
76Exit:
77    restoreall
78    blr