fork/wezterm

git clone https://git.julia.blue/fork/wezterm

Joe Xuefix: tmux -CC error on %config-error (#6773)4ce83f093

termwiz-0.23.3
3.6 KiB99 linesraw
1// Plese put new items in alphabet order in its category
2
3// Generic tokens
4any_text = { ANY* }
5number = { ASCII_DIGIT+ }
6word = { (ASCII_ALPHANUMERIC | "/")+ }
7
8// Tmux tokens
9client_name = { word }
10pane_id = { "%" ~ number }
11session_id = { "$" ~ number }
12window_id = { "@" ~ number }
13window_layout = { (ASCII_HEX_DIGIT | "x" | "[" | "]" | "{" | "}" | ",")+ }
14
15// Tmux generic rules
16begin = { "%begin " ~ number ~ " " ~ number ~ " " ~ number }
17end = { "%end " ~ number ~ " " ~ number ~ " " ~ number }
18error = { "%error " ~ number ~ " " ~ number ~ " " ~ number }
19
20// Tmux specific rules
21client_session_changed = { "%client-session-changed " ~ client_name ~ " " ~ session_id ~ " " ~any_text }
22client_detached = { "%client-detached " ~ client_name }
23config_error = { "%config-error " ~ any_text }
24continue = { "%continue " ~ pane_id }
25exit = { "%exit" ~ (" " ~ any_text)? }
26extended_output = { "%extended-output " ~ pane_id ~ " " ~ any_text }
27layout_change = { "%layout-change " ~ window_id ~ " " ~ (window_layout ~ " " ~ window_layout ~ " " ~any_text | window_layout) }
28message = { "%message " ~ any_text }
29output = { "%output " ~ pane_id ~ " " ~ any_text }
30pane_mode_changed = { "%pane-mode-changed " ~ pane_id }
31paste_buffer_changed = { "%paste-buffer-changed " ~ any_text }
32paste_buffer_deleted = { "%paste-buffer-deleted " ~ any_text }
33pause = { "%pause " ~ pane_id }
34session_changed = { "%session-changed " ~ session_id ~ " " ~ any_text }
35session_renamed = { "%session-renamed " ~ any_text }
36session_window_changed = { "%session-window-changed " ~ session_id ~ " " ~ window_id }
37sessions_changed = { "%sessions-changed" }
38subscription_changed = { "%subscription-changed " ~ any_text }
39unlinked_window_add = { "%unlinked-window-add " ~ window_id }
40unlinked_window_close = { "%unlinked-window-close " ~ window_id }
41unlinked_window_renamed = { "%unlinked-window-renamed " ~ window_id }
42window_add = { "%window-add " ~ window_id }
43window_close = { "%window-close " ~ window_id }
44window_pane_changed = { "%window-pane-changed " ~ window_id ~ " " ~ pane_id }
45window_renamed = { "%window-renamed " ~ window_id ~ " " ~ any_text }
46
47line = _{ (
48  // Tmux generic rules
49  begin |
50  end |
51  error |
52
53  // Tmux specific rules
54  client_detached |
55  client_session_changed |
56  config_error |
57  continue |
58  exit |
59  extended_output |
60  layout_change |
61  message |
62  output |
63  pane_mode_changed |
64  paste_buffer_changed |
65  paste_buffer_deleted |
66  pause |
67  session_changed |
68  session_renamed |
69  session_window_changed |
70  sessions_changed |
71  subscription_changed |
72  unlinked_window_add |
73  unlinked_window_close |
74  unlinked_window_renamed |
75  window_add |
76  window_close |
77  window_pane_changed |
78  window_renamed
79) }
80
81line_entire = _{ SOI ~ line ~ EOI }
82
83// layout section:
84// The tmux layout has three cases: single pane, horizontal split or vertical split.
85// horizontal split can be nested in vertical split
86// vertical split can be nested in horizontal split
87// layout pane:       widthxheight,left,top,id
88// layout split pane: widthxheight,left,top
89// layout horizontal: widthxheight,left,top{...}
90// layout vertical:   widthxheight,left,top[...]
91layout_pane = {number ~ "x" ~ number ~ "," ~ number ~ "," ~ number ~ "," ~ number}
92layout_split_horizontal = { layout_split_pane ~ "{" ~ (layout_split_vertical | layout_pane) ~ ("," ~ (layout_split_vertical | layout_pane))* ~ "}" }
93layout_split_pane = {number ~ "x" ~ number ~ "," ~ number ~ "," ~ number }
94layout_split_vertical = { layout_split_pane ~ "[" ~ (layout_split_horizontal | layout_pane) ~ ("," ~ (layout_split_horizontal | layout_pane))* ~ "]" }
95layout_window = _{ (
96    layout_pane |
97    layout_split_horizontal |
98    layout_split_vertical
99) }