fork/training-mode-ce

git clone https://git.julia.blue/fork/training-mode-ce

AitchMerge pull request #242 from NickCondron/remove-asm96edbd1

techchase-camera
2.2 KiB100 linesraw
1    # To be inserted at 80005508
2    .include "../../../Globals.s"
3    .include "../../../m-ex/Header.s"
4
5    .set REG_FighterData, 31
6    .set player, 30
7    .set REG_TextColor, 29
8
9##########################################################
10## 804a1f5c -> 804a1fd4 = Static Stock Icon Text Struct ##
11## Is 0x80 long and is zero'd at the start ##
12## of every VS Match ##
13## Store Text Info here ##
14##########################################################
15
16    backupall
17
18    mr player, r4
19    lwz REG_FighterData, 0x2C(player)
20
21#####################
22## CHECK IF IASA'd ##
23#####################
24
25    # CHECK IF ENABLED
26    li r0, OSD.ActOoS                           # wavedash ID
27    # lwz r4, -0xdbc(rtoc) #get frame data toggle bits
28    lwz r4, MemcardData(r13)
29    lwz r4, 0x1F24(r4)
30    li r5, 1
31    slw r0, r5, r0
32    and. r0, r0, r4
33    beq Exit
34
35CheckForIASA:
36    cmpwi r3, 0x1
37    bne Exit
38
39CheckForFollower:
40    mr r3, REG_FighterData
41    branchl r12, 0x80005510
42    cmpwi r3, 0x1
43    beq Exit
44
45CheckForGuardOff:
46    lwz r3, 0x10(REG_FighterData)
47    cmpwi r3, 0xB4
48    beq Exit
49
50ShieldWaitCheck:
51    # CHECK IF 3RD MOST RECENT AS WAS SHIELD STUN
52    lhz r3, TM_TwoASAgo(REG_FighterData)
53    cmpwi r3, 0xB5
54    beq CreateText
55
56GuardOffCheck:
57    # CHECK IF 4TH MOST RECENT AS WAS SHIELD STUN
58    lhz r3, TM_ThreeASAgo(REG_FighterData)
59    cmpwi r3, 0xB5
60    beq CreateText
61    b Exit
62
63CreateText:
64    # Change color to Green if frame perfect act oos
65    lhz r3, TM_ShieldFrames(REG_FighterData)    # get shield stun frames left
66    cmpwi r3, 0x0
67    bgt WhiteText
68    li REG_TextColor, MSGCOLOR_GREEN
69    b PrintMessage
70
71WhiteText:
72    li REG_TextColor, MSGCOLOR_WHITE
73    b PrintMessage
74
75PrintMessage:
76    li r3, 3                                    # Message Kind
77    lbz r4, 0xC(REG_FighterData)                # Message Queue
78    mr r5, REG_TextColor
79    bl OoS_String
80    mflr r6
81    lhz r7, TM_ShieldFrames(REG_FighterData)    # get shield stun frames left
82    addi r7, r7, 1
83    Message_Display
84
85    b Exit
86
87###################
88## TEXT CONTENTS ##
89###################
90
91OoS_String:
92    blrl
93    .string "Act OoShield\nFrame %d"
94    .align 2
95
96##############################
97
98Exit:
99    restoreall
100    blr