fork/training-mode-ce

git clone https://git.julia.blue/fork/training-mode-ce

AitchMerge pull request #88 from NickCondron/remove-asm2c08d3a

techchase-camera
3.7 KiB172 linesraw
1    # To be inserted at 80302788
2    .include "../../Globals.s"
3
4    .set IdleThreshold, (3*60) * 60
5
6    .set REG_DevelopText, 31
7    .set REG_GObjData, 30
8    .set REG_GObj, 29
9    .set REG_Floats, 28
10
11    backup
12
13    bl Floats
14    mflr REG_Floats
15
16    # Create Rectangle
17    li r3, 32
18    branchl r12, HSD_MemAlloc
19    mr r8, r3
20    li r3, 20
21    li r4, -25
22    li r5, -25
23    li r6, 1
24    li r7, 1
25    branchl r12, DevelopText_CreateDataTable
26    mr REG_DevelopText, r3
27    # Activate Text
28    lwz r3, -0x4884(r13)
29    mr r4, REG_DevelopText
30    branchl r12, DevelopText_Activate
31    # Hide blinking cursor
32    li r3, 0
33    stb r3, 0x26(REG_DevelopText)
34    # Change BG Color
35    mr r3, REG_DevelopText
36    addi r4, REG_Floats, TextBG
37    branchl r12, DevelopText_StoreBGColor
38    # Hide Filter
39    mr r3, REG_DevelopText
40    branchl r12, DevelopText_HideBG
41    # Set Stretch
42    lfs f1, TextScale_X(REG_Floats)
43    stfs f1, 0x8(REG_DevelopText)
44    lfs f1, TextScale_Y(REG_Floats)
45    stfs f1, 0xC(REG_DevelopText)
46    # Create Background GObj
47    li r3, 0
48    li r4, 0
49    li r5, 0
50    branchl r12, GObj_Create
51    mr REG_GObj, r3
52    # Allocate Space
53    li r3, 64
54    branchl r12, HSD_MemAlloc
55    mr REG_GObjData, r3
56    # Zero
57    li r4, 64
58    branchl r12, ZeroAreaLength
59    # Initialize
60    mr r6, REG_GObjData
61    mr r3, REG_GObj
62    li r4, 4
63    load r5, HSD_Free
64    branchl r12, GObj_AddUserData
65    # Add Process
66    mr r3, REG_GObj
67    bl IdleThink
68    mflr r4
69    li r5, 0
70    branchl r12, GObj_AddProc
71    # Store pointer to dev text
72    stw REG_DevelopText, 0x0(REG_GObjData)
73    b Injection_Exit
74
75IdleThink:
76    blrl
77    .set REG_GObjData, 31
78    .set REG_Floats, 30
79
80    .set IdleData_Text, 0x0
81    .set IdleData_State, 0x4
82    .set IdleData_VolumeBackup, 0x8
83    .set IdleData_IdleCounter, 0xC
84
85    backup
86
87    # Init
88    lwz REG_GObjData, 0x2C(r3)
89    bl Floats
90    mflr REG_Floats
91
92    # Check if already muted
93    lwz r3, IdleData_State(REG_GObjData)
94    cmpwi r3, 0x0
95    bne IdleThink_CheckToUnmute
96
97IdleThink_CheckToMute:
98    # Check if anyone is inputting on this frame
99    li r3, 4
100    branchl r12, Inputs_GetPlayerHeldInputs
101    cmpwi r4, 0
102    beq IdleThink_CheckToMute_IncTimer
103
104IdleThink_CheckToMute_ResetTimer:
105    li r3, 0
106    stw r3, IdleData_IdleCounter(REG_GObjData)
107    b IdleThink_Exit
108
109IdleThink_CheckToMute_IncTimer:
110    lwz r3, IdleData_IdleCounter(REG_GObjData)
111    addi r3, r3, 1
112    stw r3, IdleData_IdleCounter(REG_GObjData)
113    cmpwi r3, IdleThreshold
114    blt IdleThink_Exit
115    # Mute Music
116    lwz r4, -0x7E1C(r13)
117    stw r4, IdleData_VolumeBackup(REG_GObjData)
118    li r3, 0
119    branchl r12, cvt_sll_flt
120    lfs f2, VolumeMultiplier(REG_Floats)
121    fmuls f1, f1, f2
122    branchl r12, cvt_fp2unsigned
123    stw r3, -0x7E1C(r13)
124    # Display filter
125    lwz r3, IdleData_Text(REG_GObjData)
126    branchl r12, DevelopText_ShowBG
127    # Change state
128    li r3, 1
129    stw r3, IdleData_State(REG_GObjData)
130    # Reset Timer
131    li r3, 0
132    stw r3, IdleData_IdleCounter(REG_GObjData)
133    b IdleThink_Exit
134
135IdleThink_CheckToUnmute:
136    # Check if anyone is inputting on this frame
137    li r3, 4
138    branchl r12, Inputs_GetPlayerHeldInputs
139    cmpwi r4, 0
140    beq IdleThink_Exit
141    # Unmute music
142    lwz r3, IdleData_VolumeBackup(REG_GObjData)
143    stw r3, -0x7E1C(r13)
144    # Hide Filter
145    lwz r3, IdleData_Text(REG_GObjData)
146    branchl r12, DevelopText_HideBG
147    # Change state
148    li r3, 0
149    stw r3, IdleData_State(REG_GObjData)
150    b IdleThink_Exit
151
152IdleThink_Exit:
153    restore
154    blr
155
156######################
157Floats:
158    blrl
159    .set TextScale_X, 0x0
160    .set TextScale_Y, 0x4
161    .set TextBG, 0x8
162    .set VolumeMultiplier, 0xC
163    .float 1000
164    .float 1000
165    .byte 0, 0, 0, 130
166    .float 0.3
167
168######################
169
170Injection_Exit:
171    restore
172    mr r3, r31