fork/training-mode-ce

git clone https://git.julia.blue/fork/training-mode-ce

Alex Harrisonfix Act OoWait showing frame 2 on some actionsdd3e08a

techchase-camera
13.8 KiB623 linesraw
1    # To be inserted at 8006b7f4
2    # Runs once per frame, use for OSDs that don't require a specific injection point
3
4    .include "../../Globals.s"
5    .include "../../m-ex/Header.s"
6
7    .set playerdata, 31
8    .set player, 30
9
10    backupall
11    
12OSD_ActOoWait:
13    # CHECK IF ENABLED
14    li r0, OSD.ActOoWait                        # PowerShield ID
15    # lwz r4, -0xdbc(rtoc) #get frame data toggle bits
16    lwz r4, MemcardData(r13)
17    lwz r4, 0x1F24(r4)
18    li r3, 1
19    slw r0, r3, r0
20    and. r0, r0, r4
21    beq ActOoWait_End
22
23    # Act Oo Wait
24    li r4, 0
25ActOoWait_SearchForWait:
26    # r3 = data->TM.prev_state[r4]
27    mulli r3, r4, 2
28    add r3, r3, playerdata
29    lhz r3, TM_PrevASStart(r3)
30    
31    cmpwi r3, ASID_Wait
32    beq ActOoWait_FoundWait
33    cmpwi r3, ASID_Landing
34    beq ActOoWait_FoundWait
35    
36    # If the player walks/turns as an intermediate state,
37    # skip this intermediate state and show the OSD for the next state.
38    cmpwi r3, ASID_WalkSlow
39    beq ActOoWait_NextPrevState
40    cmpwi r3, ASID_WalkMiddle
41    beq ActOoWait_NextPrevState
42    cmpwi r3, ASID_WalkFast
43    beq ActOoWait_NextPrevState
44    cmpwi r3, ASID_Turn
45    beq ActOoWait_NextPrevState
46    cmpwi r3, ASID_Squat
47    beq ActOoWait_NextPrevState
48    b ActOoWait_End
49    
50ActOoWait_NextPrevState:
51    addi r4, r4, 1
52    cmpwi r4, TM_PrevASSlots
53    beq ActOoWait_End
54    b ActOoWait_SearchForWait
55    
56ActOoWait_FoundWait:
57    # Make Sure Player Didn't Buffer Crouch, Shield, Walk, or Turn
58    lwz r3, 0x10(playerdata)
59    cmpwi r3, ASID_Wait
60    beq ActOoWait_End
61    cmpwi r3, ASID_WalkSlow
62    beq ActOoWait_End
63    cmpwi r3, ASID_WalkMiddle
64    beq ActOoWait_End
65    cmpwi r3, ASID_WalkFast
66    beq ActOoWait_End
67    cmpwi r3, ASID_Squat
68    beq ActOoWait_End
69    cmpwi r3, ASID_GuardOn
70    beq ActOoWait_End
71    cmpwi r3, ASID_Turn
72    beq ActOoWait_End
73    cmpwi r3, ASID_SquatWait
74    beq ActOoWait_End
75
76    # Display OSD if enabled
77    mr r3, player
78    branchl r12, 0x8000551c
79ActOoWait_End:
80
81OSD_FighterSpecificTech:
82    li r0, OSD.FighterSpecificTech    # OSD ID
83    lwz r4, MemcardData(r13)
84    lwz r4, 0x1F24(r4)
85    li r3, 1
86    slw r0, r3, r0
87    and. r0, r0, r4
88    beq FighterSpecificTech_End
89
90    # Check Fighter
91    lwz r3, 0x4(playerdata)  # load fighter Internal ID
92    cmpwi r3, Fox.Int
93    beq FoxFalco
94    cmpwi r3, Falco.Int
95    beq FoxFalco
96    cmpwi r3, Yoshi.Int
97    beq Yoshi
98
99    # Check If Anyone Else
100    b FighterSpecificTech_End
101
102# /////////////////////////////////////////////////////////////////////////////
103
104FoxFalco:
105    lwz r3, 0x10(playerdata)  # load action state ID
106    cmpwi r3, 0x15B                 # Ground Side B Start
107    beq FoxFalco_SideBStart
108    cmpwi r3, 0x15E                 # Air Side B Start
109    beq FoxFalco_SideBStart
110
111    cmpwi r3, 0x15C                 # Ground Side B
112    beq FoxFalco_SideB
113    cmpwi r3, 0x15F                 # Air Side B
114    beq FoxFalco_SideB
115
116    cmpwi r3, 0x15D                 # Ground Side B End
117    beq FoxFalco_SideBEnd
118    cmpwi r3, 0x160                 # Air Side B End
119    beq FoxFalco_SideBEnd
120    
121    cmpwi r3, 0x16D                 # Ground Side B End
122    beq FoxFalco_ShineAirStartup
123
124    cmpwi r3, 0x169
125    beq FoxFalco_ShineGroundLoop
126    cmpwi r3, 0x16E
127    beq FoxFalco_ShineAirLoop
128
129    b FighterSpecificTech_End
130
131# --------
132
133FoxFalco_SideBStart:
134    # Check If Pressed B
135    lwz r3, 0x668(playerdata)
136    rlwinm. r3, r3, 0, 22, 22
137    beq FighterSpecificTech_End
138
139    # Get Frames Early
140    lwz r7, 0x590(playerdata)       # get anim data
141    lfs f1, 0x008(r7)               # get anim length (float)
142    fctiwz f1, f1
143    stfd f1, 0xF0(sp)
144    lwz r7, 0xF4(sp)
145    lhz r3, 0x23F8(playerdata)
146    sub r7, r7, r3
147    subi r7, r7, 0x1
148
149    li r3, OSD.FighterSpecificTech  # ID
150    lbz r4, 0xC(playerdata)         # queue
151    load r5, MSGCOLOR_RED
152    bl FoxFalco_ShortenEarlyPressText
153    mflr r6
154    Message_Display
155
156    b FighterSpecificTech_End
157
158# --------
159
160FoxFalco_SideB:
161    # Check If Pressed B
162    lwz r3, 0x668(playerdata)
163    rlwinm. r3, r3, 0, 22, 22
164    beq FighterSpecificTech_End
165
166    # Get Press Frame
167    lfs f1, 0x894(playerdata)
168    fctiwz f1, f1
169    stfd f1, 0xF0(sp)
170    lwz r3, 0xF4(sp)
171    addi r7, r3, 0x1
172
173    li r3, OSD.FighterSpecificTech  # ID
174    lbz r4, 0xC(playerdata)         # queue
175    load r5, MSGCOLOR_GREEN
176    bl FoxFalco_ShortenTypeText
177    mflr r6
178    Message_Display
179
180    b FighterSpecificTech_End
181
182# --------
183
184FoxFalco_SideBEnd:
185    # Check If Pressed B
186    lwz r3, 0x668(playerdata)
187    rlwinm. r3, r3, 0, 22, 22
188    beq FighterSpecificTech_End
189
190    li r3, OSD.FighterSpecificTech  # ID
191    lbz r4, 0xC(playerdata)         # queue
192    load r5, MSGCOLOR_RED
193    bl FoxFalco_ShortenLatePressText
194    mflr r6
195    Message_Display
196
197    b FighterSpecificTech_End
198
199# --------
200
201FoxFalco_ShineGroundLoop:
202    # Check For JC
203    bl CheckForJumpCancel
204    cmpwi r3, 0x0
205    beq FighterSpecificTech_End
206
207FoxFalco_ShineGroundLoop_SetColor:
208    load r5, MSGCOLOR_RED
209    lhz r3, 0x23F8(playerdata)
210    cmpwi r3, 0x1
211    bne FoxFalco_ShineGroundLoop_EndSetColor
212    load r5, MSGCOLOR_GREEN
213
214FoxFalco_ShineGroundLoop_EndSetColor:
215    li r3, OSD.FighterSpecificTech  # ID
216    lbz r4, 0xC(playerdata)         # queue
217    bl FoxFalco_ActOOShineText
218    mflr r6
219    lhz r7, 0x23F8(playerdata)
220    Message_Display
221
222    b FighterSpecificTech_End
223
224# --------
225
226FoxFalco_ShineAirLoop:
227    # Check For Remaining Jump
228    lbz r3, 0x1968(playerdata)      # Jumps Used
229    lwz r0, 0x0168(playerdata)      # Total Jumps
230    cmpw r3, r0
231    bge FighterSpecificTech_End
232
233    # Check For JC
234    bl CheckForJumpCancel
235    cmpwi r3, 0x0
236    beq FighterSpecificTech_End
237
238FoxFalco_ShineAirLoop_SetColor:
239    load r5, MSGCOLOR_RED
240    lhz r3, 0x23F8(playerdata)
241    cmpwi r3, 0x1
242    bne FoxFalco_ShineAirLoop_EndSetColor
243    load r5, MSGCOLOR_GREEN
244
245FoxFalco_ShineAirLoop_EndSetColor:
246
247    li r3, OSD.FighterSpecificTech  # ID
248    lbz r4, 0xC(playerdata)         # queue
249    bl FoxFalco_ActOOShineText
250    mflr r6
251    lhz r7, 0x23F8(playerdata)
252    Message_Display
253
254    b FighterSpecificTech_End
255    
256# --------
257    
258FoxFalco_ShineAirStartup:
259    # ensure we just jumped from the ground
260    lhz r3, 0x23fc(playerdata)
261    cmpwi r3, ASID_JumpF
262    beq FoxFalco_ShineAirStartup_AfterJump 
263    cmpwi r3, ASID_JumpB
264    beq FoxFalco_ShineAirStartup_AfterJump 
265    b FighterSpecificTech_End 
266     
267FoxFalco_ShineAirStartup_AfterJump:
268
269    # Calculate frames holding jump
270    li r9, 0
271FoxFalco_ShineAirStartup_JumpInputsLoop:
272    mulli r10, r9, 8
273    add r10, r10, playerdata
274
275    lhz r11, TM_Inputs(r10) # buttons
276    andi. r11, r11, 0xC00 # x or y
277    bne FoxFalco_ShineAirStartup_EndJumpInputsLoop
278
279    addi r10, r10, 3
280    lbz r11, TM_Inputs(r10) # stick y
281    extsb r11, r11
282    cmpwi r11, 44
283    bgt FoxFalco_ShineAirStartup_EndJumpInputsLoop
284
285    # no jump input this frame
286    addi r9, r9, 1
287    cmpwi r9, 32
288    blt FoxFalco_ShineAirStartup_JumpInputsLoop
289    
290    # Out of input history with no jump input - probably took longer than 32 frames.
291    # Nothing we can do here unless we increase the input history range.
292    b FighterSpecificTech_End
293    
294FoxFalco_ShineAirStartup_EndJumpInputsLoop:
295    lbz r10, 0x685(playerdata) # timer_jump
296    sub r9, r10, r9 # get jump held frames
297    addi r9, r9, 1 # 1-index
298    
299    # get hop type and text
300    mr r3, r9
301    bl IntToFloat
302    lfs f2, 0x148(playerdata) # jump_startup_time
303    bl ShortHopText
304    mflr r8
305    li r19, 0 # save for later
306    fcmpo cr0, f1, f2
307    blt EndGetHopTypeText
308    bl FullHopText
309    mflr r8
310    li r19, 1 # save for later
311EndGetHopTypeText:
312    
313    # display
314    li r3, OSD.FighterSpecificTechAlt  # ID - use alt so that ActOoShine doesn't overwrite
315    lbz r4, 0xC(playerdata)         # queue
316    li r5, MSGCOLOR_WHITE
317    bl FoxFalco_JCShineText
318    mflr r6
319    lhz r7, 0x2408(playerdata) # frames in JumpF / JumpB
320    Message_Display
321    lwz r3, 0x2C(r3)
322    lwz r20, MsgData_Text(r3)
323    
324    # set shine frame colour
325    bl GreenRedColors
326    mflr r5
327    lhz r7, 0x2408(playerdata) # frames in JumpF / JumpB
328    cmpwi r7, 2
329    ble ShineWasGood
330    addi r5, r5, 4
331ShineWasGood:
332    li r4, 1
333    mr r3, r20 
334    branchl r12, Text_ChangeTextColor
335       
336    # set hop type colour
337    li r4, 2
338    mr r3, r19
339    bl GreenRedColors
340    mflr r5
341    mulli r3, r3, 4
342    add r5, r5, r3
343    mr r3, r20
344    branchl r12, Text_ChangeTextColor
345    
346    b FighterSpecificTech_End
347
348# /////////////////////////////////////////////////////////////////////////////
349
350Yoshi:
351    lwz r3, 0x10(playerdata)  # load action state ID
352    cmpwi r3, 0x159    # Parry Start
353    beq Yoshi_Parry
354
355    b FighterSpecificTech_End
356
357# --------
358
359Yoshi_Parry:
360    bl CheckForJumpCancel
361    cmpwi r3, 0x0
362    beq FighterSpecificTech_End
363
364Yoshi_PrintJumpOoParryText:
365    load r5, MSGCOLOR_WHITE
366    li r3, OSD.FighterSpecificTech  # ID
367    lbz r4, 0xC(playerdata)         # queue
368    bl Yoshi_JumpOoParryText
369    mflr r6
370    lhz r7, 0x23F8(playerdata)
371    Message_Display
372    b FighterSpecificTech_End
373
374# /////////////////////////////////////////////////////////////////////////////
375
376CheckForJumpCancel:
377    mflr r0
378    stw r0, 0x0004(sp)
379    stwu sp, -0x0038(sp)
380    # Check For JC
381    lwz r5, -0x514C(r13)
382    lfs f0, 0x0070(r5)
383    lfs f1, 0x0624(playerdata)
384    fcmpo cr0, f1, f0
385    blt CheckForJumpCancel_CheckButtons
386    lbz r3, 0x0671(playerdata)
387    lwz r0, 0x0074(r5)
388    cmpw r3, r0
389    bge CheckForJumpCancel_CheckButtons
390    li r3, 0x1
391    b CheckForJumpCancel_OSD_Lockout
392
393CheckForJumpCancel_CheckButtons:
394    lwz r0, 0x0668(playerdata)
395    rlwinm. r0, r0, 0, 20, 21
396    beq CheckForJumpCancel_NoButtons
397    li r3, 0x1
398    b CheckForJumpCancel_OSD_Lockout
399
400CheckForJumpCancel_NoButtons:
401    li r3, 0x0
402
403CheckForJumpCancel_OSD_Lockout:
404    lwz r0, 0x003C(sp)
405    addi sp, sp, 56
406    mtlr r0
407    blr
408
409###################
410## TEXT CONTENTS ##
411###################
412
413FoxFalco_ShortenEarlyPressText:
414    blrl
415    .string "Shorten Press\n%df Early"
416    .align 2
417
418FoxFalco_ShortenTypeText:
419    blrl
420    .string "Shorten Press\nFrame %d/4"
421    .align 2
422
423FoxFalco_ShortenLatePressText:
424    blrl
425    .string "Shorten Press\nLate"
426    .align 2
427
428FoxFalco_ActOOShineText:
429    blrl
430    .string "Act OoShine\nFrame %d"
431    .align 2
432    
433FoxFalco_JCShineText:
434    blrl
435    .string "JC Shine\nFrame %d\n%s: %df"
436    .align 2
437
438ShortHopText:
439    blrl
440    .string "Short Hop"
441    .align 2
442
443FullHopText:
444    blrl
445    .string "Full Hop"
446    .align 2
447    
448GreenRedColors:
449    blrl
450    .long 0x8dff6eff                # green
451    .long 0xffa2baff                # red
452    .align 2
453
454# --------
455
456Yoshi_JumpOoParryText:
457    blrl
458    .string "Jump OoParry\nFrame %d"
459    .align 2
460
461FighterSpecificTech_End:
462
463##############################
464
465OSD_Lockout:
466    # Check enabled
467    li r0, OSD.LockoutTimers
468    lwz r4, MemcardData(r13)
469    lwz r4, 0x1F24(r4)
470    li r3, 1
471    slw r0, r3, r0
472    and. r0, r0, r4
473    beq Lockout_End
474
475    # dont show if in the air
476    lwz r3, 0xE0(playerdata) # air_state
477    cmpwi r3, 1
478    beq Lockout_End
479
480    # dont show if in dtilt / dsmash
481    lwz r3, 0x10(playerdata) # state_id
482    cmpwi r3, ASID_AttackLw3
483    beq Lockout_End
484    cmpwi r3, ASID_AttackLw4
485    beq Lockout_End
486
487    # dont show if stick is vertical
488    lfs f0, 0x624(playerdata) # input.stick.y
489    fsubs f1, f1, f1 # zero f1
490    fcmpo cr0, f0, f1
491    bge Lockout_End
492
493    lbz r7, 0x674(playerdata) # input.timer_lstick_smash_y
494    li r5, MSGCOLOR_RED
495    cmpwi r7, 4
496    blt Lockout_InLockout
497    li r5, MSGCOLOR_GREEN
498    cmpwi r7, 25
499    bge Lockout_End
500
501Lockout_InLockout:
502    addi r7, r7, 1 # 1-index timer
503    bl LockoutText
504    mflr r6
505
506    li r3, OSD.LockoutTimers        # ID
507    lbz r4, 0xC(playerdata)         # queue
508    Message_Display
509    b Lockout_End
510
511LockoutText:
512    blrl
513    .string "DTilt Lockout\nFrame %d"
514    .align 2
515
516Lockout_End:
517
518##############################
519
520OSD_DJL:
521    li r0, OSD.FighterSpecificTech    # OSD ID
522    lwz r4, MemcardData(r13)
523    lwz r4, 0x1F24(r4)
524    li r3, 1
525    slw r0, r3, r0
526    and. r0, r0, r4
527    beq DJL_End
528    
529    lwz r3, 0x4(playerdata)  # load fighter Internal ID
530    cmpwi r3, Peach.Int
531    bne DJL_End
532    
533    bl DJL_Data
534    .byte 0, 0, 0, 0
535    .byte 0, 0, 0, 0
536    .byte 0, 0, 0, 0
537    .align 2
538DJL_Data:
539    mflr r3
540    
541    lbz r4, 0x685(playerdata) # input.timer_jump
542    lwz r5, 0xC(playerdata) # ply
543    add r3, r3, r5
544    lbz r5, 0x0(r3) # frames since jump input
545    lbz r7, 0x6(r3) # previous frame's input.timer_jump
546    stb r4, 0x6(r3)
547    
548    # if just input a jump:
549    # input.timer_jump holds zero while jump is held, so we need to compare with
550    # the previous frame's input.timer_jump to determine when jump is first pressed.
551    cmpwi r4, 0
552    bne DJL_Increment
553    cmpwi r7, 0
554    bne DJL_Reset
555    
556# No jump, increment jump timer
557DJL_Increment:
558    cmpwi r5, 255
559    beq DJL_End
560    addi r5, r5, 1
561    stb r5, 0x0(r3)
562    b DJL_End
563
564# We just input a jump, so reset jump timer
565DJL_Reset:    
566    li r6, 0
567    stb r6, 0x0(r3)
568    
569    # ensure prev jump input was 10 frame or fewer ago
570    cmpwi r5, 10
571    bge DJL_End
572    
573DJL_Show:
574    addi r7, r5, 1 # fix off-by-one    
575    li r3, OSD.FighterSpecificTech # ID
576    lbz r4, 0xC(playerdata)        # queue
577    
578    li r5, MSGCOLOR_RED
579    cmpwi r7, 5
580    bne DJL_EndColor
581    li r5, MSGCOLOR_GREEN
582DJL_EndColor:
583
584    bl DJL_Text
585    mflr r6
586    Message_Display
587    b DJL_End
588    
589DJL_Text:
590    blrl
591    .string "Insta Double Jump\nFrame %d"
592    .align 2
593    
594DJL_End:
595    b Exit
596
597##############################
598
599IntToFloat:
600    mflr r0
601    stw r0, 0x4(r1)
602    stwu r1, -0x100(r1)             # make space for 12 registers
603    stmw r20, 0x8(r1)
604    stfs f2, 0x38(r1)
605
606    lis r0, 0x4330
607    lfd f2, -0x6758(rtoc)
608    xoris r3, r3, 0x8000
609    stw r0, 0xF0(sp)
610    stw r3, 0xF4(sp)
611    lfd f1, 0xF0(sp)
612    fsubs f1, f1, f2                # Convert To Float
613
614    lfs f2, 0x38(r1)
615    lmw r20, 0x8(r1)
616    lwz r0, 0x104(r1)
617    addi r1, r1, 0x100              # release the space
618    mtlr r0
619    blr
620
621Exit:
622    restoreall
623    lwz r12, 0x219C(r31)