fork/training-mode-ce

git clone https://git.julia.blue/fork/training-mode-ce

AitchMerge pull request #242 from NickCondron/remove-asm96edbd1

nix
6.0 KiB295 linesraw
1    # To be inserted at 80099d7c
2    .include "../../../Globals.s"
3    .include "../../../m-ex/Header.s"
4
5    .set REG_FighterData, 29
6    .set REG_FighterGObj, 27
7    .set text, 28
8    .set REG_Text, 30
9
10    backup
11
12    # Get Pointers
13    mr REG_FighterGObj, r3
14    lwz REG_FighterData, 0x2C(REG_FighterGObj)
15
16    # CHECK IF OSD IS ENABLED
17    li r0, OSD.Wavedash             # wavedash ID
18    lwz r4, MemcardData(r13)
19    lwz r4, 0x1F24(r4)
20    li r3, 1
21    slw r0, r3, r0
22    and. r0, r0, r4
23    beq Exit
24
25    # Check if fighter is a subcharacter
26    mr r3, REG_FighterData
27    branchl r12, 0x80005510
28    cmpwi r3, 0x1
29    beq Exit
30
31    # CHECK IF IT WAS A WAVEDASH (landed within 20 frames)
32    lhz r3, TM_FramesinCurrentAS(REG_FighterData)
33    cmpwi r3, 20
34    bgt Exit
35
36    # Get wavedash angle
37    lfs f1, TM_AirdodgeAngle(REG_FighterData)
38    bl GetWavedashAngle
39    stfs f1, 0x80(sp)
40
41    # Get frames in jump
42    lhz r7, TM_FramesinOneASAgo(REG_FighterData)
43
44    # Get short or full hop
45    bl ShortHopString
46    mflr r8
47    lwz r9, TM_ShortOrFullHop(REG_FighterData)
48    cmpwi r9, 1
49    bgt PrintMessage_NoHopType
50    beq EndShortOrFullHop
51    bl FullHopString
52    mflr r8
53EndShortOrFullHop:
54
55    # Get frames since jump release
56    li r9, 0
57JumpInputsLoop:
58    mulli r10, r9, 8
59    add r10, r10, REG_FighterData
60
61    lhz r11, TM_Inputs(r10) # buttons
62    andi. r11, r11, 0xC00 # x or y
63    bne EndJumpInputsLoop
64
65    addi r10, r10, 3
66    lbz r11, TM_Inputs(r10) # stick y
67    extsb r11, r11
68    cmpwi r11, 44
69    bgt EndJumpInputsLoop
70
71    # no jump input this frame
72    addi r9, r9, 1
73    cmpwi r9, 32
74    blt JumpInputsLoop
75
76    # Out of input history with no jump input - wavedash probably took longer than 32 frames.
77    # Nothing we can do here unless we increase the input history range.
78
79    b PrintMessage_NoHopType
80
81EndJumpInputsLoop:
82    lbz r10, 0x685(REG_FighterData) # timer_jump
83    sub r9, r10, r9 # get jump held frames
84    addi r9, r9, 1 # 1-index
85    b PrintMessage
86
87PrintMessage:
88    li r3, 0                        # Message Kind
89    lbz r4, 0xC(REG_FighterData)    # Message Queue
90    li r5, MSGCOLOR_WHITE
91    bl Wavedash_String
92    mflr r6
93    Message_Display
94    lwz r3, 0x2C(r3)
95    lwz REG_Text, MsgData_Text(r3)
96    b CheckSetHopTypeColor
97
98PrintMessage_NoHopType:
99    li r3, 0                        # Message Kind
100    lbz r4, 0xC(REG_FighterData)    # Message Queue
101    li r5, MSGCOLOR_WHITE
102    bl Wavedash_String_NoHopType
103    mflr r6
104    Message_Display
105    lwz r3, 0x2C(r3)
106    lwz REG_Text, MsgData_Text(r3)
107    b SetTimingColor
108
109CheckSetHopTypeColor:
110    lwz r3, TM_ShortOrFullHop(REG_FighterData)
111    cmpwi r3, 0
112    beq SetTimingColor
113    bl Floats
114    mflr r4
115    addi r5, r4, 0xC
116    # Change Color
117    mr r3, REG_Text                 # text pointer
118    li r4, 2
119    branchl r12, Text_ChangeTextColor
120
121SetTimingColor:
122    # Adjust Timing color
123    lhz r3, TM_FramesinOneASAgo(REG_FighterData)
124    cmpwi r3, 1
125    bne CheckSetAngleColor
126    bl Floats
127    mflr r4
128    addi r5, r4, 0xC
129    # Change Color
130    mr r3, REG_Text                 # text pointer
131    li r4, 0
132    branchl r12, Text_ChangeTextColor
133
134CheckSetAngleColor:
135    # Adjust Angle color
136    # Get Angle and Float Pointer
137    bl Floats
138    mflr r4
139    lfs f1, 0x80(sp)
140    # Check For Perfect Angle
141    lfs f2, 0x0(r4)
142    fcmpo cr0, f1, f2
143    blt Exit
144    lfs f2, 0x4(r4)
145    fcmpo cr0, f1, f2
146    blt PerfectAngle
147    lfs f2, 0x8(r4)
148    fcmpo cr0, f1, f2
149    bgt Exit
150
151OKAngle:
152    addi r5, r4, 0x10
153    b ChangeAngleColor
154
155PerfectAngle:
156    addi r5, r4, 0xC
157    b ChangeAngleColor
158
159ChangeAngleColor:
160    # Change Color
161    mr r3, REG_Text                 # text pointer
162    li r4, 1
163    branchl r12, Text_ChangeTextColor
164
165    b Exit
166
167#########################
168## Get Wavedash Angle ##
169#########################
170
171GetWavedashAngle:
172    backup
173
174    # Convert angle to degrees
175    lfs f2, -0x3D10(rtoc)           # 0.017453
176    fdivs f2, f1, f2
177    # Multiply by 10 to preserve 1 decimal point
178    li r3, 10
179    bl IntToFloat
180    fmuls f2, f1, f2
181    # Cast to int to floor
182    fctiwz f1, f2
183    stfd f1, -0x4(sp)
184    lwz r3, 0x0(sp)
185    # Cast back to float
186    bl IntToFloat
187    # Divide by 10 to get decimal point back
188    fmr f2, f1
189    li r3, 10
190    bl IntToFloat
191    fdivs f2, f2, f1
192    # Normalize to 0-90, definitely could have handled this better but its w/e
193    li r3, 0
194    bl IntToFloat
195    fcmpo cr0, f2, f1
196    bge TopQuadrant
197
198BottomQuadrant:
199    li r3, -90
200    bl IntToFloat
201    fcmpo cr0, f2, f1
202    bgt Quadrant4
203
204Quadrant3:
205    li r3, 180
206    bl IntToFloat
207    fadds f2, f1, f2
208    b SaveAngle
209
210Quadrant4:
211    fneg f2, f2
212    b SaveAngle
213
214TopQuadrant:
215    li r3, 90
216    bl IntToFloat
217    fcmpo cr0, f2, f1
218    bgt Quadrant2
219
220Quadrant1:
221    b SaveAngle
222
223Quadrant2:
224    fneg f2, f2
225    li r3, 180
226    bl IntToFloat
227    fadds f2, f1, f2
228    b SaveAngle
229
230SaveAngle:
231    fmr f1, f2
232    restore
233    blr
234
235#########################
236
237Wavedash_String:
238    blrl
239    .string "Wavedash Frame: %d\nAngle: %2.1f\n%s: %df"
240    .align 2
241
242Wavedash_String_NoHopType:
243    blrl
244    .string "Wavedash Frame: %d\nAngle: %2.1f"
245    .align 2
246
247ShortHopString:
248    blrl
249    .string "Short Hop"
250    .align 2
251
252FullHopString:
253    blrl
254    .string "Full Hop"
255    .align 2
256
257Floats:
258    blrl
259    .float 16.8                     # Great Angle Min
260    .float 23.7                     # Great Angle Max
261    .float 30.5                     # Good Angle Max
262    .long 0x8dff6eff                # Perfect Angle
263    .long 0xfff000ff                # Great Angle
264
265##############################
266
267IntToFloat:
268    mflr r0
269    stw r0, 0x4(r1)
270    stwu r1, -0x100(r1)             # make space for 12 registers
271    stmw r20, 0x8(r1)
272    stfs f2, 0x38(r1)
273
274    lis r0, 0x4330
275    lfd f2, -0x6758(rtoc)
276    xoris r3, r3, 0x8000
277    stw r0, 0xF0(sp)
278    stw r3, 0xF4(sp)
279    lfd f1, 0xF0(sp)
280    fsubs f1, f1, f2                # Convert To Float
281
282    lfs f2, 0x38(r1)
283    lmw r20, 0x8(r1)
284    lwz r0, 0x104(r1)
285    addi r1, r1, 0x100              # release the space
286    mtlr r0
287    blr
288
289##############################
290
291Exit:
292    mr r3, REG_FighterGObj
293    restore
294
295    lwz r4, -0x514C(r13)