fork/training-mode-ce

git clone https://git.julia.blue/fork/training-mode-ce

AitchMerge pull request #242 from NickCondron/remove-asm96edbd1

techchase-camera
5.1 KiB219 linesraw
1    # To be inserted at 80005518
2    .include "../../../Globals.s"
3    .include "../../../m-ex/Header.s"
4
5    .set entity, 31
6    .set REG_FighterData, 31
7    .set player, 30
8    .set REG_DBBool, 29
9    .set REG_String, 28
10    .set REG_DBRate, 27
11    .set REG_TextColor, 26
12    .set REG_Text, 25
13
14##########################################################
15## 804a1f5c -> 804a1fd4 = Static Stock Icon Text Struct ##
16## Is 0x80 long and is zero'd at the start ##
17## of every VS Match ##
18## Store Text Info here ##
19##########################################################
20
21    backupall
22
23    mr player, r3
24    lwz REG_FighterData, 0x2C(player)
25    mr REG_DBBool, r4               # Dashback Bool
26
27    # CHECK IF ENABLED
28    li r0, OSD.Dashback             # wavedash ID
29    # lwz r4, -0xdbc(rtoc) #get frame data toggle bits
30    lwz r4, MemcardData(r13)
31    lwz r4, 0x1F24(r4)
32    li r3, 1
33    slw r0, r3, r0
34    and. r0, r0, r4
35    beq Exit
36
37CheckForFollower:
38    mr r3, REG_FighterData
39    branchl r12, 0x80005510
40    cmpwi r3, 0x1
41    beq Exit
42
43    # Change color to Green if frame perfect act oos
44    cmpwi REG_DBBool, 0x0
45    beq FailedDB
46    # Check If UCF DB or Vanilla DB
47    lwz r3, 0x2350(REG_FighterData) # get turn flag
48    cmpwi r3, 0x0                   # if 0, was a smash turn
49    bne UCFDB
50
51VanillaDB:
52    mr r3, REG_FighterData
53    bl IncDBRate
54    mr REG_DBRate, r3
55    bl DBVanilla_String
56    mflr REG_String
57    li REG_TextColor, MSGCOLOR_GREEN
58    b PrintMessage
59
60UCFDB:
61    mr r3, REG_FighterData
62    bl IncDBRate
63    mr REG_DBRate, r3
64    bl DBUCF_String
65    mflr REG_String
66    li REG_TextColor, MSGCOLOR_YELLOW
67    b PrintMessage
68
69FailedDB:
70    mr r3, REG_FighterData
71    bl DecDBRate
72    mr REG_DBRate, r3
73    bl DBFailed_String
74    mflr REG_String
75    li REG_TextColor, MSGCOLOR_RED
76    b PrintMessage
77
78PrintMessage:
79    li r3, 4                        # Message Kind
80    lbz r4, 0xC(REG_FighterData)    # Message Queue
81    li r5, MSGCOLOR_WHITE
82    mr r6, REG_String
83    mr r7, REG_DBRate
84    Message_Display
85    lwz r3, 0x2C(r3)
86    lwz REG_Text, MsgData_Text(r3)
87
88    # adjust top line color
89    bl Colors
90    mflr r3
91    cmpwi REG_TextColor, MSGCOLOR_GREEN
92    beq GreenText
93    cmpwi REG_TextColor, MSGCOLOR_RED
94    beq RedText
95
96YellowText:
97    addi r5, r3, 0x4
98    b ChangeColor
99
100GreenText:
101    addi r5, r3, 0x0
102    b ChangeColor
103
104RedText:
105    addi r5, r3, 0x8
106    b ChangeColor
107
108ChangeColor:
109    mr r3, REG_Text
110    li r4, 0
111    branchl r12, Text_ChangeTextColor
112
113    b Exit
114
115#########################
116### DB Rate Functions ###
117#########################
118
119IncDBRate:
120    stwu r1, -0x100(r1)             # make space for 12 registers
121    mflr r0
122    stw r0, 0xFC(sp)
123    lbz r3, 0xC(r3)                 # get player slot
124    load r4, 0x804a1fc8             # get DB rate mem location
125    mulli r3, r3, 0x4               # length of players DB info
126    add r8, r3, r4                  # players DB info in r8
127    lhz r3, 0x0(r8)                 # successful DBs
128    addi r3, r3, 0x1
129    sth r3, 0x0(r8)                 # successful DBs
130    lhz r3, 0x2(r8)                 # total DBs
131    addi r3, r3, 0x1
132    sth r3, 0x2(r8)                 # total DBs
133    mr r3, r8
134    bl GetDBRate
135    lwz r0, 0xFC(sp)
136    mtlr r0
137    addi r1, r1, 0x100              # release the space
138    blr
139
140DecDBRate:
141    stwu r1, -0x100(r1)             # make space for 12 registers
142    mflr r0
143    stw r0, 0xFC(sp)
144    lbz r3, 0xC(r3)                 # get player slot
145    load r4, 0x804a1fc8             # get DB rate mem location
146    mulli r3, r3, 0x4               # length of players DB info
147    add r8, r3, r4                  # players DB info in r8
148    lhz r3, 0x2(r8)                 # total DBs
149    addi r3, r3, 0x1
150    sth r3, 0x2(r8)                 # total DBs
151    mr r3, r8
152    bl GetDBRate
153    lwz r0, 0xFC(sp)
154    mtlr r0
155    addi r1, r1, 0x100              # release the space
156    blr
157
158GetDBRate:
159    # Get Values
160    lhz r4, 0x0(r3)                 # successful DBs
161    lhz r5, 0x2(r3)                 # total DBs
162    # Get as Floats (f1 = successful, f2 = total
163    lis r0, 0x4330
164    lfd f5, -0x6758(rtoc)
165    xoris r6, r4, 0x8000
166    xoris r7, r5, 0x8000
167    stw r0, 0xF0(sp)
168    # Successful DB
169    stw r6, 0xF4(sp)
170    lfd f1, 0xF0(sp)
171    fsubs f1, f1, f5
172    # Total DB
173    stw r7, 0xF4(sp)
174    lfd f2, 0xF0(sp)
175    fsubs f2, f2, f5
176    # 100f
177    li r4, 100
178    xoris r4, r4, 0x8000
179    stw r4, 0xF4(sp)
180    lfd f3, 0xF0(sp)
181    fsubs f3, f3, f5
182    fdivs f1, f1, f2                # successful DB / total DB
183    fmuls f1, f1, f3                # times 100
184    # Back to Int
185    fctiwz f1, f1
186    stfd f1, 0xF0(sp)
187    lwz r3, 0xF4(sp)
188    blr
189
190###################
191## TEXT CONTENTS ##
192###################
193
194DBVanilla_String:
195    blrl
196    .string "Vanilla Dashback\nSuccess Rate: %d%"
197    .align 2
198
199DBUCF_String:
200    blrl
201    .string "UCF Dashback\nSuccess Rate: %d%"
202    .align 2
203
204DBFailed_String:
205    blrl
206    .string "Failed Dashback\nSuccess Rate: %d%"
207    .align 2
208
209Colors:
210    blrl
211    .long 0x8dff6eff                # green
212    .long 0xfff000ff                # yellow
213    .byte 255, 162, 186, 255        # red
214
215##############################
216
217Exit:
218    restoreall
219    blr