fork/training-mode-ce

git clone https://git.julia.blue/fork/training-mode-ce

AitchMerge pull request #242 from NickCondron/remove-asm96edbd1

techchase-camera
1.9 KiB89 linesraw
1    # To be inserted at 800da07c
2    .include "../../Globals.s"
3
4    .set playerdata, 31
5
6    backupall
7
8    # CHECK IF ENABLED
9    li r0, OSD.GrabBreakout # OSD Menu ID
10    lwz r4, MemcardData(r13)
11    lwz r4, 0x1F24(r4)
12    li r3, 1
13    slw r0, r3, r0
14    and. r0, r0, r4
15    beq Exit
16
17    # CHECK FOR FOLLOWER
18    mr r3, playerdata
19    branchl r12, 0x80005510
20    cmpwi r3, 0x1
21    beq Exit
22
23    # The grab timer is set at some number when initially grabbed,
24    # then decrements by 1 for each frame not being pummelled, and for each input.
25    # The grab breaks when the timer reaches zero.
26    bl Data
27    .float 0.5
28    .float 1.0
29    .long 0    # 0x8  initial grab timer
30    .long 0    # 0xC  frame counter for grab
31    .long 0    # 0x10 global frame counter - used to detect new grabs
32Data:
33    mflr r3
34
35    # If this run is not 1f later than last run, then it's a new grab.
36    # Doesn't work for simultaneous grabs in doubles, oh well.
37CheckNewGrab:
38    # r5 = stc_match->time_frames
39    lis r5, 0x8046
40    ori r5, r5, 0xb6a0
41    lwz r5, 0x24(r5)
42
43    lwz r4, 0x10(r3)
44    stw r5, 0x10(r3)
45    addi r4, r4, 1
46    cmpw r4, r5
47
48    beq GrabUpdate
49
50NewGrab:
51    # initial_grab_timer = data->grab.grab_timer
52    lfs f0, 0x1A4C (playerdata)
53    stfs f0, 0x8(r3)
54    li r4, 0
55    stw r4, 0xC(r3)
56
57GrabUpdate:
58    # frame_counter += 1.f
59    lfs f1, 0xC(r3)
60    lfs f2, 0x4(r3)
61    fadds f1, f1, f2
62    stfs f1, 0xC(r3)
63
64    # grab_timer = data->grab.grab_timer
65    lfs f1, 0x1A4C (playerdata)
66
67    # calculate mash rate
68    # mash_rate = (initial_grab_timer - grab_timer) / frame_counter
69    lfs f2, 0x8(r3)
70    lfs f3, 0xC(r3)
71    fsubs f2, f2, f1
72    fdivs f2, f2, f3
73
74    li r3, OSD.GrabBreakout
75    lbz r4, 0xC(playerdata)
76    li r5, MSGCOLOR_WHITE
77    bl Text
78    mflr r6
79    Message_Display
80    b Exit
81
82Text:
83    blrl
84    .string "Grab Breakout\nGrab Timer: %.0f\nMash Rate: %.1f/f"
85    .align 2
86
87Exit:
88    restoreall
89    lbz r0, 0x2226 (r31)