fork/training-mode-ce

git clone https://git.julia.blue/fork/training-mode-ce

Nick CondronFix restore CSS CPU when sheik4075cce

techchase-camera
2.5 KiB104 linesraw
1    # To be inserted at 801baa98
2    .include "../../../../Globals.s"
3    .include "../../../../m-ex/Header.s"
4    
5    # RESTORE HMN ----------------------------------
6
7    # Get Backup Location
8    lwz r9, MemcardData(r13)
9    addi r9, r9, 3344
10    # Restore HMN Character Choice
11    load r3, 0x80497758     # CSS Match Info
12    # mr r4, r4 #CSS Type
13    lbz r5, 104(r9)         # Character Backup
14    li r6, 0                # Unk
15    lbz r7, 107(r9)         # Costume Backup
16    lbz r8, 114(r9)         # Nametag Backup Location
17    li r9, 0                # Unk Backup Location
18    lbz r10, 0x0006(r31)    # Player who accessed CSS
19    branchl r12, 0x801b06b0
20    
21    # RESTORE CPU ----------------------------------
22    
23    # load allowed cpu characters
24    lwz r4, MemcardData(r13)
25    lbz r3, 0x0535(r4)
26    lbz r4, CurrentEventPage(r4)
27    rtocbl r12, TM_GetEventCharList
28    lwz r6, 0x4(r3)
29        
30    cmpwi r6, -1
31    beq RestoreCPU
32    
33    # CPU is not allowed, find first allowed CPU
34    
35    li r4, 0
36FindFirstAllowedCPU:
37    li r5, 1
38    slw r5, r5, r4
39    and. r5, r5, r6
40    bne FoundCPU
41    addi r4, r4, 1
42    b FindFirstAllowedCPU
43    
44FoundCPU:
45    # convert from CSSID to External ID
46    bl CSSIDToExternalIDMapEnd
47    .byte Doc.Ext 
48    .byte Mario.Ext 
49    .byte Luigi.Ext 
50    .byte Bowser.Ext 
51    .byte Peach.Ext 
52    .byte Yoshi.Ext 
53    .byte DK.Ext 
54    .byte CaptainFalcon.Ext 
55    .byte Ganondorf.Ext 
56    .byte Falco.Ext 
57    .byte Fox.Ext 
58    .byte Ness.Ext 
59    .byte IceClimbers.Ext 
60    .byte Kirby.Ext 
61    .byte Samus.Ext 
62    .byte Zelda.Ext 
63    .byte Link.Ext 
64    .byte YLink.Ext 
65    .byte Pichu.Ext 
66    .byte Pikachu.Ext 
67    .byte Jigglypuff.Ext 
68    .byte Mewtwo.Ext 
69    .byte GaW.Ext 
70    .byte Marth.Ext 
71    .byte Roy.Ext
72    .align 2 
73CSSIDToExternalIDMapEnd:
74    mflr r6
75    add r4, r4, r6
76    lbz r4, 0x0(r4)
77
78    li r6, 0 # set first costume
79    
80    # Get Backup Location
81    lwz r9, MemcardData(r13)
82    addi r9, r9, 3344
83    b WriteCPU
84    
85RestoreCPU:
86    # Get Backup Location
87    lwz r9, MemcardData(r13)
88    addi r9, r9, 3344
89    
90    lbz r6, 143(r9)         # Costume Backup
91    lbz r4, 140(r9)         # Character Backup
92
93    # Swap sheik to zelda
94    cmpwi r4, Sheik.Ext
95    bne WriteCPU
96    li r4, Zelda.Ext
97
98WriteCPU:
99    load r3, 0x80497758     # CSS Match Info
100    li r5, 1                # Unk
101    lbz r7, 150(r9)         # Nametag Backup
102    li r8, 0
103    lbz r9, 0x0006(r31)     # Player who accessed CSS
104    branchl r12, 0x801b07b4