fork/training-mode-ce

git clone https://git.julia.blue/fork/training-mode-ce

AitchMerge pull request #88 from NickCondron/remove-asm2c08d3a

techchase-camera
3.4 KiB109 linesraw
1    # To be inserted at 800C9A44
2    .include "../../Globals.s"
3    .include "../Header.s"
4
5    .set REG_PlayerData, 31
6    .set REG_Floats, 30
7    .set REG_InputIndex, 29
8    .set REG_PrevInput, 28
9
10NTSC102:
11    .set Injection, 0x800C9A44
12    .set OFST_PlCo, -0x514C
13    .set InputIndex, 0x804c1f78
14    .set InputArray, 0x8046b108
15    .set PlayerBlock_LoadPlayerGObj, 0x8003418c
16
17    # Original codeline
18    stfs f0, 0x2C(REG_PlayerData)           # Entry point, store new facing direction
19
20    # Init
21    backup
22    bl Floats
23    mflr REG_Floats
24
25CHECK_IF_SLOW_TURN:
26    lfs f1, 0x894(REG_PlayerData)           # Check if 2nd frame of turn
27    lfs f2, OFST_SlowTurnFrame(REG_Floats)  # 2fp
28    fcmpo cr0, f1, f2
29    bne Injection_Exit
30
31CHECK_SMASH_TURN_INPUT_CONDITIONS:
32    lwz r4, OFST_PlCo(r13)
33    lfs f1, 0x0620(REG_PlayerData)
34    fabs f1, f1
35    lfs f2, 0x3C(r4)                        # PlCo constant 0.8
36    fcmpo cr0, f1, f2                       # Load control stick x-inputs and compare to 0.8
37    blt Injection_Exit
38    # Check that cardinal direction not held 2+ frames
39    lbz r3, 0x0670(REG_PlayerData)
40    cmpwi r3, 2
41    bge- Injection_Exit                     # Skip if no dash input
42
43SKIP_IF_NANA:
44    lbz r3, 0x221f(REG_PlayerData)          # load flags
45    rlwinm. r0, r3, 0, 28, 28               # (08) = secondary character
46    bne Injection_Exit
47
48BEGIN_HW_INPUTS:
49LOAD_2_FRAMES_PAST_INPUTS:
50    lbz REG_PrevInput, MEX_UCF2fX (REG_PlayerData)
51    extsb REG_PrevInput, REG_PrevInput
52
53LOAD_CURRENT_FRAME_INPUT:
54    lbz r3, MEX_UCFCurrX (REG_PlayerData)
55    extsb r3, r3
56
57CALCULATE_DIFFERENCE:
58    sub r3, REG_PrevInput, r3
59    mullw r3, r3, r3                        # Take square to get positive value for comparison
60
61THRESHOLD_TEST:
62    cmpwi r3, 3600                          # compare square of input difference between current frame and 2 frames ago to square of 60(formerly 75 because different units)
63    ble- Injection_Exit
64
65CHANGE_TO_SMASH_TURN:
66    li r0, 1
67    stw r0, 0x2358(REG_PlayerData)
68    stw r0, 0x2340(REG_PlayerData)          # Change smash turn and can dash flags
69    # Check if Popo
70    lwz r4, 0x4(REG_PlayerData)             # Load character id
71    cmpwi r4, 0xA                           # Check if Popo
72    bne+ Injection_Exit                     # Skip if not Popo
73    # Get Nana's Block From Popo's in r4
74    lbz r3, 0xC(REG_PlayerData)             # P1 Slot
75    li r4, 0x1                              # Subchar Bool
76    branchl r12, PlayerBlock_LoadPlayerGObj
77    cmpwi r3, 0x0
78    beq Injection_Exit
79    lwz r4, 0x2C(r3)
80    # Adjust Nana's inputs
81    lwz r4, 0x1ECC(r4)                      # Load address where popos inputs were last stored
82    lfs f1, 0x2C(REG_PlayerData)            # get popos facing direction
83    stfs f1, 0x18(r4)                       # Store popos direction for nana
84    # Check which direction popo turned
85    lfs f2, OFST_ZeroFP(REG_Floats)         # 0fp
86    fcmpo cr0, f1, f2
87    bgt- POPO_TURNED_RIGHT
88    li r3, 0x80                             # leftward 1.0
89    b StoreNanaDirection
90
91POPO_TURNED_RIGHT:
92    li r3, 0x7f                             # rightward 1.0
93
94StoreNanaDirection:
95    stb r3, 0x6(r4)                         # Store rightward 1.0 input for Nana
96    b Injection_Exit
97
98Floats:
99    .set OFST_SlowTurnFrame, 0x0
100    .set OFST_ZeroFP, 0x4
101    blrl
102    .float 2
103    .float 0
104    .align 2
105
106###################
107
108Injection_Exit:
109    restore